diff options
Diffstat (limited to 'meta/recipes-bsp/grub/grub-efi_2.00.bb')
-rw-r--r-- | meta/recipes-bsp/grub/grub-efi_2.00.bb | 92 |
1 files changed, 92 insertions, 0 deletions
diff --git a/meta/recipes-bsp/grub/grub-efi_2.00.bb b/meta/recipes-bsp/grub/grub-efi_2.00.bb new file mode 100644 index 0000000000..d213f31a20 --- /dev/null +++ b/meta/recipes-bsp/grub/grub-efi_2.00.bb | |||
@@ -0,0 +1,92 @@ | |||
1 | SUMMARY = "GRUB2 is the next-generation GRand Unified Bootloader" | ||
2 | |||
3 | DESCRIPTION = "GRUB2 is the next generaion of a GPLed bootloader \ | ||
4 | intended to unify bootloading across x86 operating systems. In \ | ||
5 | addition to loading the Linux kernel, it implements the Multiboot \ | ||
6 | standard, which allows for flexible loading of multiple boot images. \ | ||
7 | This recipe builds an EFI binary for the target. It does not install \ | ||
8 | or package anything, it only deploys a target-arch GRUB EFI image." | ||
9 | |||
10 | HOMEPAGE = "http://www.gnu.org/software/grub/" | ||
11 | SECTION = "bootloaders" | ||
12 | |||
13 | LICENSE = "GPLv3" | ||
14 | LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504" | ||
15 | |||
16 | # FIXME: We should be able to optionally drop freetype as a dependency | ||
17 | DEPENDS = "autogen-native flex-native bison-native" | ||
18 | DEPENDS_class-target = "grub-efi-native" | ||
19 | PR = "r2" | ||
20 | |||
21 | SRC_URI = "ftp://ftp.gnu.org/gnu/grub/grub-${PV}.tar.gz \ | ||
22 | file://cfg \ | ||
23 | file://grub-2.00-fpmath-sse-387-fix.patch \ | ||
24 | file://grub-2.00-fix-enable_execute_stack-check.patch \ | ||
25 | file://check-if-liblzma-is-disabled.patch \ | ||
26 | file://grub-no-unused-result.patch \ | ||
27 | file://grub-2.00-ignore-gnulib-gets-stupidity.patch \ | ||
28 | file://fix-issue-with-flex-2.5.37.patch \ | ||
29 | file://grub-efi-allow-a-compilation-without-mcmodel-large.patch \ | ||
30 | file://grub-2.00-add-oe-kernel.patch \ | ||
31 | file://grub-efi-fix-with-glibc-2.20.patch \ | ||
32 | " | ||
33 | SRC_URI[md5sum] = "e927540b6eda8b024fb0391eeaa4091c" | ||
34 | SRC_URI[sha256sum] = "65b39a0558f8c802209c574f4d02ca263a804e8a564bc6caf1cd0fd3b3cc11e3" | ||
35 | |||
36 | COMPATIBLE_HOST = '(x86_64.*|i.86.*)-(linux|freebsd.*)' | ||
37 | |||
38 | S = "${WORKDIR}/grub-${PV}" | ||
39 | |||
40 | # Determine the target arch for the grub modules | ||
41 | python __anonymous () { | ||
42 | import re | ||
43 | target = d.getVar('TARGET_ARCH', True) | ||
44 | if target == "x86_64": | ||
45 | grubtarget = 'x86_64' | ||
46 | grubimage = "bootx64.efi" | ||
47 | elif re.match('i.86', target): | ||
48 | grubtarget = 'i386' | ||
49 | grubimage = "bootia32.efi" | ||
50 | else: | ||
51 | raise bb.parse.SkipPackage("grub-efi is incompatible with target %s" % target) | ||
52 | d.setVar("GRUB_TARGET", grubtarget) | ||
53 | d.setVar("GRUB_IMAGE", grubimage) | ||
54 | } | ||
55 | |||
56 | inherit autotools-brokensep gettext texinfo deploy | ||
57 | |||
58 | CACHED_CONFIGUREVARS += "ac_cv_path_HELP2MAN=" | ||
59 | EXTRA_OECONF = "--with-platform=efi --disable-grub-mkfont \ | ||
60 | --enable-efiemu=no --program-prefix='' \ | ||
61 | --enable-liblzma=no --enable-device-mapper=no --enable-libzfs=no" | ||
62 | |||
63 | do_install_class-target() { | ||
64 | : | ||
65 | } | ||
66 | |||
67 | do_install_class-native() { | ||
68 | install -d ${D}${bindir} | ||
69 | install -m 755 grub-mkimage ${D}${bindir} | ||
70 | } | ||
71 | |||
72 | GRUB_BUILDIN ?= "boot linux ext2 fat serial part_msdos part_gpt normal efi_gop iso9660 search" | ||
73 | |||
74 | do_deploy() { | ||
75 | # Search for the grub.cfg on the local boot media by using the | ||
76 | # built in cfg file provided via this recipe | ||
77 | grub-mkimage -c ../cfg -p /EFI/BOOT -d ./grub-core/ \ | ||
78 | -O ${GRUB_TARGET}-efi -o ./${GRUB_IMAGE} \ | ||
79 | ${GRUB_BUILDIN} | ||
80 | install -m 644 ${B}/${GRUB_IMAGE} ${DEPLOYDIR} | ||
81 | } | ||
82 | |||
83 | do_deploy_class-native() { | ||
84 | : | ||
85 | } | ||
86 | |||
87 | addtask deploy after do_install before do_build | ||
88 | |||
89 | FILES_${PN}-dbg += "${libdir}/${BPN}/${GRUB_TARGET}-efi/.debug" | ||
90 | |||
91 | BBCLASSEXTEND = "native" | ||
92 | ALLOW_EMPTY_${PN} = "1" | ||