diff options
author | Saul Wold <Saul.Wold@windriver.com> | 2020-09-09 17:46:32 -0700 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2020-09-12 14:48:59 +0100 |
commit | 0c06506d42f9e1f43a54a178cda47cfea3f12f81 (patch) | |
tree | 48d5d790965d4b3e6c7b4bc1e74964c5375cdcab /meta/recipes-support/gnupg/gnupg_2.2.23.bb | |
parent | 9b2b23d5ec4c9b0031ad9c002ab40e70a49fe71e (diff) | |
download | poky-0c06506d42f9e1f43a54a178cda47cfea3f12f81.tar.gz |
gnupg: uprev 2.2.22 -> 2.2.23
This addresses CVE-2020-25125 and provides some other minor
updates and translations.
Updated commits for reference:
e234d04c3 Werner Koch Release 2.2.23
aeb8272ca Werner Koch gpg: Fix AEAD preference list overflow
038314665 Werner Koch po: auto update
1a4b0fd79 Yuri Chornoivan po: Update Ukrainian translation
93d10403a Jakub Bogusz po: Update Polish translation
a8a8105bc Werner Koch po: Add key-check.c to the list of translatable sources.
cad9955ac Petr Pisar po: Update Czech translation.
896c528ba Werner Koch gpg: Fix segv importing certain keys.
0a9665187 NIIBE Yutaka scd: Fix a regression for OpenPGP card.
bcae9cd4e Nagy Ferenc László po: Minor update to the Hungarian translation.
d2fe2ffd7 Werner Koch sm: Fix a bug in the rfc2253 parser
f799b3ddb Werner Koch Post release updates
(From OE-Core rev: 965683336816eba7cb0548e59faf224f74b306b1)
Signed-off-by: Saul Wold <saul.wold@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-support/gnupg/gnupg_2.2.23.bb')
-rw-r--r-- | meta/recipes-support/gnupg/gnupg_2.2.23.bb | 80 |
1 files changed, 80 insertions, 0 deletions
diff --git a/meta/recipes-support/gnupg/gnupg_2.2.23.bb b/meta/recipes-support/gnupg/gnupg_2.2.23.bb new file mode 100644 index 0000000000..c624b67a0b --- /dev/null +++ b/meta/recipes-support/gnupg/gnupg_2.2.23.bb | |||
@@ -0,0 +1,80 @@ | |||
1 | SUMMARY = "GNU Privacy Guard - encryption and signing tools (2.x)" | ||
2 | HOMEPAGE = "http://www.gnupg.org/" | ||
3 | LICENSE = "GPLv3 & LGPLv3" | ||
4 | LIC_FILES_CHKSUM = "file://COPYING;md5=189af8afca6d6075ba6c9e0aa8077626 \ | ||
5 | file://COPYING.LGPL3;md5=a2b6bf2cb38ee52619e60f30a1fc7257" | ||
6 | |||
7 | DEPENDS = "npth libassuan libksba zlib bzip2 readline libgcrypt" | ||
8 | |||
9 | inherit autotools gettext texinfo pkgconfig | ||
10 | |||
11 | UPSTREAM_CHECK_URI = "https://gnupg.org/download/index.html" | ||
12 | SRC_URI = "${GNUPG_MIRROR}/${BPN}/${BPN}-${PV}.tar.bz2 \ | ||
13 | file://0001-Use-pkg-config-to-find-pth-instead-of-pth-config.patch \ | ||
14 | file://0002-use-pkgconfig-instead-of-npth-config.patch \ | ||
15 | file://0003-dirmngr-uses-libgpg-error.patch \ | ||
16 | file://0004-autogen.sh-fix-find-version-for-beta-checking.patch \ | ||
17 | file://0001-Woverride-init-is-not-needed-with-gcc-9.patch \ | ||
18 | " | ||
19 | SRC_URI_append_class-native = " file://0001-configure.ac-use-a-custom-value-for-the-location-of-.patch \ | ||
20 | file://relocate.patch" | ||
21 | SRC_URI_append_class-nativesdk = " file://relocate.patch" | ||
22 | |||
23 | SRC_URI[sha256sum] = "10b55e49d78b3e49f1edb58d7541ecbdad92ddaeeb885b6f486ed23d1cd1da5c" | ||
24 | |||
25 | EXTRA_OECONF = "--disable-ldap \ | ||
26 | --disable-ccid-driver \ | ||
27 | --with-zlib=${STAGING_LIBDIR}/.. \ | ||
28 | --with-bzip2=${STAGING_LIBDIR}/.. \ | ||
29 | --with-readline=${STAGING_LIBDIR}/.. \ | ||
30 | --enable-gpg-is-gpg2 \ | ||
31 | " | ||
32 | |||
33 | # A minimal package containing just enough to run gpg+gpgagent (E.g. use gpgme in opkg) | ||
34 | PACKAGES =+ "${PN}-gpg" | ||
35 | FILES_${PN}-gpg = " \ | ||
36 | ${bindir}/gpg \ | ||
37 | ${bindir}/gpg2 \ | ||
38 | ${bindir}/gpg-agent \ | ||
39 | " | ||
40 | |||
41 | # Normal package (gnupg) should depend on minimal package (gnupg-gpg) | ||
42 | # to ensure all tools are included. This is done only in non-native | ||
43 | # builds. Native builds don't have sub-packages, so appending RDEPENDS | ||
44 | # in this case breaks recipe parsing. | ||
45 | RDEPENDS_${PN} += "${@ "" if ("native" in d.getVar("PN")) else (d.getVar("PN") + "-gpg")}" | ||
46 | |||
47 | RRECOMMENDS_${PN} = "pinentry" | ||
48 | |||
49 | do_configure_prepend () { | ||
50 | # Else these could be used in prefernce to those in aclocal-copy | ||
51 | rm -f ${S}/m4/gpg-error.m4 | ||
52 | rm -f ${S}/m4/libassuan.m4 | ||
53 | rm -f ${S}/m4/ksba.m4 | ||
54 | rm -f ${S}/m4/libgcrypt.m4 | ||
55 | } | ||
56 | |||
57 | do_install_append() { | ||
58 | ln -sf gpg2 ${D}${bindir}/gpg | ||
59 | ln -sf gpgv2 ${D}${bindir}/gpgv | ||
60 | } | ||
61 | |||
62 | do_install_append_class-native() { | ||
63 | create_wrappers ${STAGING_BINDIR_NATIVE} | ||
64 | } | ||
65 | |||
66 | do_install_append_class-nativesdk() { | ||
67 | create_wrappers ${SDKPATHNATIVE}${bindir_nativesdk} | ||
68 | } | ||
69 | |||
70 | create_wrappers() { | ||
71 | for i in gpg2 gpgconf gpg-agent gpg-connect-agent; do | ||
72 | create_wrapper ${D}${bindir}/$i GNUPG_BINDIR=$1 | ||
73 | done | ||
74 | } | ||
75 | |||
76 | PACKAGECONFIG ??= "gnutls" | ||
77 | PACKAGECONFIG[gnutls] = "--enable-gnutls, --disable-gnutls, gnutls" | ||
78 | PACKAGECONFIG[sqlite3] = "--enable-sqlite, --disable-sqlite, sqlite3" | ||
79 | |||
80 | BBCLASSEXTEND = "native nativesdk" | ||