summaryrefslogtreecommitdiffstats
path: root/meta/recipes-connectivity/bind/bind_9.9.5.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-connectivity/bind/bind_9.9.5.bb')
-rw-r--r--meta/recipes-connectivity/bind/bind_9.9.5.bb65
1 files changed, 65 insertions, 0 deletions
diff --git a/meta/recipes-connectivity/bind/bind_9.9.5.bb b/meta/recipes-connectivity/bind/bind_9.9.5.bb
new file mode 100644
index 0000000000..604deb6236
--- /dev/null
+++ b/meta/recipes-connectivity/bind/bind_9.9.5.bb
@@ -0,0 +1,65 @@
1SUMMARY = "ISC Internet Domain Name Server"
2HOMEPAGE = "http://www.isc.org/sw/bind/"
3SECTION = "console/network"
4
5LICENSE = "ISC & BSD"
6LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=a3df5f651469919a0e6cb42f84fb6ff1"
7
8DEPENDS = "openssl libcap"
9
10SRC_URI = "ftp://ftp.isc.org/isc/bind9/${PV}/${BPN}-${PV}.tar.gz \
11 file://conf.patch \
12 file://cross-build-fix.patch \
13 file://make-etc-initd-bind-stop-work.patch \
14 file://mips1-not-support-opcode.diff \
15 file://dont-test-on-host.patch \
16 "
17
18SRC_URI[md5sum] = "e676c65cad5234617ee22f48e328c24e"
19SRC_URI[sha256sum] = "d4b64c1dde442145a316679acff2df4008aa117ae52dfa3a6bc69efecc7840d1"
20
21# --enable-exportlib is necessary for building dhcp
22ENABLE_IPV6 = "--enable-ipv6=${@base_contains('DISTRO_FEATURES', 'ipv6', 'yes', 'no', d)}"
23EXTRA_OECONF = " ${ENABLE_IPV6} --with-randomdev=/dev/random --disable-threads \
24 --disable-devpoll --disable-epoll --with-gost=no \
25 --with-gssapi=no --with-ecdsa=yes \
26 --sysconfdir=${sysconfdir}/bind \
27 --with-openssl=${STAGING_LIBDIR}/.. --with-libxml2=${STAGING_LIBDIR}/.. \
28 --enable-exportlib --with-export-includedir=${includedir} --with-export-libdir=${libdir} \
29 "
30inherit autotools-brokensep update-rc.d
31
32INITSCRIPT_NAME = "bind"
33INITSCRIPT_PARAMS = "defaults"
34
35PARALLEL_MAKE = ""
36
37RDEPENDS_${PN} = "python-core"
38
39PACKAGES_prepend = " ${PN}-utils "
40FILES_${PN}-utils = "${bindir}/host ${bindir}/dig"
41FILES_${PN}-dev += "${bindir}/isc-config.h"
42
43do_install_append() {
44 rm "${D}${bindir}/nslookup"
45 rm "${D}${mandir}/man1/nslookup.1"
46 rmdir "${D}${localstatedir}/run"
47 rmdir --ignore-fail-on-non-empty "${D}${localstatedir}"
48 install -d "${D}${sysconfdir}/bind"
49 install -d "${D}${sysconfdir}/init.d"
50 install -m 644 ${S}/conf/* "${D}${sysconfdir}/bind/"
51 install -m 755 "${S}/init.d" "${D}${sysconfdir}/init.d/bind"
52 sed -i -e '1s,#!.*python,#! /usr/bin/env python,' ${D}${sbindir}/dnssec-coverage ${D}${sbindir}/dnssec-checkds
53}
54
55CONFFILES_${PN} = " \
56 ${sysconfdir}/bind/named.conf \
57 ${sysconfdir}/bind/named.conf.local \
58 ${sysconfdir}/bind/named.conf.options \
59 ${sysconfdir}/bind/db.0 \
60 ${sysconfdir}/bind/db.127 \
61 ${sysconfdir}/bind/db.empty \
62 ${sysconfdir}/bind/db.local \
63 ${sysconfdir}/bind/db.root \
64 "
65