summaryrefslogtreecommitdiffstats
path: root/meta/recipes-core/coreutils/coreutils_8.22.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-core/coreutils/coreutils_8.22.bb')
-rw-r--r--meta/recipes-core/coreutils/coreutils_8.22.bb101
1 files changed, 101 insertions, 0 deletions
diff --git a/meta/recipes-core/coreutils/coreutils_8.22.bb b/meta/recipes-core/coreutils/coreutils_8.22.bb
new file mode 100644
index 0000000..ba3a0a0
--- /dev/null
+++ b/meta/recipes-core/coreutils/coreutils_8.22.bb
@@ -0,0 +1,101 @@
1SUMMARY = "The basic file, shell and text manipulation utilities"
2DESCRIPTION = "The GNU Core Utilities provide the basic file, shell and text \
3manipulation utilities. These are the core utilities which are expected to exist on \
4every system."
5HOMEPAGE = "http://www.gnu.org/software/coreutils/"
6BUGTRACKER = "http://debbugs.gnu.org/coreutils"
7LICENSE = "GPLv3+"
8LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504\
9 file://src/ls.c;beginline=5;endline=16;md5=38b79785ca88537b75871782a2a3c6b8"
10DEPENDS = "gmp libcap"
11DEPENDS_class-native = ""
12
13inherit autotools gettext
14
15SRC_URI = "${GNU_MIRROR}/coreutils/${BP}.tar.xz \
16 file://remove-usr-local-lib-from-m4.patch \
17 file://dummy_help2man.patch \
18 file://fix-for-dummy-man-usage.patch \
19 "
20
21SRC_URI[md5sum] = "8fb0ae2267aa6e728958adc38f8163a2"
22SRC_URI[sha256sum] = "5b3e94998152c017e6c75d56b9b994188eb71bf46d4038a642cb9141f6ff1212"
23
24EXTRA_OECONF_class-native = "--without-gmp"
25EXTRA_OECONF_class-target = "--enable-install-program=arch --libexecdir=${libdir}"
26
27# acl is not a default feature
28#
29PACKAGECONFIG_class-target ??= "${@base_contains('DISTRO_FEATURES', 'acl', 'acl', '', d)}"
30PACKAGECONFIG_class-native ??= ""
31
32# with, without, depends, rdepends
33#
34PACKAGECONFIG[acl] = "--enable-acl,--disable-acl,acl,"
35
36# [ df mktemp base64 gets a special treatment and is not included in this
37bindir_progs = "arch basename chcon cksum comm csplit cut dir dircolors dirname du \
38 env expand expr factor fmt fold groups head hostid id install \
39 join link logname md5sum mkfifo nice nl nohup nproc od paste pathchk \
40 pinky pr printenv printf ptx readlink realpath runcon seq sha1sum sha224sum sha256sum \
41 sha384sum sha512sum shred shuf sort split stdbuf sum tac tail tee test timeout\
42 tr truncate tsort tty unexpand uniq unlink uptime users vdir wc who whoami yes"
43
44# hostname gets a special treatment and is not included in this
45base_bindir_progs = "cat chgrp chmod chown cp date dd echo false kill ln ls mkdir \
46 mknod mv pwd rm rmdir sleep stty sync touch true uname stat"
47
48sbindir_progs= "chroot"
49
50# Let aclocal use the relative path for the m4 file rather than the
51# absolute since coreutils has a lot of m4 files, otherwise there might
52# be an "Argument list too long" error when it is built in a long/deep
53# directory.
54acpaths = "-I ./m4"
55
56# Deal with a separate builddir failure if src doesn't exist when creating version.c/version.h
57do_compile_prepend () {
58 mkdir -p ${B}/src
59}
60
61do_install_append() {
62 for i in df mktemp base64; do mv ${D}${bindir}/$i ${D}${bindir}/$i.${BPN}; done
63
64 install -d ${D}${base_bindir}
65 [ "${base_bindir}" != "${bindir}" ] && for i in ${base_bindir_progs}; do mv ${D}${bindir}/$i ${D}${base_bindir}/$i.${BPN}; done
66
67 install -d ${D}${sbindir}
68 [ "${sbindir}" != "${bindir}" ] && for i in ${sbindir_progs}; do mv ${D}${bindir}/$i ${D}${sbindir}/$i.${BPN}; done
69
70 # [ requires special handling because [.coreutils will cause the sed stuff
71 # in update-alternatives to fail, therefore use lbracket - the name used
72 # for the actual source file.
73 mv ${D}${bindir}/[ ${D}${bindir}/lbracket.${BPN}
74}
75
76inherit update-alternatives
77
78ALTERNATIVE_PRIORITY = "100"
79ALTERNATIVE_${PN} = "lbracket ${bindir_progs} ${base_bindir_progs} ${sbindir_progs} base64 mktemp df"
80
81ALTERNATIVE_LINK_NAME[base64] = "${base_bindir}/base64"
82ALTERNATIVE_TARGET[base64] = "${bindir}/base64.${BPN}"
83
84ALTERNATIVE_LINK_NAME[mktemp] = "${base_bindir}/mktemp"
85ALTERNATIVE_TARGET[mktemp] = "${bindir}/mktemp.${BPN}"
86
87ALTERNATIVE_LINK_NAME[df] = "${base_bindir}/df"
88ALTERNATIVE_TARGET[df] = "${bindir}/df.${BPN}"
89
90ALTERNATIVE_LINK_NAME[lbracket] = "${bindir}/["
91ALTERNATIVE_TARGET[lbracket] = "${bindir}/lbracket.${BPN}"
92
93python __anonymous() {
94 for prog in d.getVar('base_bindir_progs', True).split():
95 d.setVarFlag('ALTERNATIVE_LINK_NAME', prog, '%s/%s' % (d.getVar('base_bindir', True), prog))
96
97 for prog in d.getVar('sbindir_progs', True).split():
98 d.setVarFlag('ALTERNATIVE_LINK_NAME', prog, '%s/%s' % (d.getVar('sbindir', True), prog))
99}
100
101BBCLASSEXTEND = "native"