diff options
Diffstat (limited to 'meta/recipes-devtools/bison/bison_3.8.2.bb')
-rw-r--r-- | meta/recipes-devtools/bison/bison_3.8.2.bb | 54 |
1 files changed, 54 insertions, 0 deletions
diff --git a/meta/recipes-devtools/bison/bison_3.8.2.bb b/meta/recipes-devtools/bison/bison_3.8.2.bb new file mode 100644 index 0000000000..58395c3dce --- /dev/null +++ b/meta/recipes-devtools/bison/bison_3.8.2.bb | |||
@@ -0,0 +1,54 @@ | |||
1 | SUMMARY = "GNU Project parser generator (yacc replacement)" | ||
2 | DESCRIPTION = "Bison is a general-purpose parser generator that converts an annotated context-free grammar into \ | ||
3 | an LALR(1) or GLR parser for that grammar. Bison is upward compatible with Yacc: all properly-written Yacc \ | ||
4 | grammars ought to work with Bison with no change. Anyone familiar with Yacc should be able to use Bison with \ | ||
5 | little trouble." | ||
6 | HOMEPAGE = "http://www.gnu.org/software/bison/" | ||
7 | LICENSE = "GPLv3" | ||
8 | LIC_FILES_CHKSUM = "file://COPYING;md5=1ebbd3e34237af26da5dc08a4e440464" | ||
9 | SECTION = "devel" | ||
10 | DEPENDS = "bison-native flex-native" | ||
11 | |||
12 | SRC_URI = "${GNU_MIRROR}/bison/bison-${PV}.tar.xz \ | ||
13 | file://add-with-bisonlocaledir.patch \ | ||
14 | " | ||
15 | SRC_URI[sha256sum] = "9bba0214ccf7f1079c5d59210045227bcf619519840ebfa80cd3849cff5a5bf2" | ||
16 | |||
17 | inherit autotools gettext texinfo | ||
18 | |||
19 | # No point in hardcoding path to m4, just use PATH | ||
20 | CACHED_CONFIGUREVARS = "ac_cv_path_M4=m4" | ||
21 | |||
22 | PACKAGECONFIG ??= "readline ${@ 'textstyle' if d.getVar('USE_NLS') == 'yes' else ''}" | ||
23 | PACKAGECONFIG:class-native ??= "" | ||
24 | |||
25 | # Make readline and textstyle optional. There are recipie for these, but leave them | ||
26 | # disabled for the native recipe. This prevents host contamination of the native tool. | ||
27 | PACKAGECONFIG[readline] = "--with-libreadline-prefix,--without-libreadline-prefix,readline" | ||
28 | PACKAGECONFIG[textstyle] = "--with-libtextstyle-prefix,--without-libtextstyle-prefix,gettext" | ||
29 | |||
30 | # Include the cached configure variables, configure is really good at finding | ||
31 | # libreadline, even if we don't want it. | ||
32 | CACHED_CONFIGUREVARS += "${@bb.utils.contains('PACKAGECONFIG', 'readline', '', ' \ | ||
33 | ac_cv_header_readline_history_h=no \ | ||
34 | ac_cv_header_readline_readline_h=no \ | ||
35 | gl_cv_lib_readline=no', d)} \ | ||
36 | ${@bb.utils.contains('PACKAGECONFIG', 'textstyle', '', ' \ | ||
37 | ac_cv_libtextstyle=no', d)}" | ||
38 | |||
39 | # The automatic m4 path detection gets confused, so force the right value | ||
40 | acpaths = "-I ./m4" | ||
41 | |||
42 | do_compile:prepend() { | ||
43 | for i in mfcalc calc++ rpcalc; do mkdir -p ${B}/examples/$i; done | ||
44 | } | ||
45 | |||
46 | do_install:append:class-native() { | ||
47 | create_wrapper ${D}/${bindir}/bison \ | ||
48 | BISON_PKGDATADIR=${STAGING_DATADIR_NATIVE}/bison | ||
49 | } | ||
50 | do_install:append:class-nativesdk() { | ||
51 | create_wrapper ${D}/${bindir}/bison \ | ||
52 | BISON_PKGDATADIR=${datadir}/bison | ||
53 | } | ||
54 | BBCLASSEXTEND = "native nativesdk" | ||