initial commit for Enea Linux 5.0 arm

Signed-off-by: Tudor Florea <tudor.florea@enea.com>

2 files changed, 55 insertions, 0 deletions

diff --git a/meta/recipes-support/sqlite/sqlite3.inc b/meta/recipes-support/sqlite/sqlite3.inc
new file mode 100644
index 0000000000..2e3791bfc3
--- /dev/null
+++ b/meta/recipes-support/sqlite/sqlite3.inc
@@ -0,0 +1,34 @@
+SUMMARY = "Embeddable SQL database engine"
+HOMEPAGE = "http://www.sqlite.org"
+SECTION = "libs"
+DEPENDS = "readline ncurses"
+DEPENDS_class-native = ""
+LICENSE = "PD"
+
+inherit autotools pkgconfig
+
+EXTRA_OECONF = "--enable-shared --enable-threadsafe"
+EXTRA_OECONF_class-native = "--enable-shared --enable-threadsafe --disable-readline"
+export config_BUILD_CC = "${BUILD_CC}"
+export config_BUILD_CFLAGS = "${BUILD_CFLAGS}"
+export config_BUILD_LIBS = "${BUILD_LDFLAGS}"
+export config_TARGET_CC = "${CC}"
+export config_TARGET_LINK = "${CCLD}"
+export config_TARGET_CFLAGS = "${CFLAGS}"
+export config_TARGET_LFLAGS = "${LDFLAGS}"
+
+# pread() is in POSIX.1-2001 so any reasonable system must surely support it
+BUILD_CFLAGS += "-DUSE_PREAD"
+TARGET_CFLAGS += "-DUSE_PREAD"
+
+PACKAGES = "lib${BPN} lib${BPN}-dev lib${BPN}-doc ${PN}-dbg lib${BPN}-staticdev ${PN}"
+
+FILES_${PN} = "${bindir}/*"
+FILES_lib${BPN} = "${libdir}/*.so.*"
+FILES_lib${BPN}-dev = "${libdir}/*.la ${libdir}/*.so \
+                                   ${libdir}/pkgconfig ${includedir}"
+FILES_lib${BPN}-doc = "${docdir} ${mandir} ${infodir}"
+FILES_lib${BPN}-staticdev = "${libdir}/lib*.a"
+AUTO_LIBNAME_PKGS = "${MLPREFIX}lib${BPN}"
+
+BBCLASSEXTEND = "native nativesdk"
diff --git a/meta/recipes-support/sqlite/sqlite3_3.8.6.0.bb b/meta/recipes-support/sqlite/sqlite3_3.8.6.0.bb
new file mode 100644
index 0000000000..32f60ebbeb
--- /dev/null
+++ b/meta/recipes-support/sqlite/sqlite3_3.8.6.0.bb
@@ -0,0 +1,21 @@
+require sqlite3.inc
+
+LIC_FILES_CHKSUM = "file://sqlite3.h;endline=11;md5=65f0a57ca6928710b418c094b3570bb0"
+
+def sqlite_download_version(d):
+    pvsplit = d.getVar('PV', True).split('.')
+    return pvsplit[0] + ''.join([part.rjust(2,'0') for part in pvsplit[1:]])
+
+PE = "3"
+SQLITE_PV = "${@sqlite_download_version(d)}"
+SRC_URI = "http://www.sqlite.org/2014/sqlite-autoconf-${SQLITE_PV}.tar.gz"
+
+SRC_URI[md5sum] = "f7e4a156b583abeba349629e2364224b"
+SRC_URI[sha256sum] = "53bab14255bc16c3d73fdbe54b364c1764709d68dda167587f8026c98b9f4e95"
+
+S = "${WORKDIR}/sqlite-autoconf-${SQLITE_PV}"
+
+# Provide column meta-data API
+BUILD_CFLAGS += "-DSQLITE_ENABLE_COLUMN_METADATA"
+TARGET_CFLAGS += "-DSQLITE_ENABLE_COLUMN_METADATA"
+