1 files changed, 26 insertions, 10 deletions

diff --git a/meta/recipes-core/gettext/gettext-minimal-native_0.21.1.bb b/meta/recipes-core/gettext/gettext-minimal-native_0.21.1.bb
index 7a4dcbec57..db1bbb7e68 100644
--- a/meta/recipes-core/gettext/gettext-minimal-native_0.21.1.bb
+++ b/meta/recipes-core/gettext/gettext-minimal-native_0.21.1.bb
@@ -3,10 +3,9 @@ DESCRIPTION = "Contains the m4 macros sufficient to support building \
 autoconf/automake. This provides a significant build time speedup by \
 the removal of gettext-native from most dependency chains (now only \
 needed for gettext for the target)."
-SRC_URI = "file://aclocal/ \
-           file://config.rpath \
-           file://Makefile.in.in \
-           file://remove-potcdate.sin \
+
+require gettext-sources.inc
+SRC_URI += " \
            file://COPYING \
 "
 
@@ -14,17 +13,34 @@ INHIBIT_DEFAULT_DEPS = "1"
 INHIBIT_AUTOTOOLS_DEPS = "1"
 
 LICENSE = "FSF-Unlimited"
-LIC_FILES_CHKSUM = "file://COPYING;md5=4bd090a20bfcd1a18f1f79837b5e3e91"
+LIC_FILES_CHKSUM = "file://../COPYING;md5=4bd090a20bfcd1a18f1f79837b5e3e91"
 
 inherit native
 
-S = "${WORKDIR}"
+S = "${WORKDIR}/gettext-${PV}"
+
+python get_aclocal_files() {
+    fpath = oe.path.join(d.getVar("S"), "/gettext-tools/m4/Makefile.am")
+    with open(fpath) as f:
+        content = f.read()
+        for l in content.replace("\\\n","").split("\n"):
+            if l.startswith("aclocal_DATA"):
+                aclocal_files = l.split("=")[1]
+                with open(oe.path.join(d.getVar("WORKDIR"),"aclocal-files"),'w') as outf:
+                    outf.write(aclocal_files)
+                break
+        else:
+            bb.error("Could not obtain list of installed aclocal files from {}".format(fpath))
+}
+do_install[prefuncs] += "get_aclocal_files"
 
 do_install () {
         install -d ${D}${datadir}/aclocal/
-        cp ${WORKDIR}/aclocal/*.m4 ${D}${datadir}/aclocal/
+        for i in `cat ${WORKDIR}/aclocal-files`; do
+                cp ${S}/gettext-tools/m4/$i ${D}${datadir}/aclocal/
+        done
         install -d ${D}${datadir}/gettext/po/
-        cp ${WORKDIR}/config.rpath ${D}${datadir}/gettext/
-        cp ${WORKDIR}/Makefile.in.in ${D}${datadir}/gettext/po/
-        cp ${WORKDIR}/remove-potcdate.sin ${D}${datadir}/gettext/po/
+        cp ${S}/build-aux/config.rpath ${D}${datadir}/gettext/
+        cp ${S}/gettext-runtime/po/Makefile.in.in ${D}${datadir}/gettext/po/
+        cp ${S}/gettext-runtime/po/remove-potcdate.sin ${D}${datadir}/gettext/po/
 }