which: Add new recipe

Add which-2.20, which is licensed under GPLv3.

The installation will override the busybox "which" command.

Signed-off-by: Dongxiao Xu <dongxiao.xu@intel.com>

2 files changed, 51 insertions, 0 deletions

diff --git a/meta/packages/which/which-2.20/remove-declaration.patch b/meta/packages/which/which-2.20/remove-declaration.patch
new file mode 100644
index 0000000000..09b81439b6
--- /dev/null
+++ b/meta/packages/which/which-2.20/remove-declaration.patch
@@ -0,0 +1,16 @@
+Remove the declaration of group_member since it has already been
+declared in unistd.h
+
+Signed-off-by: Dongxiao Xu <dongxiao.xu@intel.com>
+
+diff -ruN which-2.20-orig/bash.c which-2.20/bash.c
+--- which-2.20-orig/bash.c      2010-08-03 12:59:08.897088878 +0800
++++ which-2.20/bash.c   2010-08-03 13:17:23.406097212 +0800
+@@ -46,7 +46,6 @@
+  * - changed all occurences of 'gid_t' into 'GID_T'.
+  * - exported functions needed in which.c
+  */
+-static int group_member (GID_T gid);
+ static char* extract_colon_unit (char const* string, int* p_index);
+ 
+ /*===========================================================================
diff --git a/meta/packages/which/which_2.20.bb b/meta/packages/which/which_2.20.bb
new file mode 100644
index 0000000000..b7730de3b3
--- /dev/null
+++ b/meta/packages/which/which_2.20.bb
@@ -0,0 +1,35 @@
+DESCRIPTION = "which - shows the full path of (shell) commands."
+SECTION     = "libs"
+LICENSE = "GPLv3+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504\
+                    file://which.c;beginline=1;endline=17;md5=a9963693af2272e7a8df6f231164e7a2"
+HOMEPAGE = "http://ftp.gnu.org/gnu/which/"
+DEPENDS     = "cwautomacros-native"
+
+inherit autotools
+
+PR = "r0"
+
+SRC_URI = "http://ftp.gnu.org/gnu/which/which-${PV}.tar.gz \
+           file://remove-declaration.patch"
+
+do_configure_prepend() {
+        sed -i -e 's%@ACLOCAL_CWFLAGS@%-I ${STAGING_DIR_NATIVE}/usr/share/cwautomacros/m4%g' ${S}/Makefile.am ${S}/tilde/Makefile.am
+}
+
+do_install() {
+        autotools_do_install
+        mv ${D}${bindir}/which ${D}${bindir}/which.${PN}
+}
+
+pkg_postinst_${PN} () {
+        if [ "${PN}" = "${BPN}" ] ; then
+                update-alternatives --install ${bindir}/which which which.${PN} 100
+        fi
+}
+
+pkg_prerm_${PN} () {
+        if [ "${PN}" = "${BPN}" ] ; then
+                update-alternatives --remove which which.${PN}
+        fi
+}