summaryrefslogtreecommitdiffstats
path: root/meta/recipes-bsp/u-boot/u-boot.inc
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-bsp/u-boot/u-boot.inc')
-rw-r--r--meta/recipes-bsp/u-boot/u-boot.inc88
1 files changed, 88 insertions, 0 deletions
diff --git a/meta/recipes-bsp/u-boot/u-boot.inc b/meta/recipes-bsp/u-boot/u-boot.inc
new file mode 100644
index 0000000000..f49bb5db1d
--- /dev/null
+++ b/meta/recipes-bsp/u-boot/u-boot.inc
@@ -0,0 +1,88 @@
1SUMMARY = "Universal Boot Loader for embedded devices"
2HOMEPAGE = "http://www.denx.de/wiki/U-Boot/WebHome"
3SECTION = "bootloaders"
4PROVIDES = "virtual/bootloader"
5
6inherit uboot-config deploy
7
8EXTRA_OEMAKE = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${TARGET_PREFIX}gcc ${TOOLCHAIN_OPTIONS}"'
9
10# Allow setting an additional version string that will be picked up by the
11# u-boot build system and appended to the u-boot version. If the .scmversion
12# file already exists it will not be overwritten.
13UBOOT_LOCALVERSION ?= ""
14
15# Some versions of u-boot use .bin and others use .img. By default use .bin
16# but enable individual recipes to change this value.
17UBOOT_SUFFIX ?= "bin"
18UBOOT_IMAGE ?= "u-boot-${MACHINE}-${PV}-${PR}.${UBOOT_SUFFIX}"
19UBOOT_BINARY ?= "u-boot.${UBOOT_SUFFIX}"
20UBOOT_SYMLINK ?= "u-boot-${MACHINE}.${UBOOT_SUFFIX}"
21UBOOT_MAKE_TARGET ?= "all"
22
23# Some versions of u-boot build an SPL (Second Program Loader) image that
24# should be packaged along with the u-boot binary as well as placed in the
25# deploy directory. For those versions they can set the following variables
26# to allow packaging the SPL.
27SPL_BINARY ?= ""
28SPL_IMAGE ?= "${SPL_BINARY}-${MACHINE}-${PV}-${PR}"
29SPL_SYMLINK ?= "${SPL_BINARY}-${MACHINE}"
30
31do_compile () {
32 if [ "${@base_contains('DISTRO_FEATURES', 'ld-is-gold', 'ld-is-gold', '', d)}" = "ld-is-gold" ] ; then
33 sed -i 's/$(CROSS_COMPILE)ld$/$(CROSS_COMPILE)ld.bfd/g' config.mk
34 fi
35
36 unset LDFLAGS
37 unset CFLAGS
38 unset CPPFLAGS
39
40 if [ ! -e ${B}/.scmversion -a ! -e ${S}/.scmversion ]
41 then
42 echo ${UBOOT_LOCALVERSION} > ${B}/.scmversion
43 echo ${UBOOT_LOCALVERSION} > ${S}/.scmversion
44 fi
45
46 oe_runmake ${UBOOT_MACHINE}
47 oe_runmake ${UBOOT_MAKE_TARGET}
48}
49
50do_install () {
51 install -d ${D}/boot
52 install ${S}/${UBOOT_BINARY} ${D}/boot/${UBOOT_IMAGE}
53 ln -sf ${UBOOT_IMAGE} ${D}/boot/${UBOOT_BINARY}
54
55 if [ -e ${WORKDIR}/fw_env.config ] ; then
56 install -d ${D}${sysconfdir}
57 install -m 644 ${WORKDIR}/fw_env.config ${D}${sysconfdir}/fw_env.config
58 fi
59
60 if [ "x${SPL_BINARY}" != "x" ]
61 then
62 install ${S}/${SPL_BINARY} ${D}/boot/${SPL_IMAGE}
63 ln -sf ${SPL_IMAGE} ${D}/boot/${SPL_BINARY}
64 fi
65}
66
67FILES_${PN} = "/boot ${sysconfdir}"
68FILESPATH =. "${FILE_DIRNAME}/u-boot-git/${MACHINE}:"
69
70do_deploy () {
71 install -d ${DEPLOYDIR}
72 install ${S}/${UBOOT_BINARY} ${DEPLOYDIR}/${UBOOT_IMAGE}
73
74 cd ${DEPLOYDIR}
75 rm -f ${UBOOT_BINARY} ${UBOOT_SYMLINK}
76 ln -sf ${UBOOT_IMAGE} ${UBOOT_SYMLINK}
77 ln -sf ${UBOOT_IMAGE} ${UBOOT_BINARY}
78
79 if [ "x${SPL_BINARY}" != "x" ]
80 then
81 install ${S}/${SPL_BINARY} ${DEPLOYDIR}/${SPL_IMAGE}
82 rm -f ${DEPLOYDIR}/${SPL_BINARY} ${DEPLOYDIR}/${SPL_SYMLINK}
83 ln -sf ${SPL_IMAGE} ${DEPLOYDIR}/${SPL_BINARY}
84 ln -sf ${SPL_IMAGE} ${DEPLOYDIR}/${SPL_SYMLINK}
85 fi
86}
87
88addtask deploy before do_build after do_compile