5 files changed, 121 insertions, 0 deletions

diff --git a/meta/recipes-core/zlib/site_config/headers b/meta/recipes-core/zlib/site_config/headers
new file mode 100644
index 0000000000..50268918aa
--- /dev/null
+++ b/meta/recipes-core/zlib/site_config/headers
@@ -0,0 +1 @@
+zlib.h
diff --git a/meta/recipes-core/zlib/zlib-1.2.8/Makefile-runtests.patch b/meta/recipes-core/zlib/zlib-1.2.8/Makefile-runtests.patch
new file mode 100644
index 0000000000..61eea8238a
--- /dev/null
+++ b/meta/recipes-core/zlib/zlib-1.2.8/Makefile-runtests.patch
@@ -0,0 +1,38 @@
+Add 'ptest' target to Makefile, to run tests without checking dependencies.
+
+Signed-off-by: Anders Roxell <anders.roxell@enea.com>
+Upstream-Status: Pending
+---
+diff -uNr a/Makefile.in b/Makefile.in
+--- a/Makefile.in       2013-06-10 13:48:14.321959162 +0200
++++ b/Makefile.in       2013-06-10 13:49:36.686476448 +0200
+@@ -83,6 +83,9 @@
+ test: all teststatic testshared
+ 
+ teststatic: static
++       @make runteststatic
++
++runteststatic:
+        @TMPST=tmpst_$$; \
+        if echo hello world | ./minigzip | ./minigzip -d && ./example $$TMPST ; then \
+          echo '                *** zlib test OK ***'; \
+@@ -92,6 +95,9 @@
+        rm -f $$TMPST
+ 
+ testshared: shared
++       @make runtestshared
++
++runtestshared:
+        @LD_LIBRARY_PATH=`pwd`:$(LD_LIBRARY_PATH) ; export LD_LIBRARY_PATH; \
+        LD_LIBRARYN32_PATH=`pwd`:$(LD_LIBRARYN32_PATH) ; export LD_LIBRARYN32_PATH; \
+        DYLD_LIBRARY_PATH=`pwd`:$(DYLD_LIBRARY_PATH) ; export DYLD_LIBRARY_PATH; \
+@@ -105,6 +111,9 @@
+        rm -f $$TMPSH
+ 
+ test64: all64
++       @make runtestall64
++
++runtestall64:
+        @TMP64=tmp64_$$; \
+        if echo hello world | ./minigzip64 | ./minigzip64 -d && ./example64 $$TMP64; then \
+          echo '                *** zlib 64-bit test OK ***'; \
diff --git a/meta/recipes-core/zlib/zlib-1.2.8/remove.ldconfig.call.patch b/meta/recipes-core/zlib/zlib-1.2.8/remove.ldconfig.call.patch
new file mode 100644
index 0000000000..403b4825c9
--- /dev/null
+++ b/meta/recipes-core/zlib/zlib-1.2.8/remove.ldconfig.call.patch
@@ -0,0 +1,20 @@
+
+When /etc/ld.so.cache is writeable by user running bitbake then it creates invalid cache 
+(in my case libstdc++.so cannot be found after building zlib(-native) and I have to call 
+touch */libstdc++.so && /sbin/ldconfig to fix it.
+
+So remove ldconfig call from make install-libs
+
+Upstream-Status: Inappropriate [disable feature]
+
+diff -uNr zlib-1.2.6.orig/Makefile.in zlib-1.2.6/Makefile.in
+--- zlib-1.2.6.orig/Makefile.in 2012-01-28 23:48:50.000000000 +0100
++++ zlib-1.2.6/Makefile.in      2012-02-13 15:38:20.577700723 +0100
+@@ -199,7 +199,6 @@
+          rm -f $(DESTDIR)$(sharedlibdir)/$(SHAREDLIB) $(DESTDIR)$(sharedlibdir)/$(SHAREDLIBM); \
+          ln -s $(SHAREDLIBV) $(DESTDIR)$(sharedlibdir)/$(SHAREDLIB); \
+          ln -s $(SHAREDLIBV) $(DESTDIR)$(sharedlibdir)/$(SHAREDLIBM); \
+-         ($(LDCONFIG) || true)  >/dev/null 2>&1; \
+        fi
+        cp zlib.3 $(DESTDIR)$(man3dir)
+        chmod 644 $(DESTDIR)$(man3dir)/zlib.3
diff --git a/meta/recipes-core/zlib/zlib-1.2.8/run-ptest b/meta/recipes-core/zlib/zlib-1.2.8/run-ptest
new file mode 100644
index 0000000000..884d9dc699
--- /dev/null
+++ b/meta/recipes-core/zlib/zlib-1.2.8/run-ptest
@@ -0,0 +1,2 @@
+#!/bin/sh
+make -k runteststatic runtestshared | sed -r -e 's/^(\s+\*+ (.+?) test OK \*+)/\1\nPASS: \2/' -e 's/^(\s+\*+ (.+?) test FAILED \*+)/\1\nFAIL: \2/'
diff --git a/meta/recipes-core/zlib/zlib_1.2.8.bb b/meta/recipes-core/zlib/zlib_1.2.8.bb
new file mode 100644
index 0000000000..bdfa045b7b
--- /dev/null
+++ b/meta/recipes-core/zlib/zlib_1.2.8.bb
@@ -0,0 +1,60 @@
+SUMMARY = "Zlib Compression Library"
+DESCRIPTION = "Zlib is a general-purpose, patent-free, lossless data compression \
+library which is used by many different programs."
+HOMEPAGE = "http://zlib.net/"
+SECTION = "libs"
+LICENSE = "Zlib"
+LIC_FILES_CHKSUM = "file://zlib.h;beginline=4;endline=23;md5=fde612df1e5933c428b73844a0c494fd"
+
+
+SRC_URI = "http://www.zlib.net/${BPN}-${PV}.tar.xz \
+           file://remove.ldconfig.call.patch \
+           file://Makefile-runtests.patch \
+           file://run-ptest \
+           "
+
+SRC_URI[md5sum] = "28f1205d8dd2001f26fec1e8c2cebe37"
+SRC_URI[sha256sum] = "831df043236df8e9a7667b9e3bb37e1fcb1220a0f163b6de2626774b9590d057"
+
+RDEPENDS_${PN}-ptest += "make"
+
+inherit ptest
+
+do_configure (){
+        ./configure --prefix=${prefix} --shared --libdir=${libdir}
+}
+
+do_compile (){
+        oe_runmake
+}
+
+do_compile_ptest() {
+        oe_runmake static shared
+}
+
+do_install() {
+        oe_runmake DESTDIR=${D} install
+}
+
+do_install_ptest() {
+        install ${B}/Makefile   ${D}${PTEST_PATH}
+        install ${B}/example    ${D}${PTEST_PATH}
+        install ${B}/minigzip   ${D}${PTEST_PATH}
+        install ${B}/examplesh  ${D}${PTEST_PATH}
+        install ${B}/minigzipsh ${D}${PTEST_PATH}
+}
+
+# We move zlib shared libraries for target builds to avoid
+# qa warnings.
+#
+do_install_append_class-target() {
+        if [ ${base_libdir} != ${libdir} ]
+        then
+                mkdir -p ${D}/${base_libdir}
+                mv ${D}/${libdir}/libz.so.* ${D}/${base_libdir}
+                tmp=`readlink ${D}/${libdir}/libz.so`
+                ln -sf ../../${base_libdir}/$tmp ${D}/${libdir}/libz.so
+        fi
+}
+
+BBCLASSEXTEND = "native nativesdk"