summaryrefslogtreecommitdiffstats
path: root/meta/recipes-core/util-linux/util-linux.inc
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-core/util-linux/util-linux.inc')
-rw-r--r--meta/recipes-core/util-linux/util-linux.inc276
1 files changed, 276 insertions, 0 deletions
diff --git a/meta/recipes-core/util-linux/util-linux.inc b/meta/recipes-core/util-linux/util-linux.inc
new file mode 100644
index 0000000000..dbc6a2856f
--- /dev/null
+++ b/meta/recipes-core/util-linux/util-linux.inc
@@ -0,0 +1,276 @@
1SUMMARY = "A suite of basic system administration utilities"
2DESCRIPTION = "Util-linux includes a suite of basic system administration utilities \
3commonly found on most Linux systems. Some of the more important utilities include \
4disk partitioning, kernel message management, filesystem creation, and system login."
5
6SECTION = "base"
7
8LICENSE = "GPLv2+ & LGPLv2.1+ & BSD"
9
10LIC_FILES_CHKSUM = "file://README.licensing;md5=1715f5ee3e01203ca1e1e0b9ee65918c \
11 file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
12 file://Documentation/licenses/COPYING.GPLv2;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
13 file://Documentation/licenses/COPYING.LGPLv2.1;md5=4fbd65380cdd255951079008b364516c \
14 file://Documentation/licenses/COPYING.BSD-3;md5=58dcd8452651fc8b07d1f65ce07ca8af \
15 file://Documentation/licenses/COPYING.UCB;md5=263860f8968d8bafa5392cab74285262 \
16 file://libuuid/COPYING;md5=b442ffb762cf8d3e9df1b99e0bb4af70 \
17 file://libmount/COPYING;md5=fb93f01d4361069c5616327705373b16 \
18 file://libblkid/COPYING;md5=fb93f01d4361069c5616327705373b16"
19
20inherit autotools gettext pkgconfig systemd ptest
21DEPENDS = "zlib ncurses"
22DEPENDS_append_class-native = " lzo-native"
23DEPENDS_append_class-nativesdk = " lzo-native"
24
25SRC_URI = "${KERNELORG_MIRROR}/linux/utils/util-linux/v${MAJOR_VERSION}/util-linux-${PV}.tar.xz \
26 file://MCONFIG \
27 file://defines.h \
28 file://make_include \
29 file://swapargs.h \
30 file://ptest.patch \
31 file://run-ptest \
32 file://avoid_unsupported_find_opts.patch \
33 file://avoid_unsupported_grep_opts.patch \
34 file://avoid_unsupported_sleep_param.patch \
35 file://display_testname_for_subtest.patch \
36 "
37
38PACKAGES =+ "util-linux-agetty util-linux-fdisk util-linux-cfdisk util-linux-sfdisk \
39 util-linux-swaponoff util-linux-losetup util-linux-umount \
40 util-linux-mount util-linux-readprofile util-linux-libblkid \
41 util-linux-libmount util-linux-libuuid util-linux-uuidd \
42 util-linux-uuidgen util-linux-lscpu util-linux-fsck util-linux-blkid \
43 util-linux-mkfs util-linux-mcookie util-linux-reset \
44 util-linux-mkfs.cramfs util-linux-fsck.cramfs util-linux-fstrim \
45 util-linux-partx ${PN}-bash-completion util-linux-hwclock \
46 util-linux-findfs"
47
48SHARED_EXTRA_OECONF = "--disable-use-tty-group \
49 --disable-makeinstall-chown \
50 --enable-kill --enable-last --enable-mesg --enable-partx \
51 --enable-raw --enable-reset --disable-login \
52 --disable-vipw --disable-newgrp --disable-chfn-chsh \
53 --enable-write --enable-mount \
54 --enable-libuuid --enable-libblkid --enable-fsck --without-udev \
55 usrsbin_execdir='${sbindir}' \
56"
57
58EXTRA_OECONF = "${SHARED_EXTRA_OECONF} --libdir=${base_libdir}"
59
60PACKAGECONFIG_class-target ?= "${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'pam', '', d)} \
61 ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd', '', d)} "
62PACKAGECONFIG[pam] = "--enable-su --enable-runuser,--disable-su --disable-runuser, libpam,"
63
64# Respect the systemd feature for uuidd
65PACKAGECONFIG[systemd] = "--enable-socket-activation --with-systemdsystemunitdir=${systemd_unitdir}/system/, --disable-socket-activation --without-systemdsystemunitdir"
66
67# Build setpriv requires libcap-ng
68PACKAGECONFIG[libcap-ng] = "--enable-setpriv,--disable-setpriv,libcap-ng,"
69
70FILES_${PN}-bash-completion += "${datadir}/bash-completion"
71FILES_${PN}-doc += "${datadir}/getopt/getopt-*.*"
72
73FILES_util-linux-agetty = "${base_sbindir}/agetty"
74FILES_util-linux-fdisk = "${base_sbindir}/fdisk.${BPN}"
75FILES_util-linux-fstrim = "${base_sbindir}/fstrim"
76FILES_util-linux-cfdisk = "${base_sbindir}/cfdisk"
77FILES_util-linux-sfdisk = "${sbindir}/sfdisk"
78FILES_util-linux-swaponoff = "${base_sbindir}/swapon.${BPN} ${base_sbindir}/swapoff.${BPN}"
79FILES_util-linux-losetup = "${base_sbindir}/losetup.${BPN}"
80FILES_util-linux-mount = "${base_bindir}/mount.${BPN}"
81FILES_util-linux-mcookie = "${bindir}/mcookie"
82FILES_util-linux-umount = "${base_bindir}/umount.${BPN}"
83FILES_util-linux-readprofile = "${base_sbindir}/readprofile.${BPN}"
84FILES_util-linux-uuidgen = "${bindir}/uuidgen"
85FILES_util-linux-uuidd = "${sbindir}/uuidd"
86FILES_util-linux-reset = "${base_bindir}/reset"
87FILES_util-linux-partx = "${sbindir}/partx"
88FILES_util-linux-hwclock = "${base_sbindir}/hwclock.${BPN}"
89FILES_util-linux-findfs = "${sbindir}/findfs"
90
91FILES_util-linux-libblkid = "${base_libdir}/libblkid.so.*"
92FILES_util-linux-libmount = "${base_libdir}/libmount.so.*"
93FILES_util-linux-libuuid = "${base_libdir}/libuuid.so.*"
94FILES_util-linux-lscpu = "${bindir}/lscpu"
95
96FILES_util-linux-fsck = "${base_sbindir}/fsck*"
97FILES_util-linux-mkfs = "${sbindir}/mkfs"
98
99FILES_util-linux-fsck.cramfs = "${sbindir}/fsck.cramfs"
100FILES_util-linux-mkfs.cramfs = "${sbindir}/mkfs.cramfs"
101
102
103# Util-linux' blkid replaces the e2fsprogs one
104FILES_util-linux-blkid = "${base_sbindir}/blkid*"
105RCONFLICTS_util-linux-blkid = "e2fsprogs-blkid"
106RREPLACES_util-linux-blkid = "e2fsprogs-blkid"
107
108# reset calls 'tput'
109RDEPENDS_util-linux-reset += "ncurses"
110
111RDEPENDS_${PN} = "util-linux-umount util-linux-swaponoff util-linux-losetup"
112RRECOMMENDS_${PN} = "util-linux-fdisk util-linux-cfdisk util-linux-sfdisk util-linux-mount util-linux-readprofile util-linux-mkfs "
113
114RRECOMMENDS_${PN}_class-native = ""
115RRECOMMENDS_${PN}_class-nativesdk = ""
116RDEPENDS_${PN}_class-native = ""
117RDEPENDS_${PN}_class-nativesdk = ""
118
119RPROVIDES_${PN}-dev = "util-linux-libblkid-dev util-linux-libmount-dev util-linux-libuuid-dev"
120
121SYSTEMD_PACKAGES = "${PN}-uuidd"
122SYSTEMD_SERVICE_${PN}-uuidd = "uuidd.service"
123
124do_compile () {
125 set -e
126 install ${WORKDIR}/MCONFIG ${S}/MCONFIG
127 install ${WORKDIR}/make_include ${S}/make_include
128 install ${WORKDIR}/swapargs.h ${S}/mount-deprecated/swapargs.h
129 install ${WORKDIR}/defines.h ${S}/defines.h
130 oe_runmake ARCH=${TARGET_ARCH} CPU= CPUOPT= 'OPT=${CFLAGS}'
131}
132
133do_install () {
134 # with ccache the timestamps on compiled files may
135 # end up earlier than on their inputs, this allows
136 # for the resultant compilation in the install step.
137 oe_runmake ARCH=${TARGET_ARCH} CPU= CPUOPT= \
138 'OPT=${CFLAGS}' 'CC=${CC}' 'LD=${LD}' \
139 'LDFLAGS=${LDFLAGS}' 'DESTDIR=${D}' install
140
141 mkdir -p ${D}${base_bindir}
142
143 sbinprogs="agetty ctrlaltdel cfdisk vipw vigr"
144 sbinprogs_a="pivot_root hwclock mkswap mkfs.minix fsck.minix losetup swapon swapoff fdisk readprofile fsck blkid blockdev fstrim sulogin switch_root"
145 usrbinprogs_a="chfn chsh hexdump last logger mesg newgrp renice utmpdump wall setsid chrt flock getopt"
146 binprogs_a="dmesg kill more umount mount login reset su"
147
148 if [ "${base_sbindir}" != "${sbindir}" ]; then
149 mkdir -p ${D}${base_sbindir}
150 for p in $sbinprogs $sbinprogs_a; do
151 if [ -f "${D}${sbindir}/$p" ]; then
152 mv "${D}${sbindir}/$p" "${D}${base_sbindir}/$p"
153 fi
154 done
155 fi
156
157 if [ "${base_bindir}" != "${bindir}" ]; then
158 mkdir -p ${D}${base_bindir}
159 for p in $binprogs_a; do
160 if [ -f "${D}${bindir}/$p" ]; then
161 mv "${D}${bindir}/$p" "${D}${base_bindir}/$p"
162 fi
163 done
164 fi
165
166 install -d ${D}${sysconfdir}/default/
167 echo 'MOUNTALL="-t nonfs,nosmbfs,noncpfs"' > ${D}${sysconfdir}/default/mountall
168
169 rm -f ${D}${bindir}/chkdupexe
170}
171
172inherit update-alternatives
173
174ALTERNATIVE_PRIORITY = "100"
175
176ALTERNATIVE_${PN} = "dmesg kill more mkswap blockdev pivot_root switch_root"
177ALTERNATIVE_${PN} += "mkfs.minix hexdump last logger mesg renice wall"
178ALTERNATIVE_${PN} += "setsid chrt flock utmpdump eject getopt sulogin"
179
180ALTERNATIVE_LINK_NAME[dmesg] = "${base_bindir}/dmesg"
181ALTERNATIVE_LINK_NAME[kill] = "${base_bindir}/kill"
182ALTERNATIVE_LINK_NAME[more] = "${base_bindir}/more"
183ALTERNATIVE_LINK_NAME[mkswap] = "${base_sbindir}/mkswap"
184ALTERNATIVE_LINK_NAME[blockdev] = "${base_sbindir}/blockdev"
185ALTERNATIVE_LINK_NAME[pivot_root] = "${base_sbindir}/pivot_root"
186ALTERNATIVE_LINK_NAME[switch_root] = "${base_sbindir}/switch_root"
187ALTERNATIVE_LINK_NAME[mkfs.minix] = "${base_sbindir}/mkfs.minix"
188ALTERNATIVE_LINK_NAME[eject] = "${bindir}/eject"
189ALTERNATIVE_LINK_NAME[getopt] = "${base_bindir}/getopt"
190ALTERNATIVE_LINK_NAME[sulogin] = "${base_sbindir}/sulogin"
191ALTERNATIVE_TARGET[getopt] = "${bindir}/getopt"
192
193ALTERNATIVE_${PN}-doc = "mountpoint.1 last.1 mesg.1 wall.1 sulogin.8 utmpdump.1 reset.1"
194
195ALTERNATIVE_LINK_NAME[last.1] = "${mandir}/man1/last.1"
196ALTERNATIVE_LINK_NAME[mesg.1] = "${mandir}/man1/mesg.1"
197ALTERNATIVE_LINK_NAME[mountpoint.1] = "${mandir}/man1/mountpoint.1"
198ALTERNATIVE_LINK_NAME[reset.1] = "${mandir}/man1/reset.1"
199ALTERNATIVE_LINK_NAME[sulogin.8] = "${mandir}/man8/sulogin.8"
200ALTERNATIVE_LINK_NAME[utmpdump.1] = "${mandir}/man1/utmpdump.1"
201ALTERNATIVE_LINK_NAME[wall.1] = "${mandir}/man1/wall.1"
202
203ALTERNATIVE_util-linux-hwclock = "hwclock"
204# There seems to be problem, atleast on nslu2, with these, untill they are
205# fixed the busybox ones have higher priority
206ALTERNATIVE_PRIORITY[hwclock] = "10"
207ALTERNATIVE_LINK_NAME[hwclock] = "${base_sbindir}/hwclock"
208
209ALTERNATIVE_util-linux-fdisk = "fdisk"
210ALTERNATIVE_LINK_NAME[fdisk] = "${base_sbindir}/fdisk"
211
212ALTERNATIVE_util-linux-agetty = "getty"
213ALTERNATIVE_LINK_NAME[getty] = "${base_sbindir}/getty"
214ALTERNATIVE_TARGET[getty] = "${base_sbindir}/agetty"
215
216ALTERNATIVE_util-linux-mount = "mount"
217ALTERNATIVE_LINK_NAME[mount] = "${base_bindir}/mount"
218
219ALTERNATIVE_util-linux-umount = "umount"
220ALTERNATIVE_LINK_NAME[umount] = "${base_bindir}/umount"
221
222ALTERNATIVE_util-linux-readprofile = "readprofile"
223ALTERNATIVE_LINK_NAME[readprofile] = "${base_sbindir}/readprofile"
224
225ALTERNATIVE_util-linux-losetup = "losetup"
226ALTERNATIVE_LINK_NAME[losetup] = "${base_sbindir}/losetup"
227
228ALTERNATIVE_util-linux-swaponoff = "swapoff swapon"
229ALTERNATIVE_LINK_NAME[swapoff] = "${base_sbindir}/swapoff"
230ALTERNATIVE_LINK_NAME[swapon] = "${base_sbindir}/swapon"
231
232ALTERNATIVE_util-linux-fsck = "fsck.minix fsck"
233ALTERNATIVE_LINK_NAME[fsck.minix] = "${base_sbindir}/fsck.minix"
234ALTERNATIVE_LINK_NAME[fsck] = "${base_sbindir}/fsck"
235
236ALTERNATIVE_util-linux-blkid = "blkid"
237ALTERNATIVE_LINK_NAME[blkid] = "${base_sbindir}/blkid"
238
239ALTERNATIVE_util-linux-reset = "reset"
240ALTERNATIVE_LINK_NAME[reset] = "${bindir}/reset"
241ALTERNATIVE_TARGET[reset] = "${base_bindir}/reset"
242
243BBCLASSEXTEND = "native nativesdk"
244
245python do_package_prepend () {
246 if '--enable-su' in d.getVar('EXTRA_OECONF', True).split():
247 alt_name = "su"
248 d.setVarFlag('ALTERNATIVE_LINK_NAME', alt_name, '%s/%s' % (d.getVar('base_bindir', True), alt_name))
249 d.appendVar('ALTERNATIVE_%s' % (d.getVar('PN', True)), ' ' + alt_name)
250}
251
252do_compile_ptest() {
253 oe_runmake buildtest-TESTS
254}
255
256do_install_ptest() {
257 mkdir -p ${D}${PTEST_PATH}/tests/ts
258 find . -maxdepth 1 -type f -perm -111 -exec cp {} ${D}${PTEST_PATH} \;
259 cp ${S}/tests/functions.sh ${D}${PTEST_PATH}/tests/
260 cp ${S}/tests/commands.sh ${D}${PTEST_PATH}/tests/
261 cp ${S}/tests/run.sh ${D}${PTEST_PATH}/tests/
262 cp -pR ${S}/tests/expected ${D}${PTEST_PATH}/tests/expected
263
264 list="bitops build-sys cal col colrm column dmesg fsck hexdump hwclock ipcs isosize login look lscpu md5 misc more namei paths schedutils script swapon tailf utmpdump"
265 # The following tests are not installed yet:
266 # blkid scsi_debug module dependent
267 # cramfs gcc dependent
268 # eject gcc dependent
269 # fdisk scsi_debug module and gcc dependent
270 # libmount uuidgen dependent
271 # mount gcc dependant
272 # partx blkid dependant
273 for d in $list; do
274 cp -pR ${S}/tests/ts/$d ${D}${PTEST_PATH}/tests/ts/
275 done
276}