14 files changed, 195 insertions, 0 deletions

diff --git a/meta-openmoko/packages/images/poky-image-openmoko.bb b/meta-openmoko/packages/images/poky-image-openmoko.bb
new file mode 100644
index 0000000000..f1fc5905af
--- /dev/null
+++ b/meta-openmoko/packages/images/poky-image-openmoko.bb
@@ -0,0 +1,20 @@
+#
+# Copyright (C) 2007 OpenedHand Ltd.
+#
+
+PR = "r3"
+
+IMAGE_FEATURES += "apps-console-core ${X11_IMAGE_FEATURES} apps-x11-games"
+
+inherit poky-image
+
+IMAGE_INSTALL += "openmoko-today2 openmoko-dialer2 openmoko-theme-standard2 dates web eds-dbus tasks"
+IMAGE_INSTALL += "openmoko-contacts2 openmoko-session2 \
+    matchbox-keyboard \
+    matchbox-stroke \
+    matchbox-config-gtk \
+    matchbox-themes-gtk \
+    matchbox-applet-startup-monitor \
+    xcursor-transparent-theme \
+    openmoko-icon-theme-standard \
+    settings-daemon"
diff --git a/meta-openmoko/packages/openmoko2/libmokogsmd2_svn.bb b/meta-openmoko/packages/openmoko2/libmokogsmd2_svn.bb
new file mode 100644
index 0000000000..e4baa81054
--- /dev/null
+++ b/meta-openmoko/packages/openmoko2/libmokogsmd2_svn.bb
@@ -0,0 +1,5 @@
+require openmoko-libs.inc
+
+DEPENDS = "libgsmd glib-2.0"
+PR = "r1"
+REAL_PN = "libmokogsmd2"
diff --git a/meta-openmoko/packages/openmoko2/libmokojournal2_svn.bb b/meta-openmoko/packages/openmoko2/libmokojournal2_svn.bb
new file mode 100644
index 0000000000..6730426a3d
--- /dev/null
+++ b/meta-openmoko/packages/openmoko2/libmokojournal2_svn.bb
@@ -0,0 +1,5 @@
+require openmoko-libs.inc
+
+DEPENDS = "eds-dbus"
+PR = "r1"
+REAL_PN = "libmokojournal2"
diff --git a/meta-openmoko/packages/openmoko2/libmokoui2_svn.bb b/meta-openmoko/packages/openmoko2/libmokoui2_svn.bb
new file mode 100644
index 0000000000..b845caa331
--- /dev/null
+++ b/meta-openmoko/packages/openmoko2/libmokoui2_svn.bb
@@ -0,0 +1,5 @@
+require openmoko-libs.inc
+
+DEPENDS = "gtk+"
+PV = "0.0.5+svn${SRCDATE}"
+REAL_PN = "libmokoui2"
diff --git a/meta-openmoko/packages/openmoko2/openmoko-contacts2_svn.bb b/meta-openmoko/packages/openmoko2/openmoko-contacts2_svn.bb
new file mode 100644
index 0000000000..bd872dd79d
--- /dev/null
+++ b/meta-openmoko/packages/openmoko2/openmoko-contacts2_svn.bb
@@ -0,0 +1,12 @@
+require openmoko.inc
+
+DESCRIPTION = "The OpenMoko address book"
+RDEPENDS = "libedata-book"
+PV = "0.1+svn${SRCDATE}"
+PR = "r2"
+
+SRC_URI = "svn://svn.o-hand.com/repos/contacts/branches/;module=hito;proto=http"
+
+S = "${WORKDIR}/hito/"
+
+EXTRA_OECONF = "--disable-gnome-vfs --with-frontend=openmoko"
diff --git a/meta-openmoko/packages/openmoko2/openmoko-dialer2_svn.bb b/meta-openmoko/packages/openmoko2/openmoko-dialer2_svn.bb
new file mode 100644
index 0000000000..38b31eea5d
--- /dev/null
+++ b/meta-openmoko/packages/openmoko2/openmoko-dialer2_svn.bb
@@ -0,0 +1,10 @@
+require openmoko.inc
+
+DESCRIPTION = "The OpenMoko Dialer"
+DEPENDS += "libmokogsmd2 libmokoui2 libmokojournal2"
+REAL_PN = "openmoko-dialer2"
+PR = "r1"
+
+EXTRA_OECONF = "--with-dbusbindir=${STAGING_BINDIR_NATIVE}"
+
+FILES_${PN} += "${datadir}/openmoko-dialer/ ${datadir}/dbus-1/services/"
diff --git a/meta-openmoko/packages/openmoko2/openmoko-icon-theme-standard_svn.bb b/meta-openmoko/packages/openmoko2/openmoko-icon-theme-standard_svn.bb
new file mode 100644
index 0000000000..efc9ce03a5
--- /dev/null
+++ b/meta-openmoko/packages/openmoko2/openmoko-icon-theme-standard_svn.bb
@@ -0,0 +1,19 @@
+DESCRIPTION = "Standard Gtk+ icon theme for the OpenMoko distribution"
+SECTION = "openmoko/base"
+PV = "0.0+svn${SRCDATE}"
+PR = "r1"
+
+inherit openmoko-base autotools
+
+SRC_URI = "${OPENMOKO_MIRROR}/src/target/2007.2/artwork;module=icons;proto=http"
+S = "${WORKDIR}/icons"
+
+PACKAGE_ARCH = "all"
+
+pkg_postinst_${PN} () {
+        if [ "x$D" != "x" ]; then
+                exit 1
+        fi
+        gtk-update-icon-cache -q /usr/share/icons/openmoko-standard
+}
+
diff --git a/meta-openmoko/packages/openmoko2/openmoko-libs.inc b/meta-openmoko/packages/openmoko2/openmoko-libs.inc
new file mode 100644
index 0000000000..9166934fee
--- /dev/null
+++ b/meta-openmoko/packages/openmoko2/openmoko-libs.inc
@@ -0,0 +1,13 @@
+HOMEPAGE = "http://www.openmoko.org"
+LICENSE = "GPL"
+PV = "0.0.1+svn${SRCDATE}"
+
+inherit autotools pkgconfig
+
+SRC_URI = "svn://svn.openmoko.org/trunk/src/target/OM-2007.2/libraries;module=${REAL_PN};proto=http"
+
+S = "${WORKDIR}/${PN}"
+
+do_stage() {
+    autotools_stage_all
+}
diff --git a/meta-openmoko/packages/openmoko2/openmoko-session2.bb b/meta-openmoko/packages/openmoko2/openmoko-session2.bb
new file mode 100644
index 0000000000..38a560461d
--- /dev/null
+++ b/meta-openmoko/packages/openmoko2/openmoko-session2.bb
@@ -0,0 +1,30 @@
+DESCRIPTION = "Custom MB session files for poky"
+LICENSE = "GPL"
+SECTION = "x11"
+RDEPENDS = "matchbox-applet-startup-monitor gtk-sato-engine matchbox-theme-sato gtk-theme-sato matchbox-panel-2 matchbox-desktop-sato"
+RCONFLICTS = "matchbox-common matchbox-sato"
+PR = "r19"
+
+SRC_URI = "file://etc file://matchbox-session"
+S = ${WORKDIR}
+
+do_install() {
+        install -d ${D}/${bindir}
+        install -m 0755 ${S}/matchbox-session ${D}/${bindir}
+        cp -R ${S}/etc ${D}/etc
+        rm -fR ${D}/etc/.svn
+        rm -fR ${D}/etc/matchbox/.svn
+        chmod -R 755 ${D}/etc
+}
+
+pkg_postinst_openmoko-session2 () {
+#!/bin/sh -e
+if [ "x$D" != "x" ]; then
+    exit 1
+fi
+
+gconftool-2 --config-source=xml::$D${sysconfdir}/gconf/gconf.xml.defaults --direct --type string --set /desktop/poky/interface/theme openmoko-standard-2
+gconftool-2 --config-source=xml::$D${sysconfdir}/gconf/gconf.xml.defaults --direct --type string --set /desktop/poky/interface/icon_theme openmoko-standard
+gconftool-2 --config-source=xml::$D${sysconfdir}/gconf/gconf.xml.defaults --direct --type string --set /desktop/poky/interface/font_name "Sans 5"
+gconftool-2 --config-source=xml::$D${sysconfdir}/gconf/gconf.xml.defaults --direct --type int --set /desktop/poky/peripherals/mouse/drag_threshold 8
+}
diff --git a/meta-openmoko/packages/openmoko2/openmoko-session2/etc/matchbox/session b/meta-openmoko/packages/openmoko2/openmoko-session2/etc/matchbox/session
new file mode 100755
index 0000000000..787d9c72ba
--- /dev/null
+++ b/meta-openmoko/packages/openmoko2/openmoko-session2/etc/matchbox/session
@@ -0,0 +1,11 @@
+#!/bin/sh
+
+SHOWCURSOR="no"
+
+openmoko-today &
+openmoko-dialer &
+
+matchbox-window-manager -use_titlebar yes -use_desktop_mode decorated -theme openmoko-standard-2 -use_cursor $SHOWCURSOR $@ &
+
+exec matchbox-panel --start-applets showdesktop --end-applets clock,battery,systray,startup --titlebar
+
diff --git a/meta-openmoko/packages/openmoko2/openmoko-session2/matchbox-session b/meta-openmoko/packages/openmoko2/openmoko-session2/matchbox-session
new file mode 100644
index 0000000000..65f1ce72ca
--- /dev/null
+++ b/meta-openmoko/packages/openmoko2/openmoko-session2/matchbox-session
@@ -0,0 +1,24 @@
+#!/bin/sh
+#
+# Very simple session manager for matchbox tools
+#
+
+# Uncomment below to enable parsing of debian menu entrys
+# export MB_USE_DEB_MENUS=1 
+
+if [ -e $HOME/.matchbox/session ]
+then
+exec $HOME/.matchbox/session
+fi
+
+if [ -e /etc/matchbox/session ]
+then
+exec /etc/matchbox/session
+fi
+
+# Default files to run if $HOME/.matchbox/session or /etc/matchbox/session
+# dont exist. 
+
+matchbox-desktop &
+matchbox-panel  --orientation south &
+exec matchbox-window-manager $@
diff --git a/meta-openmoko/packages/openmoko2/openmoko-theme-standard2_svn.bb b/meta-openmoko/packages/openmoko2/openmoko-theme-standard2_svn.bb
new file mode 100644
index 0000000000..43a1fd41d0
--- /dev/null
+++ b/meta-openmoko/packages/openmoko2/openmoko-theme-standard2_svn.bb
@@ -0,0 +1,23 @@
+require openmoko.inc
+
+DESCRIPTION = "Standard Gtk+ theme for the OpenMoko distribution"
+SECTION = "openmoko/base"
+RCONFLICTS = "openmoko-theme-standard"
+PACKAGE_ARCH = "all"
+PR = "r1"
+
+SRC_URI = "svn://svn.openmoko.org/trunk/src/target/OM-2007.2/artwork/themes;module=openmoko-standard-2;proto=http"
+
+S = "${WORKDIR}/openmoko-standard-2"
+
+do_install() {
+        find ${WORKDIR} -name ".svn" | xargs rm -rf
+        install -d ${D}${datadir}/themes/openmoko-standard-2/gtk-2.0
+        cp -fpPR ${S}/* ${D}${datadir}/themes/openmoko-standard-2/
+        rm -rf ${D}${datadir}/themes/openmoko-standard-2/patches/
+        
+        install -d ${D}${sysconfdir}/gtk-2.0
+        echo 'include "${datadir}/themes/openmoko-standard-2/gtk-2.0/gtkrc"' >> ${D}${sysconfdir}/gtk-2.0/gtkrc
+}
+
+FILES_${PN} = "${datadir} ${sysconfdir}"
diff --git a/meta-openmoko/packages/openmoko2/openmoko-today2_svn.bb b/meta-openmoko/packages/openmoko2/openmoko-today2_svn.bb
new file mode 100644
index 0000000000..fc6aba99a2
--- /dev/null
+++ b/meta-openmoko/packages/openmoko2/openmoko-today2_svn.bb
@@ -0,0 +1,8 @@
+require openmoko.inc
+
+DESCRIPTION = "OpenMoko Today application"
+SECTION = "openmoko/pim"
+DEPENDS += "startup-notification dbus-glib libice libsm libmokoui2"
+REAL_PN = "openmoko-today2"
+
+inherit gtk-icon-cache 
diff --git a/meta-openmoko/packages/openmoko2/openmoko.inc b/meta-openmoko/packages/openmoko2/openmoko.inc
new file mode 100644
index 0000000000..d5462be530
--- /dev/null
+++ b/meta-openmoko/packages/openmoko2/openmoko.inc
@@ -0,0 +1,10 @@
+HOMEPAGE = "http://www.openmoko.org"
+LICENSE = "GPL"
+DEPENDS = "gtk+ eds-dbus"
+PV = "0.0.1+svn${SRCDATE}"
+
+SRC_URI = "svn://svn.openmoko.org/trunk/src/target/OM-2007.2/applications;module=${REAL_PN};proto=http"
+
+S = "${WORKDIR}/${REAL_PN}"
+
+inherit autotools