summaryrefslogtreecommitdiffstats
path: root/meta/recipes-core/coreutils/coreutils_6.9.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-core/coreutils/coreutils_6.9.bb')
-rw-r--r--meta/recipes-core/coreutils/coreutils_6.9.bb106
1 files changed, 106 insertions, 0 deletions
diff --git a/meta/recipes-core/coreutils/coreutils_6.9.bb b/meta/recipes-core/coreutils/coreutils_6.9.bb
new file mode 100644
index 0000000000..debd2a123b
--- /dev/null
+++ b/meta/recipes-core/coreutils/coreutils_6.9.bb
@@ -0,0 +1,106 @@
1SUMMARY = "The basic file, shell and text manipulation utilities"
2DESCRIPTION = "The GNU Core Utilities provide the basic file, shell and text \
3manipulation utilities. These are the core utilities which are expected to exist on \
4every system."
5
6HOMEPAGE = "http://www.gnu.org/software/coreutils/"
7BUGTRACKER = "http://debbugs.gnu.org/coreutils"
8LICENSE = "GPLv2+"
9LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe \
10 file://src/ls.c;beginline=4;endline=16;md5=15ed60f67b1db5fedd5dbc37cf8a9543"
11PR = "r5"
12DEPENDS_class-native = "gettext-native"
13
14inherit autotools gettext texinfo
15
16SRC_URI_BASE = "${GNU_MIRROR}/coreutils/${BP}.tar.bz2 \
17 file://gnulib_m4.patch \
18 file://futimens.patch \
19 file://coreutils-ls-x.patch \
20 file://coreutils-6.9-cp-i-u.patch \
21 file://coreutils-i18n.patch \
22 file://coreutils-overflow.patch \
23 file://coreutils-fix-install.patch \
24 file://man-touch.patch \
25 file://coreutils_fix_for_automake-1.12.patch \
26 file://coreutils-build-with-acl.patch \
27 file://coreutils-fix-texinfo.patch \
28 "
29
30SRC_URI = "${SRC_URI_BASE} file://fix_for_manpage_building.patch"
31SRC_URI_class-native = "${SRC_URI_BASE}"
32
33SRC_URI[md5sum] = "c9607d8495f16e98906e7ed2d9751a06"
34SRC_URI[sha256sum] = "89c2895ad157de50e53298b22d91db116ee4e1dd3fdf4019260254e2e31497b0"
35
36
37# acl is not a default feature
38#
39PACKAGECONFIG_class-target ??= "${@bb.utils.contains('DISTRO_FEATURES', 'acl', 'acl', '', d)}"
40PACKAGECONFIG_class-native ??= ""
41
42# with, without, depends, rdepends
43#
44PACKAGECONFIG[acl] = "--enable-acl,--disable-acl,acl,"
45
46
47# [ gets a special treatment and is not included in this
48bindir_progs = "base64 basename cksum comm csplit cut dir dircolors dirname du \
49 env expand expr factor fmt fold groups head hostid id install \
50 join link logname md5sum mkfifo nice nl nohup od paste pathchk \
51 pinky pr printenv printf ptx readlink seq sha1sum sha224sum sha256sum \
52 sha384sum sha512sum shred shuf sort split sum tac tail tee test \
53 tr tsort tty unexpand uniq unlink users vdir wc who whoami yes uptime"
54
55# hostname gets a special treatment and is not included in this
56base_bindir_progs = "cat chgrp chmod chown cp date dd echo false kill ln ls mkdir \
57 mknod mv pwd rm rmdir sleep stty sync touch true uname hostname stat"
58
59sbindir_progs= "chroot"
60
61# Let aclocal use the relative path for the m4 file rather than the
62# absolute since coreutils has a lot of m4 files, otherwise there might
63# be an "Argument list too long" error when it is built in a long/deep
64# directory.
65acpaths = "-I ./m4"
66
67do_install() {
68 autotools_do_install
69
70 install -d ${D}${base_bindir}
71 [ "${bindir}" != "${base_bindir}" ] && for i in ${base_bindir_progs}; do mv ${D}${bindir}/$i ${D}${base_bindir}/$i; done
72
73 install -d ${D}${sbindir}
74 [ "${bindir}" != "${sbindir}" ] && for i in ${sbindir_progs}; do mv ${D}${bindir}/$i ${D}${sbindir}/$i; done
75
76 # [ requires special handling because [.coreutils will cause the sed stuff
77 # in update-alternatives to fail, therefore use lbracket - the name used
78 # for the actual source file.
79 mv ${D}${bindir}/[ ${D}${bindir}/lbracket.${BPN}
80
81 # Newer versions of coreutils do not include su, to mimic this behavior
82 # we simply remove it.
83 rm -f ${D}${bindir}/su
84}
85
86inherit update-alternatives
87
88ALTERNATIVE_PRIORITY = "100"
89
90ALTERNATIVE_${PN} = "lbracket ${bindir_progs} ${base_bindir_progs} ${sbindir_progs}"
91
92ALTERNATIVE_PRIORITY[uptime] = "10"
93ALTERNATIVE_PRIORITY[hostname] = "10"
94
95ALTERNATIVE_LINK_NAME[lbracket] = "${bindir}/["
96ALTERNATIVE_TARGET[lbracket] = "${bindir}/lbracket.${BPN}"
97
98python __anonymous() {
99 for prog in d.getVar('base_bindir_progs', True).split():
100 d.setVarFlag('ALTERNATIVE_LINK_NAME', prog, '%s/%s' % (d.getVar('base_bindir', True), prog))
101
102 for prog in d.getVar('sbindir_progs', True).split():
103 d.setVarFlag('ALTERNATIVE_LINK_NAME', prog, '%s/%s' % (d.getVar('sbindir', True), prog))
104}
105
106BBCLASSEXTEND = "native"