summaryrefslogtreecommitdiffstats
path: root/meta/recipes-core/eglibc/eglibc_2.18.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-core/eglibc/eglibc_2.18.bb')
-rw-r--r--meta/recipes-core/eglibc/eglibc_2.18.bb148
1 files changed, 148 insertions, 0 deletions
diff --git a/meta/recipes-core/eglibc/eglibc_2.18.bb b/meta/recipes-core/eglibc/eglibc_2.18.bb
new file mode 100644
index 0000000000..710b498a4d
--- /dev/null
+++ b/meta/recipes-core/eglibc/eglibc_2.18.bb
@@ -0,0 +1,148 @@
1require eglibc.inc
2
3DEPENDS += "gperf-native kconfig-frontends-native"
4
5SRC_URI = "http://downloads.yoctoproject.org/releases/eglibc/eglibc-${PV}-svnr23787.tar.bz2 \
6 file://eglibc-svn-arm-lowlevellock-include-tls.patch \
7 file://IO-acquire-lock-fix.patch \
8 file://mips-rld-map-check.patch \
9 file://etc/ld.so.conf \
10 file://generate-supported.mk \
11 file://glibc.fix_sqrt2.patch \
12 file://multilib_readlib.patch \
13 file://ppc-sqrt_finite.patch \
14 file://GLRO_dl_debug_mask.patch \
15 file://initgroups_keys.patch \
16 file://eglibc_fix_findidx_parameters.patch \
17 file://ppc_slow_ieee754_sqrt.patch \
18 file://fileops-without-wchar-io.patch \
19 file://add_resource_h_to_wait_h.patch \
20 file://0001-eglibc-menuconfig-support.patch \
21 file://0002-eglibc-menuconfig-hex-string-options.patch \
22 file://0003-eglibc-menuconfig-build-instructions.patch \
23 file://fsl-ppc-no-fsqrt.patch \
24 file://0001-R_ARM_TLS_DTPOFF32.patch \
25 file://tzselect-sh.patch \
26 file://tzselect-awk.patch \
27 file://0001-eglibc-run-libm-err-tab.pl-with-specific-dirs-in-S.patch \
28 file://fix-tibetian-locales.patch \
29 file://0001-ARM-Pass-dl_hwcap-to-IFUNC-resolver.patch \
30 "
31SRC_URI[md5sum] = "b395b021422a027d89884992e91734fc"
32SRC_URI[sha256sum] = "15f564b45dc5dd65faf0875579e3447961ae61e876933384ae05d19328539ad4"
33
34LIC_FILES_CHKSUM = "file://LICENSES;md5=e9a558e243b36d3209f380deb394b213 \
35 file://COPYING;md5=393a5ca445f6965873eca0259a17f833 \
36 file://posix/rxspencer/COPYRIGHT;md5=dc5485bb394a13b2332ec1c785f5d83a \
37 file://COPYING.LIB;md5=bbb461211a33b134d42ed5ee802b37ff "
38
39SRC_URI_append_class-nativesdk = " file://ld-search-order.patch \
40 file://relocatable_sdk.patch \
41 file://relocatable_sdk_fix_openpath.patch \
42 "
43S = "${WORKDIR}/eglibc-${PV}/libc"
44B = "${WORKDIR}/build-${TARGET_SYS}"
45
46PACKAGES_DYNAMIC = ""
47
48# the -isystem in bitbake.conf screws up glibc do_stage
49BUILD_CPPFLAGS = "-I${STAGING_INCDIR_NATIVE}"
50TARGET_CPPFLAGS = "-I${STAGING_DIR_TARGET}${includedir}"
51
52GLIBC_BROKEN_LOCALES = " _ER _ET so_ET yn_ER sid_ET tr_TR mn_MN gez_ET gez_ER bn_BD te_IN es_CR.ISO-8859-1"
53
54FILESPATH = "${@base_set_filespath([ '${FILE_DIRNAME}/eglibc-${PV}', '${FILE_DIRNAME}/eglibc', '${FILE_DIRNAME}/files', '${FILE_DIRNAME}' ], d)}"
55
56#
57# For now, we will skip building of a gcc package if it is a uclibc one
58# and our build is not a uclibc one, and we skip a glibc one if our build
59# is a uclibc build.
60#
61# See the note in gcc/gcc_3.4.0.oe
62#
63
64python __anonymous () {
65 import re
66 uc_os = (re.match('.*uclibc$', d.getVar('TARGET_OS', True)) != None)
67 if uc_os:
68 raise bb.parse.SkipPackage("incompatible with target %s" %
69 d.getVar('TARGET_OS', True))
70}
71
72export libc_cv_slibdir = "${base_libdir}"
73
74EXTRA_OECONF = "--enable-kernel=${OLDEST_KERNEL} \
75 --without-cvs --disable-profile \
76 --disable-debug --without-gd \
77 --enable-clocale=gnu \
78 --enable-add-ons \
79 --with-headers=${STAGING_INCDIR} \
80 --without-selinux \
81 --enable-obsolete-rpc \
82 --with-kconfig=${STAGING_BINDIR_NATIVE} \
83 ${GLIBC_EXTRA_OECONF}"
84
85EXTRA_OECONF += "${@get_libc_fpu_setting(bb, d)}"
86
87do_patch_append() {
88 bb.build.exec_func('do_fix_readlib_c', d)
89}
90
91# for mips eglibc now builds syscall tables for all abi's
92# so we make sure that we choose right march option which is
93# compatible with o32,n32 and n64 abi's
94# e.g. -march=mips32 is not compatible with n32 and n64 therefore
95# we filter it out in such case -march=from-abi which will be
96# mips1 when using o32 and mips3 when using n32/n64
97
98TUNE_CCARGS_mips := "${@oe_filter_out('-march=mips32', '${TUNE_CCARGS}', d)}"
99TUNE_CCARGS_mipsel := "${@oe_filter_out('-march=mips32', '${TUNE_CCARGS}', d)}"
100
101do_fix_readlib_c () {
102 sed -i -e 's#OECORE_KNOWN_INTERPRETER_NAMES#${EGLIBC_KNOWN_INTERPRETER_NAMES}#' ${S}/elf/readlib.c
103}
104
105do_configure () {
106# override this function to avoid the autoconf/automake/aclocal/autoheader
107# calls for now
108# don't pass CPPFLAGS into configure, since it upsets the kernel-headers
109# version check and doesn't really help with anything
110 if [ -z "`which rpcgen`" ]; then
111 echo "rpcgen not found. Install glibc-devel."
112 exit 1
113 fi
114 (cd ${S} && gnu-configize) || die "failure in running gnu-configize"
115 find ${S} -name "configure" | xargs touch
116 CPPFLAGS="" oe_runconf
117}
118
119rpcsvc = "bootparam_prot.x nlm_prot.x rstat.x \
120 yppasswd.x klm_prot.x rex.x sm_inter.x mount.x \
121 rusers.x spray.x nfs_prot.x rquota.x key_prot.x"
122
123do_compile () {
124 # -Wl,-rpath-link <staging>/lib in LDFLAGS can cause breakage if another glibc is in staging
125 unset LDFLAGS
126 base_do_compile
127 (
128 cd ${S}/sunrpc/rpcsvc
129 for r in ${rpcsvc}; do
130 h=`echo $r|sed -e's,\.x$,.h,'`
131 rpcgen -h $r -o $h || bbwarn "unable to generate header for $r"
132 done
133 )
134 echo "Adjust ldd script"
135 if [ -n "${RTLDLIST}" ]
136 then
137 prevrtld=`cat ${B}/elf/ldd | grep "^RTLDLIST=" | sed 's#^RTLDLIST="\?\([^"]*\)"\?$#\1#'`
138 if [ "${prevrtld}" != "${RTLDLIST}" ]
139 then
140 sed -i ${B}/elf/ldd -e "s#^RTLDLIST=.*\$#RTLDLIST=\"${prevrtld} ${RTLDLIST}\"#"
141 fi
142 fi
143
144}
145
146require eglibc-package.inc
147
148BBCLASSEXTEND = "nativesdk"