gpgme: 1.6.0 -> 1.8.0

- Drop gpgme.pc, it is duplicated with pkgconfig.patch

- Rebase pkgconfig.patch to 1.8.0

- Split cmake config to ${PN}-dev

- Update LIC_FILES_CHKSUM, because copytright year changed.

- The libgpgme-pthread is obsolete by upstream;

- Add package libgpgcpp;

TODO: Do not remove gpgme-pthread.pc from pkgconfig.patch,
      the upstream explains:
      git://git.gnupg.org/gpgme.git
      commit 09b64554328445e99a8cc78fc34ea49c2ea2e7f9
      ------------------------------
      libgpgme-pthread is removed but gpgme-config still supports
      --thread=pthread for compatibility with find scripts.
      ------------------------------

(From OE-Core rev: 62b91f655977bdf2faaf53443c47785738c1d0f6)

Signed-off-by: Hongxu Jia <hongxu.jia@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 39 insertions, 0 deletions

diff --git a/meta/recipes-support/gpgme/gpgme_1.8.0.bb b/meta/recipes-support/gpgme/gpgme_1.8.0.bb
new file mode 100644
index 0000000000..b870069728
--- /dev/null
+++ b/meta/recipes-support/gpgme/gpgme_1.8.0.bb
@@ -0,0 +1,39 @@
+SUMMARY = "High-level GnuPG encryption/signing API"
+DESCRIPTION = "GnuPG Made Easy (GPGME) is a library designed to make access to GnuPG easier for applications. It provides a High-Level Crypto API for encryption, decryption, signing, signature verification and key management"
+HOMEPAGE = "http://www.gnupg.org/gpgme.html"
+BUGTRACKER = "https://bugs.g10code.com/gnupg/index"
+
+LICENSE = "GPLv2+ & LGPLv2.1+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
+                    file://COPYING.LESSER;md5=bbb461211a33b134d42ed5ee802b37ff \
+                    file://src/gpgme.h.in;endline=23;md5=0f7059665c4b7897f4f4d0cb93aa9f98 \
+                    file://src/engine.h;endline=22;md5=4b6d8ba313d9b564cc4d4cfb1640af9d"
+
+UPSTREAM_CHECK_URI = "https://gnupg.org/download/index.html"
+SRC_URI = "${GNUPG_MIRROR}/gpgme/${BP}.tar.bz2 \
+           file://pkgconfig.patch \
+          "
+
+SRC_URI[md5sum] = "722a4153904b9b5dc15485a22d29263b"
+SRC_URI[sha256sum] = "596097257c2ce22e747741f8ff3d7e24f6e26231fa198a41b2a072e62d1e5d33"
+
+DEPENDS = "libgpg-error libassuan"
+RDEPENDS_${PN}-cpp += "libstdc++"
+
+BINCONFIG = "${bindir}/gpgme-config"
+
+inherit autotools texinfo binconfig-disabled pkgconfig
+
+PACKAGES =+ "${PN}-cpp"
+FILES_${PN}-cpp = "${libdir}/libgpgmepp.so.*"
+FILES_${PN}-dev += "${datadir}/common-lisp/source/gpgme/* \
+                    ${libdir}/cmake/* \
+"
+
+CFLAGS_append_libc-musl = " -D__error_t_defined "
+do_configure_prepend () {
+        # Else these could be used in preference to those in aclocal-copy
+        rm -f ${S}/m4/gpg-error.m4
+        rm -f ${S}/m4/libassuan.m4
+}
+