apr: Update to 1.4.2

Add buildconf_fix.patch of removing new libtool detection method to avoid config
failure.  Handled build/libtool.m4 & apr_rules.mk after configure to take place
of "top_builddir" by "apr_builddir", as these files would be reused by apr-util.

Signed-off-by: Zhai Edwin <edwin.zhai@intel.com>

1 files changed, 50 insertions, 0 deletions

diff --git a/meta/recipes-support/apr/apr_1.4.2.bb b/meta/recipes-support/apr/apr_1.4.2.bb
new file mode 100644
index 0000000000..fe983eb7f7
--- /dev/null
+++ b/meta/recipes-support/apr/apr_1.4.2.bb
@@ -0,0 +1,50 @@
+DESCRIPTION = "Apache Portable Runtime (APR) library"
+HOMEPAGE = "http://apr.apache.org/"
+SECTION = "libs"
+
+LICENSE = "Apache License, Version 2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=0c35ff3c4c83b89d2f076e315caac28b \
+                    file://include/apr_lib.h;endline=17;md5=ee42fa7575dc40580a9e01c1b75fae96"
+
+PR = "r0"
+
+SRC_URI = "${APACHE_MIRROR}/apr/${P}.tar.bz2 \
+           file://configure_fixes.patch;patch=1 \
+           file://cleanup.patch;patch=1 \
+           file://configfix.patch;patch=1 \
+           file://buildconf_fix.patch;patch=1"
+
+SRC_URI[md5sum] = "4b00e8f70c067893d075577962656b35"
+SRC_URI[sha256sum] = "2017ca700694d09d2b0b21dd7c4d195e43a48735aac88526160c6195ee8f5391"
+
+inherit autotools lib_package binconfig
+
+OE_BINCONFIG_EXTRA_MANGLE = " -e 's:location=source:location=installed:'"
+
+do_configure_prepend() {
+        cd ${S}
+        ./buildconf
+}
+
+#for some reason, build/libtool.m4 handled by buildconf still be overwritten
+#when autoconf, so handle it again.
+do_configure_append() {
+        cd ${S}
+        sed -i -e 's/LIBTOOL=\(.*\)top_build/LIBTOOL=\1apr_build/' build/libtool.m4
+        sed -i -e 's/LIBTOOL=\(.*\)top_build/LIBTOOL=\1apr_build/' build/apr_rules.mk
+}
+
+SYSROOT_PREPROCESS_FUNCS += "apr_sysroot_preprocess"
+
+apr_sysroot_preprocess () {
+        d=${SYSROOT_DESTDIR}${STAGING_DIR_TARGET}${datadir}/apr
+        install -d $d/
+        cp ${S}/build/apr_rules.mk $d/
+        sed -i s,apr_builddir=.*,apr_builddir=,g $d/apr_rules.mk
+        sed -i s,apr_builders=.*,apr_builders=,g $d/apr_rules.mk
+        sed -i s,LIBTOOL=.*,LIBTOOL=\$\(SHELL\)\ ${TARGET_PREFIX}libtool,g $d/apr_rules.mk
+        sed -i s,\$\(apr_builders\),${STAGING_DATADIR}/apr/,g $d/apr_rules.mk
+        cp ${S}/build/mkdir.sh $d/
+        cp ${S}/build/make_exports.awk $d/
+        cp ${S}/build/make_var_export.awk $d/
+}