summaryrefslogtreecommitdiffstats
path: root/meta/recipes-core/util-linux/util-linux.inc
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-core/util-linux/util-linux.inc')
-rw-r--r--meta/recipes-core/util-linux/util-linux.inc261
1 files changed, 261 insertions, 0 deletions
diff --git a/meta/recipes-core/util-linux/util-linux.inc b/meta/recipes-core/util-linux/util-linux.inc
new file mode 100644
index 0000000000..812bb06678
--- /dev/null
+++ b/meta/recipes-core/util-linux/util-linux.inc
@@ -0,0 +1,261 @@
1SUMMARY = "A suite of basic system administration utilities."
2DESCRIPTION = "Util-linux includes a suite of basic system administration utilities \
3commonly found on most Linux systems. Some of the more important utilities include \
4disk partitioning, kernel message management, filesystem creation, and system login."
5
6SECTION = "base"
7
8LICENSE = "GPLv2+ & LGPLv2.1+ & BSD"
9
10LIC_FILES_CHKSUM = "file://README.licensing;md5=679af3e410ee112a5ec94de6501bf5c3 \
11 file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
12 file://Documentation/licenses/COPYING.GPLv2;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
13 file://Documentation/licenses/COPYING.LGPLv2.1;md5=4fbd65380cdd255951079008b364516c \
14 file://Documentation/licenses/COPYING.BSD-3;md5=58dcd8452651fc8b07d1f65ce07ca8af \
15 file://Documentation/licenses/COPYING.UCB;md5=263860f8968d8bafa5392cab74285262 \
16 file://libuuid/COPYING;md5=aa3ac5b4a5bcb707f714f78794011b80 \
17 file://libmount/COPYING;md5=152f98bc301a5ea649769ede7203ac82 \
18 file://libblkid/COPYING;md5=152f98bc301a5ea649769ede7203ac82"
19
20inherit autotools gettext pkgconfig systemd ptest
21DEPENDS = "zlib ncurses"
22DEPENDS_append_class-native = " lzo-native"
23DEPENDS_append_class-nativesdk = " lzo-native"
24
25SRC_URI = "${KERNELORG_MIRROR}/linux/utils/util-linux/v${MAJOR_VERSION}/util-linux-${PV}.tar.bz2 \
26 file://MCONFIG \
27 file://defines.h \
28 file://make_include \
29 file://swapargs.h \
30 file://ptest.patch \
31 file://run-ptest \
32 file://avoid_unsupported_find_opts.patch \
33 file://avoid_unsupported_grep_opts.patch \
34 file://avoid_unsupported_sleep_param.patch \
35 file://display_testname_for_subtest.patch \
36 "
37
38PACKAGES =+ "util-linux-agetty util-linux-fdisk util-linux-cfdisk util-linux-sfdisk \
39 util-linux-swaponoff util-linux-losetup util-linux-umount \
40 util-linux-mount util-linux-readprofile util-linux-libblkid \
41 util-linux-libmount util-linux-libmount-dev \
42 util-linux-libblkid-dev util-linux-libuuid util-linux-libuuid-dev \
43 util-linux-uuidgen util-linux-lscpu util-linux-fsck util-linux-blkid \
44 util-linux-mkfs util-linux-mcookie util-linux-reset util-linux-uuidd \
45 util-linux-mkfs.cramfs util-linux-fsck.cramfs \
46 util-linux-partx ${PN}-bash-completion"
47
48EXTRA_OECONF = "--libdir=${base_libdir} --disable-use-tty-group \
49 --disable-makeinstall-chown --enable-elvtune --enable-init \
50 --enable-kill --enable-last --enable-mesg --enable-partx \
51 --enable-raw --enable-rdev --enable-reset --disable-login \
52 --disable-vipw --disable-newgrp --disable-chfn-chsh \
53 --enable-write --enable-arch --enable-mount --with-fsprobe=builtin \
54 --enable-libuuid --enable-libblkid --enable-fsck --without-udev \
55 usrsbin_execdir='${sbindir}' \
56"
57PACKAGECONFIG_class-target ?= "${@base_contains('DISTRO_FEATURES', 'pam', 'pam', '', d)} \
58 ${@base_contains('DISTRO_FEATURES', 'systemd', 'systemd', '', d)} "
59PACKAGECONFIG[pam] = "--enable-su --enable-runuser,--disable-su --disable-runuser, libpam,"
60
61# Respect the systemd feature for uuidd
62PACKAGECONFIG[systemd] = "--enable-socket-activation --with-systemdsystemunitdir=${systemd_unitdir}/system/, --disable-socket-activation --without-systemdsystemunitdir"
63
64FILES_${PN}-bash-completion += "${datadir}/bash-completion"
65FILES_${PN}-doc += "${datadir}/getopt/getopt-*.*"
66
67FILES_util-linux-agetty = "${base_sbindir}/agetty"
68FILES_util-linux-fdisk = "${base_sbindir}/fdisk.${BPN}"
69FILES_util-linux-cfdisk = "${base_sbindir}/cfdisk"
70FILES_util-linux-sfdisk = "${sbindir}/sfdisk"
71FILES_util-linux-swaponoff = "${base_sbindir}/swapon.${BPN} ${base_sbindir}/swapoff.${BPN}"
72FILES_util-linux-losetup = "${base_sbindir}/losetup.${BPN}"
73FILES_util-linux-mount = "${base_bindir}/mount.${BPN}"
74FILES_util-linux-mcookie = "${bindir}/mcookie"
75FILES_util-linux-umount = "${base_bindir}/umount.${BPN}"
76FILES_util-linux-readprofile = "${base_sbindir}/readprofile.${BPN}"
77FILES_util-linux-uuidgen = "${bindir}/uuidgen"
78FILES_util-linux-uuidd = "${sbindir}/uuidd"
79FILES_util-linux-reset = "${base_bindir}/reset"
80FILES_util-linux-partx = "${sbindir}/partx"
81
82FILES_util-linux-libblkid = "${base_libdir}/libblkid.so.*"
83FILES_util-linux-libblkid-dev = "${base_libdir}/libblkid.so ${base_libdir}/libblkid.la ${includedir}/blkid ${libdir}/pkgconfig/blkid.pc"
84FILES_util-linux-libmount = "${base_libdir}/libmount.so.*"
85FILES_util-linux-libmount-dev = "${base_libdir}/libmount.so ${base_libdir}/libmount.la ${includedir}/libmount ${libdir}/pkgconfig/mount.pc"
86FILES_util-linux-libuuid = "${base_libdir}/libuuid.so.*"
87FILES_util-linux-libuuid-dev = "${base_libdir}/libuuid.so ${base_libdir}/libuuid.la ${includedir}/uuid ${libdir}/pkgconfig/uuid.pc"
88FILES_util-linux-lscpu = "${bindir}/lscpu"
89
90FILES_util-linux-fsck = "${base_sbindir}/fsck*"
91FILES_util-linux-mkfs = "${sbindir}/mkfs"
92
93FILES_util-linux-fsck.cramfs = "${sbindir}/fsck.cramfs"
94FILES_util-linux-mkfs.cramfs = "${sbindir}/mkfs.cramfs"
95
96
97# Util-linux' blkid replaces the e2fsprogs one
98FILES_util-linux-blkid = "${base_sbindir}/blkid*"
99RCONFLICTS_util-linux-blkid = "e2fsprogs-blkid"
100RREPLACES_util-linux-blkid = "e2fsprogs-blkid"
101
102# reset calls 'tput'
103RDEPENDS_util-linux-reset += "ncurses"
104
105RDEPENDS_${PN} = "util-linux-umount util-linux-swaponoff util-linux-losetup"
106RRECOMMENDS_${PN} = "util-linux-fdisk util-linux-cfdisk util-linux-sfdisk util-linux-mount util-linux-readprofile util-linux-mkfs "
107
108RRECOMMENDS_${PN}_class-native = ""
109RRECOMMENDS_${PN}_class-nativesdk = ""
110RDEPENDS_${PN}_class-native = ""
111RDEPENDS_${PN}_class-nativesdk = ""
112
113SYSTEMD_PACKAGES = "${PN}-uuidd"
114SYSTEMD_SERVICE_${PN}-uuidd = "uuidd.service"
115
116do_compile () {
117 set -e
118 install ${WORKDIR}/MCONFIG ${S}/MCONFIG
119 install ${WORKDIR}/make_include ${S}/make_include
120 install ${WORKDIR}/swapargs.h ${S}/mount-deprecated/swapargs.h
121 install ${WORKDIR}/defines.h ${S}/defines.h
122 oe_runmake ARCH=${TARGET_ARCH} CPU= CPUOPT= 'OPT=${CFLAGS}'
123}
124
125do_install () {
126 # with ccache the timestamps on compiled files may
127 # end up earlier than on their inputs, this allows
128 # for the resultant compilation in the install step.
129 oe_runmake ARCH=${TARGET_ARCH} CPU= CPUOPT= \
130 'OPT=${CFLAGS}' 'CC=${CC}' 'LD=${LD}' \
131 'LDFLAGS=${LDFLAGS}' 'DESTDIR=${D}' install
132
133 mkdir -p ${D}${base_bindir}
134
135 sbinprogs="agetty ctrlaltdel cfdisk vipw vigr"
136 sbinprogs_a="pivot_root hwclock mkswap mkfs.minix fsck.minix losetup swapon swapoff fdisk readprofile fsck blkid blockdev"
137 usrbinprogs_a="chfn chsh hexdump last logger mesg newgrp renice utmpdump wall setsid chrt flock getopt"
138 binprogs_a="dmesg kill more umount mount login reset su"
139
140 if [ "${base_sbindir}" != "${sbindir}" ]; then
141 mkdir -p ${D}${base_sbindir}
142 for p in $sbinprogs $sbinprogs_a; do
143 if [ -f "${D}${sbindir}/$p" ]; then
144 mv "${D}${sbindir}/$p" "${D}${base_sbindir}/$p"
145 fi
146 done
147 fi
148
149 if [ "${base_bindir}" != "${bindir}" ]; then
150 mkdir -p ${D}${base_bindir}
151 for p in $binprogs_a; do
152 if [ -f "${D}${bindir}/$p" ]; then
153 mv "${D}${bindir}/$p" "${D}${base_bindir}/$p"
154 fi
155 done
156 fi
157
158 install -d ${D}${sysconfdir}/default/
159 echo 'MOUNTALL="-t nonfs,nosmbfs,noncpfs"' > ${D}${sysconfdir}/default/mountall
160
161 rm -f ${D}${bindir}/chkdupexe
162}
163
164inherit update-alternatives
165
166ALTERNATIVE_PRIORITY = "100"
167
168ALTERNATIVE_${PN} = "dmesg kill more mkswap blockdev pivot_root"
169ALTERNATIVE_${PN} += "mkfs.minix hexdump last logger mesg renice wall"
170ALTERNATIVE_${PN} += "setsid chrt flock hwclock utmpdump eject getopt"
171
172ALTERNATIVE_LINK_NAME[dmesg] = "${base_bindir}/dmesg"
173ALTERNATIVE_LINK_NAME[kill] = "${base_bindir}/kill"
174ALTERNATIVE_LINK_NAME[more] = "${base_bindir}/more"
175ALTERNATIVE_LINK_NAME[mkswap] = "${base_sbindir}/mkswap"
176ALTERNATIVE_LINK_NAME[blockdev] = "${base_sbindir}/blockdev"
177ALTERNATIVE_LINK_NAME[pivot_root] = "${base_sbindir}/pivot_root"
178ALTERNATIVE_LINK_NAME[mkfs.minix] = "${base_sbindir}/mkfs.minix"
179ALTERNATIVE_LINK_NAME[eject] = "${bindir}/eject"
180ALTERNATIVE_LINK_NAME[getopt] = "${base_bindir}/getopt"
181ALTERNATIVE_TARGET[getopt] = "${bindir}/getopt"
182
183ALTERNATIVE_${PN}-doc = "mountpoint.1 last.1 mesg.1 wall.1 sulogin.8 utmpdump.1"
184
185ALTERNATIVE_LINK_NAME[last.1] = "${mandir}/man1/last.1"
186ALTERNATIVE_LINK_NAME[mesg.1] = "${mandir}/man1/mesg.1"
187ALTERNATIVE_LINK_NAME[mountpoint.1] = "${mandir}/man1/mountpoint.1"
188ALTERNATIVE_LINK_NAME[sulogin.8] = "${mandir}/man8/sulogin.8"
189ALTERNATIVE_LINK_NAME[utmpdump.1] = "${mandir}/man1/utmpdump.1"
190ALTERNATIVE_LINK_NAME[wall.1] = "${mandir}/man1/wall.1"
191
192# There seems to be problem, atleast on nslu2, with these, untill they are
193# fixed the busybox ones have higher priority
194ALTERNATIVE_PRIORITY[hwclock] = "10"
195ALTERNATIVE_LINK_NAME[hwclock] = "${base_sbindir}/hwclock"
196
197ALTERNATIVE_util-linux-fdisk = "fdisk"
198ALTERNATIVE_LINK_NAME[fdisk] = "${base_sbindir}/fdisk"
199
200ALTERNATIVE_util-linux-agetty = "getty"
201ALTERNATIVE_LINK_NAME[getty] = "${base_sbindir}/getty"
202ALTERNATIVE_TARGET[getty] = "${base_sbindir}/agetty"
203
204ALTERNATIVE_util-linux-mount = "mount"
205ALTERNATIVE_LINK_NAME[mount] = "${base_bindir}/mount"
206
207ALTERNATIVE_util-linux-umount = "umount"
208ALTERNATIVE_LINK_NAME[umount] = "${base_bindir}/umount"
209
210ALTERNATIVE_util-linux-losetup = "losetup"
211ALTERNATIVE_LINK_NAME[losetup] = "${base_sbindir}/losetup"
212
213ALTERNATIVE_util-linux-swaponoff = "swapoff swapon"
214ALTERNATIVE_LINK_NAME[swapoff] = "${base_sbindir}/swapoff"
215ALTERNATIVE_LINK_NAME[swapon] = "${base_sbindir}/swapon"
216
217ALTERNATIVE_util-linux-fsck = "fsck.minix fsck"
218ALTERNATIVE_LINK_NAME[fsck.minix] = "${base_sbindir}/fsck.minix"
219ALTERNATIVE_LINK_NAME[fsck] = "${base_sbindir}/fsck"
220
221ALTERNATIVE_util-linux-blkid = "blkid"
222ALTERNATIVE_LINK_NAME[blkid] = "${base_sbindir}/blkid"
223
224ALTERNATIVE_util-linux-reset = "reset"
225ALTERNATIVE_LINK_NAME[reset] = "${bindir}/reset"
226ALTERNATIVE_TARGET[reset] = "${base_bindir}/reset"
227
228BBCLASSEXTEND = "native nativesdk"
229
230python do_package_prepend () {
231 if '--enable-su' in d.getVar('EXTRA_OECONF', True).split():
232 alt_name = "su"
233 d.setVarFlag('ALTERNATIVE_LINK_NAME', alt_name, '%s/%s' % (d.getVar('base_bindir', True), alt_name))
234 d.appendVar('ALTERNATIVE_%s' % (d.getVar('PN', True)), ' ' + alt_name)
235}
236
237do_compile_ptest() {
238 oe_runmake buildtest-TESTS
239}
240
241do_install_ptest() {
242 mkdir -p ${D}${PTEST_PATH}/tests/ts
243 find . -maxdepth 1 -type f -perm -111 -exec cp {} ${D}${PTEST_PATH} \;
244 cp ${S}/tests/functions.sh ${D}${PTEST_PATH}/tests/
245 cp ${S}/tests/commands.sh ${D}${PTEST_PATH}/tests/
246 cp ${S}/tests/run.sh ${D}${PTEST_PATH}/tests/
247 cp -pR ${S}/tests/expected ${D}${PTEST_PATH}/tests/expected
248
249 list="bitops build-sys cal col colrm column dmesg fsck hexdump hwclock ipcs isosize login look lscpu md5 misc more namei paths schedutils script swapon tailf utmpdump"
250 # The following tests are not installed yet:
251 # blkid scsi_debug module dependent
252 # cramfs gcc dependent
253 # eject gcc dependent
254 # fdisk scsi_debug module and gcc dependent
255 # libmount uuidgen dependent
256 # mount gcc dependant
257 # partx blkid dependant
258 for d in $list; do
259 cp -pR ${S}/tests/ts/$d ${D}${PTEST_PATH}/tests/ts/
260 done
261}