1 files changed, 50 insertions, 0 deletions

diff --git a/meta/recipes-bsp/u-boot/u-boot-fw-utils_2015.01.bb b/meta/recipes-bsp/u-boot/u-boot-fw-utils_2015.01.bb
new file mode 100644
index 0000000000..2b0550cb37
--- /dev/null
+++ b/meta/recipes-bsp/u-boot/u-boot-fw-utils_2015.01.bb
@@ -0,0 +1,50 @@
+SUMMARY = "U-Boot bootloader fw_printenv/setenv utilities"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://Licenses/README;md5=c7383a594871c03da76b3707929d2919"
+SECTION = "bootloader"
+DEPENDS = "mtd-utils"
+
+# This revision corresponds to the tag "v2015.01"
+# We use the revision in order to avoid having to fetch it from the
+# repo during parse
+SRCREV = "92fa7f53f1f3f03296f8ffb14bdf1baefab83368"
+
+PV = "v2015.01+git${SRCPV}"
+
+SRC_URI = "git://git.denx.de/u-boot.git;branch=master;protocol=git \
+           file://0001-tools-env-fix-build-error.patch"
+
+S = "${WORKDIR}/git"
+
+INSANE_SKIP_${PN} = "already-stripped"
+EXTRA_OEMAKE_class-target = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${CC} ${CFLAGS} ${LDFLAGS}" V=1'
+EXTRA_OEMAKE_class-cross = 'ARCH=${TARGET_ARCH} CC="${CC} ${CFLAGS} ${LDFLAGS}" V=1'
+
+inherit uboot-config
+
+do_compile () {
+        oe_runmake ${UBOOT_MACHINE}
+        oe_runmake env
+}
+
+do_install () {
+        install -d ${D}${base_sbindir}
+        install -d ${D}${sysconfdir}
+        install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_printenv
+        install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_setenv
+        install -m 0644 ${S}/tools/env/fw_env.config ${D}${sysconfdir}/fw_env.config
+}
+
+do_install_class-cross () {
+        install -d ${D}${bindir_cross}
+        install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_printenv
+        install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_setenv
+}
+
+SYSROOT_PREPROCESS_FUNCS_class-cross = "uboot_fw_utils_cross"
+uboot_fw_utils_cross() {
+        sysroot_stage_dir ${D}${bindir_cross} ${SYSROOT_DESTDIR}${bindir_cross}
+}
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+BBCLASSEXTEND = "cross"