1 files changed, 47 insertions, 0 deletions

diff --git a/meta/packages/tcltk/tcl_8.4.19.bb b/meta/packages/tcltk/tcl_8.4.19.bb
new file mode 100644
index 0000000000..33d600bc79
--- /dev/null
+++ b/meta/packages/tcltk/tcl_8.4.19.bb
@@ -0,0 +1,47 @@
+DESCRIPTION = "Tool Command Language"
+LICENSE = "tcl"
+SECTION = "devel/tcltk"
+HOMEPAGE = "http://tcl.sourceforge.net"
+PR = "r3"
+
+SRC_URI = "\
+  ${SOURCEFORGE_MIRROR}/tcl/tcl${PV}-src.tar.gz \
+  file://tcl-add-soname.patch;patch=1;pnum=2"
+
+S = "${WORKDIR}/tcl${PV}/unix"
+
+inherit autotools
+
+EXTRA_OECONF = "--enable-threads"
+
+do_configure() {
+        gnu-configize
+        oe_runconf
+}
+
+do_compile_prepend() {
+        echo > ../compat/fixstrtod.c
+}
+
+do_install() {
+        autotools_do_install
+        oe_libinstall -so libtcl8.4 ${STAGING_LIBDIR}
+        ln -sf ./tclsh8.4 ${D}${bindir}/tclsh
+        sed -i "s+${WORKDIR}+${STAGING_INCDIR}+g" tclConfig.sh
+        sed -i "s,-L${libdir},," tclConfig.sh
+        install -d ${STAGING_BINDIR_CROSS}/
+        install -m 0755 tclConfig.sh ${STAGING_BINDIR_CROSS}
+        cd ..
+        for dir in compat generic unix
+        do
+                install -d ${STAGING_INCDIR}/tcl${PV}/$dir
+                install -m 0644 $dir/*.h ${STAGING_INCDIR}/tcl${PV}/$dir/
+        done
+}
+
+PACKAGES =+ "${PN}-lib"
+FILES_${PN}-lib = "${libdir}/libtcl8.4.so.*"
+FILES_${PN} += "${libdir}/tcl8.4"
+FILES_${PN}-dev += "${libdir}/tclConfig.sh"
+
+BBCLASSEXTEND = "native"