packages: Separate out most of the remaining packages into recipes

Signed-off-by: Richard Purdie <rpurdie@linux.intel.com>

1 files changed, 34 insertions, 0 deletions

diff --git a/meta/recipes-support/apr/apr_1.3.3.bb b/meta/recipes-support/apr/apr_1.3.3.bb
new file mode 100644
index 0000000000..a193a18a2e
--- /dev/null
+++ b/meta/recipes-support/apr/apr_1.3.3.bb
@@ -0,0 +1,34 @@
+DESCRIPTION = "Apache Portable Runtime (APR) library"
+SECTION = "libs"
+LICENSE = "Apache License, Version 2.0"
+
+PR = "r5"
+
+SRC_URI = "${APACHE_MIRROR}/apr/${P}.tar.bz2 \
+           file://configure_fixes.patch;patch=1 \
+           file://cleanup.patch;patch=1 \
+           file://configfix.patch;patch=1"
+
+inherit autotools lib_package binconfig
+
+OE_BINCONFIG_EXTRA_MANGLE = " -e 's:location=source:location=installed:'"
+
+do_configure_prepend() {
+        cd ${S}
+        ./buildconf
+}
+
+SYSROOT_PREPROCESS_FUNCS += "apr_sysroot_preprocess"
+
+apr_sysroot_preprocess () {
+        d=${SYSROOT_DESTDIR}${STAGING_DIR_TARGET}${datadir}/apr
+        install -d $d/
+        cp ${S}/build/apr_rules.mk $d/
+        sed -i s,apr_builddir=.*,apr_builddir=,g $d/apr_rules.mk
+        sed -i s,apr_builders=.*,apr_builders=,g $d/apr_rules.mk
+        sed -i s,LIBTOOL=.*,LIBTOOL=\$\(SHELL\)\ ${TARGET_PREFIX}libtool,g $d/apr_rules.mk
+        sed -i s,\$\(apr_builders\),${STAGING_DATADIR}/apr/,g $d/apr_rules.mk
+        cp ${S}/build/mkdir.sh $d/
+        cp ${S}/build/make_exports.awk $d/
+        cp ${S}/build/make_var_export.awk $d/
+}