diff options
Diffstat (limited to 'meta/classes/live-vm-common.bbclass')
-rw-r--r-- | meta/classes/live-vm-common.bbclass | 58 |
1 files changed, 58 insertions, 0 deletions
diff --git a/meta/classes/live-vm-common.bbclass b/meta/classes/live-vm-common.bbclass new file mode 100644 index 0000000000..c751385e7d --- /dev/null +++ b/meta/classes/live-vm-common.bbclass | |||
@@ -0,0 +1,58 @@ | |||
1 | # Some of the vars for vm and live image are conflicted, this function | ||
2 | # is used for fixing the problem. | ||
3 | def set_live_vm_vars(d, suffix): | ||
4 | vars = ['GRUB_CFG', 'SYSLINUX_CFG', 'ROOT', 'LABELS', 'INITRD'] | ||
5 | for var in vars: | ||
6 | var_with_suffix = var + '_' + suffix | ||
7 | if d.getVar(var, True): | ||
8 | bb.warn('Found potential conflicted var %s, please use %s rather than %s' % \ | ||
9 | (var, var_with_suffix, var)) | ||
10 | elif d.getVar(var_with_suffix, True): | ||
11 | d.setVar(var, d.getVar(var_with_suffix, True)) | ||
12 | |||
13 | |||
14 | EFI = "${@bb.utils.contains("MACHINE_FEATURES", "efi", "1", "0", d)}" | ||
15 | EFI_PROVIDER ?= "grub-efi" | ||
16 | EFI_CLASS = "${@bb.utils.contains("MACHINE_FEATURES", "efi", "${EFI_PROVIDER}", "", d)}" | ||
17 | |||
18 | # Include legacy boot if MACHINE_FEATURES includes "pcbios" or if it does not | ||
19 | # contain "efi". This way legacy is supported by default if neither is | ||
20 | # specified, maintaining the original behavior. | ||
21 | def pcbios(d): | ||
22 | pcbios = bb.utils.contains("MACHINE_FEATURES", "pcbios", "1", "0", d) | ||
23 | if pcbios == "0": | ||
24 | pcbios = bb.utils.contains("MACHINE_FEATURES", "efi", "0", "1", d) | ||
25 | return pcbios | ||
26 | |||
27 | PCBIOS = "${@pcbios(d)}" | ||
28 | PCBIOS_CLASS = "${@['','syslinux'][d.getVar('PCBIOS', True) == '1']}" | ||
29 | |||
30 | inherit ${EFI_CLASS} | ||
31 | inherit ${PCBIOS_CLASS} | ||
32 | |||
33 | KERNEL_IMAGETYPE ??= "bzImage" | ||
34 | |||
35 | populate_kernel() { | ||
36 | dest=$1 | ||
37 | install -d $dest | ||
38 | |||
39 | # Install bzImage, initrd, and rootfs.img in DEST for all loaders to use. | ||
40 | if [ -e ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE} ]; then | ||
41 | install -m 0644 ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE} $dest/vmlinuz | ||
42 | fi | ||
43 | |||
44 | # initrd is made of concatenation of multiple filesystem images | ||
45 | if [ -n "${INITRD}" ]; then | ||
46 | rm -f $dest/initrd | ||
47 | for fs in ${INITRD} | ||
48 | do | ||
49 | if [ -s "$fs" ]; then | ||
50 | cat $fs >> $dest/initrd | ||
51 | else | ||
52 | bbfatal "$fs is invalid. initrd image creation failed." | ||
53 | fi | ||
54 | done | ||
55 | chmod 0644 $dest/initrd | ||
56 | fi | ||
57 | } | ||
58 | |||