diff options
Diffstat (limited to 'meta/recipes-core/systemd/systemd-boot_246.bb')
-rw-r--r-- | meta/recipes-core/systemd/systemd-boot_246.bb | 70 |
1 files changed, 70 insertions, 0 deletions
diff --git a/meta/recipes-core/systemd/systemd-boot_246.bb b/meta/recipes-core/systemd/systemd-boot_246.bb new file mode 100644 index 0000000000..f92c639810 --- /dev/null +++ b/meta/recipes-core/systemd/systemd-boot_246.bb | |||
@@ -0,0 +1,70 @@ | |||
1 | require systemd.inc | ||
2 | FILESEXTRAPATHS =. "${FILE_DIRNAME}/systemd:" | ||
3 | |||
4 | require conf/image-uefi.conf | ||
5 | |||
6 | DEPENDS = "intltool-native libcap util-linux gnu-efi gperf-native" | ||
7 | |||
8 | inherit meson pkgconfig gettext | ||
9 | inherit deploy | ||
10 | |||
11 | LDFLAGS_prepend = "${@ " ".join(d.getVar('LD').split()[1:])} " | ||
12 | |||
13 | do_write_config[vardeps] += "CC OBJCOPY" | ||
14 | do_write_config_append() { | ||
15 | cat >${WORKDIR}/meson-${PN}.cross <<EOF | ||
16 | [binaries] | ||
17 | efi_cc = ${@meson_array('CC', d)} | ||
18 | objcopy = ${@meson_array('OBJCOPY', d)} | ||
19 | EOF | ||
20 | } | ||
21 | |||
22 | EXTRA_OEMESON += "-Defi=true \ | ||
23 | -Dgnu-efi=true \ | ||
24 | -Defi-includedir=${STAGING_INCDIR}/efi \ | ||
25 | -Defi-libdir=${STAGING_LIBDIR} \ | ||
26 | -Defi-ld=${@ d.getVar('LD').split()[0]} \ | ||
27 | -Dman=false \ | ||
28 | --cross-file ${WORKDIR}/meson-${PN}.cross \ | ||
29 | " | ||
30 | |||
31 | # install to the image as boot*.efi if its the EFI_PROVIDER, | ||
32 | # otherwise install as the full name. | ||
33 | # This allows multiple bootloaders to coexist in a single image. | ||
34 | python __anonymous () { | ||
35 | import re | ||
36 | target = d.getVar('TARGET_ARCH') | ||
37 | prefix = "" if d.getVar('EFI_PROVIDER') == "systemd-boot" else "systemd-" | ||
38 | systemdimage = prefix + d.getVar("EFI_BOOT_IMAGE") | ||
39 | d.setVar("SYSTEMD_BOOT_IMAGE", systemdimage) | ||
40 | prefix = "systemd-" if prefix == "" else "" | ||
41 | d.setVar("SYSTEMD_BOOT_IMAGE_PREFIX", prefix) | ||
42 | } | ||
43 | |||
44 | FILES_${PN} = "${EFI_FILES_PATH}/${SYSTEMD_BOOT_IMAGE}" | ||
45 | |||
46 | RDEPENDS_${PN} += "virtual/systemd-bootconf" | ||
47 | |||
48 | # Imported from the old gummiboot recipe | ||
49 | TUNE_CCARGS_remove = "-mfpmath=sse" | ||
50 | COMPATIBLE_HOST = "(x86_64.*|i.86.*)-linux" | ||
51 | COMPATIBLE_HOST_x86-x32 = "null" | ||
52 | |||
53 | do_compile() { | ||
54 | SYSTEMD_BOOT_EFI_ARCH="ia32" | ||
55 | if [ "${TARGET_ARCH}" = "x86_64" ]; then | ||
56 | SYSTEMD_BOOT_EFI_ARCH="x64" | ||
57 | fi | ||
58 | |||
59 | ninja src/boot/efi/${SYSTEMD_BOOT_IMAGE_PREFIX}${SYSTEMD_BOOT_IMAGE} | ||
60 | } | ||
61 | |||
62 | do_install() { | ||
63 | install -d ${D}${EFI_FILES_PATH} | ||
64 | install ${B}/src/boot/efi/systemd-boot*.efi ${D}${EFI_FILES_PATH}/${SYSTEMD_BOOT_IMAGE} | ||
65 | } | ||
66 | |||
67 | do_deploy () { | ||
68 | install ${B}/src/boot/efi/systemd-boot*.efi ${DEPLOYDIR} | ||
69 | } | ||
70 | addtask deploy before do_build after do_compile | ||