diff options
author | Fan Xin <fan.xin@jp.fujitsu.com> | 2017-07-13 17:34:51 +0900 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2017-07-17 14:01:39 +0100 |
commit | 3c24505d16f5db91194fc7cd6ae77ff27e1dc36f (patch) | |
tree | e2e03500ff694284cbef7419ccbd919911057cb8 /meta/recipes-support/apr/apr_1.6.2.bb | |
parent | fb449921ac40c267b4e6a80f7b242cf749b0d218 (diff) | |
download | poky-3c24505d16f5db91194fc7cd6ae77ff27e1dc36f.tar.gz |
apr: 1.5.2 -> 1.6.2
Update apr from 1.5.2 to 1.6.2
(From OE-Core rev: 88e7f5c25f1e303b9d68fe25d7e785b9412c6138)
Signed-off-by: Fan Xin <fan.xin@jp.fujitsu.com>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-support/apr/apr_1.6.2.bb')
-rw-r--r-- | meta/recipes-support/apr/apr_1.6.2.bb | 114 |
1 files changed, 114 insertions, 0 deletions
diff --git a/meta/recipes-support/apr/apr_1.6.2.bb b/meta/recipes-support/apr/apr_1.6.2.bb new file mode 100644 index 0000000000..e2eed53c9e --- /dev/null +++ b/meta/recipes-support/apr/apr_1.6.2.bb | |||
@@ -0,0 +1,114 @@ | |||
1 | SUMMARY = "Apache Portable Runtime (APR) library" | ||
2 | HOMEPAGE = "http://apr.apache.org/" | ||
3 | SECTION = "libs" | ||
4 | DEPENDS = "util-linux" | ||
5 | |||
6 | LICENSE = "Apache-2.0" | ||
7 | LIC_FILES_CHKSUM = "file://LICENSE;md5=4dfd4cd216828c8cae5de5a12f3844c8 \ | ||
8 | file://include/apr_lib.h;endline=17;md5=ee42fa7575dc40580a9e01c1b75fae96" | ||
9 | |||
10 | BBCLASSEXTEND = "native nativesdk" | ||
11 | |||
12 | SRC_URI = "${APACHE_MIRROR}/apr/${BPN}-${PV}.tar.bz2 \ | ||
13 | file://configure_fixes.patch \ | ||
14 | file://cleanup.patch \ | ||
15 | file://configfix.patch \ | ||
16 | file://run-ptest \ | ||
17 | file://upgrade-and-fix-1.5.1.patch \ | ||
18 | file://Fix-packet-discards-HTTP-redirect.patch \ | ||
19 | file://configure.in-fix-LTFLAGS-to-make-it-work-with-ccache.patch \ | ||
20 | file://0001-apr-fix-off_t-size-doesn-t-match-in-glibc-when-cross.patch \ | ||
21 | file://0002-explicitly-link-libapr-against-phtread-to-make-gold-.patch \ | ||
22 | " | ||
23 | |||
24 | SRC_URI[md5sum] = "e81a851967c79b5ce9bfbc909e4bf735" | ||
25 | SRC_URI[sha256sum] = "09109cea377bab0028bba19a92b5b0e89603df9eab05c0f7dbd4dd83d48dcebd" | ||
26 | |||
27 | inherit autotools-brokensep lib_package binconfig multilib_header ptest | ||
28 | |||
29 | OE_BINCONFIG_EXTRA_MANGLE = " -e 's:location=source:location=installed:'" | ||
30 | |||
31 | # Added to fix some issues with cmake. Refer to https://github.com/bmwcarit/meta-ros/issues/68#issuecomment-19896928 | ||
32 | CACHED_CONFIGUREVARS += "apr_cv_mutex_recursive=yes" | ||
33 | |||
34 | # Also suppress trying to use sctp. | ||
35 | # | ||
36 | CACHED_CONFIGUREVARS += "ac_cv_header_netinet_sctp_h=no ac_cv_header_netinet_sctp_uio_h=no" | ||
37 | |||
38 | # Otherwise libtool fails to compile apr-utils | ||
39 | # x86_64-linux-libtool: compile: unable to infer tagged configuration | ||
40 | # x86_64-linux-libtool: error: specify a tag with '--tag' | ||
41 | CCACHE = "" | ||
42 | |||
43 | PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)}" | ||
44 | PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6," | ||
45 | |||
46 | do_configure_prepend() { | ||
47 | # Avoid absolute paths for grep since it causes failures | ||
48 | # when using sstate between different hosts with different | ||
49 | # install paths for grep. | ||
50 | export GREP="grep" | ||
51 | |||
52 | cd ${S} | ||
53 | ./buildconf | ||
54 | } | ||
55 | |||
56 | FILES_${PN}-dev += "${libdir}/apr.exp ${datadir}/build-1/*" | ||
57 | RDEPENDS_${PN}-dev += "bash" | ||
58 | |||
59 | #for some reason, build/libtool.m4 handled by buildconf still be overwritten | ||
60 | #when autoconf, so handle it again. | ||
61 | do_configure_append() { | ||
62 | sed -i -e 's/LIBTOOL=\(.*\)top_build/LIBTOOL=\1apr_build/' ${S}/build/libtool.m4 | ||
63 | sed -i -e 's/LIBTOOL=\(.*\)top_build/LIBTOOL=\1apr_build/' ${S}/build/apr_rules.mk | ||
64 | } | ||
65 | |||
66 | do_install_append() { | ||
67 | oe_multilib_header apr.h | ||
68 | install -d ${D}${datadir}/apr | ||
69 | } | ||
70 | |||
71 | do_install_append_class-target() { | ||
72 | sed -i -e 's,${STAGING_DIR_HOST},,g' ${D}${datadir}/build-1/apr_rules.mk | ||
73 | sed -i -e 's,${STAGING_DIR_HOST},,g' \ | ||
74 | -e 's,APR_SOURCE_DIR=.*,APR_SOURCE_DIR=,g' \ | ||
75 | -e 's,APR_BUILD_DIR=.*,APR_BUILD_DIR=,g' ${D}${bindir}/apr-1-config | ||
76 | } | ||
77 | |||
78 | SSTATE_SCAN_FILES += "apr_rules.mk libtool" | ||
79 | |||
80 | SYSROOT_PREPROCESS_FUNCS += "apr_sysroot_preprocess" | ||
81 | |||
82 | apr_sysroot_preprocess () { | ||
83 | d=${SYSROOT_DESTDIR}${datadir}/apr | ||
84 | install -d $d/ | ||
85 | cp ${S}/build/apr_rules.mk $d/ | ||
86 | sed -i s,apr_builddir=.*,apr_builddir=,g $d/apr_rules.mk | ||
87 | sed -i s,apr_builders=.*,apr_builders=,g $d/apr_rules.mk | ||
88 | sed -i s,LIBTOOL=.*,LIBTOOL=${HOST_SYS}-libtool,g $d/apr_rules.mk | ||
89 | sed -i s,\$\(apr_builders\),${STAGING_DATADIR}/apr/,g $d/apr_rules.mk | ||
90 | cp ${S}/build/mkdir.sh $d/ | ||
91 | cp ${S}/build/make_exports.awk $d/ | ||
92 | cp ${S}/build/make_var_export.awk $d/ | ||
93 | cp ${S}/${HOST_SYS}-libtool ${SYSROOT_DESTDIR}${datadir}/build-1/libtool | ||
94 | } | ||
95 | |||
96 | do_compile_ptest() { | ||
97 | cd ${S}/test | ||
98 | oe_runmake | ||
99 | } | ||
100 | |||
101 | do_install_ptest() { | ||
102 | t=${D}${PTEST_PATH}/test | ||
103 | mkdir -p $t/.libs | ||
104 | cp -r ${S}/test/data $t/ | ||
105 | cp -r ${S}/test/.libs/*.so $t/.libs/ | ||
106 | cp ${S}/test/proc_child $t/ | ||
107 | cp ${S}/test/readchild $t/ | ||
108 | cp ${S}/test/sockchild $t/ | ||
109 | cp ${S}/test/sockperf $t/ | ||
110 | cp ${S}/test/testall $t/ | ||
111 | cp ${S}/test/tryread $t/ | ||
112 | } | ||
113 | |||
114 | export CONFIG_SHELL="/bin/bash" | ||