summaryrefslogtreecommitdiffstats
path: root/meta/recipes-devtools/distcc/distcc_3.1.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-devtools/distcc/distcc_3.1.bb')
-rw-r--r--meta/recipes-devtools/distcc/distcc_3.1.bb74
1 files changed, 74 insertions, 0 deletions
diff --git a/meta/recipes-devtools/distcc/distcc_3.1.bb b/meta/recipes-devtools/distcc/distcc_3.1.bb
new file mode 100644
index 0000000000..ad0e94f110
--- /dev/null
+++ b/meta/recipes-devtools/distcc/distcc_3.1.bb
@@ -0,0 +1,74 @@
1SUMMARY = "A parallel build system"
2DESCRIPTION = "distcc is a parallel build system that distributes \
3compilation of C/C++/ObjC code across machines on a network."
4SECTION = "devel"
5LICENSE = "GPLv2"
6LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
7
8DEPENDS = "avahi"
9
10GTKCONFIG = "gtk"
11GTKCONFIG_libc-uclibc = ""
12
13PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'x11', '${GTKCONFIG}', '', d)} popt"
14PACKAGECONFIG[gtk] = "--with-gtk,--without-gtk --without-gnome,gtk+"
15# use system popt by default
16PACKAGECONFIG[popt] = "--without-included-popt,--with-included-popt,popt"
17
18RRECOMMENDS_${PN} = "avahi-daemon"
19
20SRC_URI = "http://distcc.googlecode.com/files/${BPN}-${PV}.tar.bz2 \
21 file://separatebuilddir.patch \
22 file://default \
23 file://distccmon-gnome.desktop \
24 file://distcc \
25 file://distcc.service"
26
27SRC_URI[md5sum] = "a1a9d3853df7133669fffec2a9aab9f3"
28SRC_URI[sha256sum] = "f55dbafd76bed3ce57e1bbcdab1329227808890d90f4c724fcd2d53f934ddd89"
29
30inherit autotools pkgconfig update-rc.d useradd systemd
31
32EXTRA_OECONF += "--disable-Werror PYTHON=/dev/null"
33
34USERADD_PACKAGES = "${PN}"
35USERADD_PARAM_${PN} = "--system \
36 --home /dev/null \
37 --no-create-home \
38 --gid nogroup \
39 distcc"
40
41INITSCRIPT_NAME = "distcc"
42
43SYSTEMD_PACKAGES = "${PN}"
44SYSTEMD_SERVICE_${PN} = "distcc.service"
45
46do_install_append() {
47 install -d ${D}${sysconfdir}/init.d/
48 install -d ${D}${sysconfdir}/default
49 install -m 0755 ${WORKDIR}/distcc ${D}${sysconfdir}/init.d/
50 install -m 0755 ${WORKDIR}/default ${D}${sysconfdir}/default/distcc
51 install -d ${D}${systemd_unitdir}/system/
52 install -m 0644 ${WORKDIR}/distcc.service ${D}${systemd_unitdir}/system
53 sed -i -e 's,@BINDIR@,${bindir},g' ${D}${systemd_unitdir}/system/distcc.service
54 ${DESKTOPINSTALL}
55}
56DESKTOPINSTALL = ""
57DESKTOPINSTALL_libc-glibc () {
58 install -d ${D}${datadir}/distcc/
59 install -m 0644 ${WORKDIR}/distccmon-gnome.desktop ${D}${datadir}/distcc/
60}
61PACKAGES += "distcc-distmon-gnome"
62
63FILES_${PN} = " ${sysconfdir} \
64 ${bindir}/distcc \
65 ${bindir}/lsdistcc \
66 ${bindir}/distccd \
67 ${bindir}/distccmon-text \
68 ${systemd_unitdir}/system/distcc.service"
69FILES_distcc-distmon-gnome = " ${bindir}/distccmon-gnome \
70 ${datadir}/distcc"
71
72pkg_postrm_${PN} () {
73 deluser distcc || true
74}