diff options
author | Khem Raj <raj.khem@gmail.com> | 2018-05-20 15:03:15 -0700 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2018-05-29 21:07:15 +0100 |
commit | 09dc5c8273b4de9b2fa05af0cde83705b92df7f7 (patch) | |
tree | 88130e4dbb50e3654b8ebc4bdc569a94c572dfe6 /meta/recipes-sato/webkit/webkitgtk_2.20.2.bb | |
parent | f7137f94905c0d0ef1c0af8e53db18de00a17fec (diff) | |
download | poky-09dc5c8273b4de9b2fa05af0cde83705b92df7f7.tar.gz |
webkitgtk: Upgrade to 2.20.2
Backport a patch to fix build
clang 6.0+ driver can correclty detect corss gold linker now
(From OE-Core rev: 10cb11fe911473a3a2f4cb67815ff86141c0ab3c)
Signed-off-by: Khem Raj <raj.khem@gmail.com>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-sato/webkit/webkitgtk_2.20.2.bb')
-rw-r--r-- | meta/recipes-sato/webkit/webkitgtk_2.20.2.bb | 124 |
1 files changed, 124 insertions, 0 deletions
diff --git a/meta/recipes-sato/webkit/webkitgtk_2.20.2.bb b/meta/recipes-sato/webkit/webkitgtk_2.20.2.bb new file mode 100644 index 0000000000..a68a69f43c --- /dev/null +++ b/meta/recipes-sato/webkit/webkitgtk_2.20.2.bb | |||
@@ -0,0 +1,124 @@ | |||
1 | SUMMARY = "WebKit web rendering engine for the GTK+ platform" | ||
2 | HOMEPAGE = "http://www.webkitgtk.org/" | ||
3 | BUGTRACKER = "http://bugs.webkit.org/" | ||
4 | |||
5 | LICENSE = "BSD & LGPLv2+" | ||
6 | LIC_FILES_CHKSUM = "file://Source/JavaScriptCore/COPYING.LIB;md5=d0c6d6397a5d84286dda758da57bd691 \ | ||
7 | file://Source/WebCore/LICENSE-APPLE;md5=4646f90082c40bcf298c285f8bab0b12 \ | ||
8 | file://Source/WebCore/LICENSE-LGPL-2;md5=36357ffde2b64ae177b2494445b79d21 \ | ||
9 | file://Source/WebCore/LICENSE-LGPL-2.1;md5=a778a33ef338abbaf8b8a7c36b6eec80 \ | ||
10 | " | ||
11 | |||
12 | SRC_URI = "http://www.webkitgtk.org/releases/${BPN}-${PV}.tar.xz \ | ||
13 | file://0001-FindGObjectIntrospection.cmake-prefix-variables-obta.patch \ | ||
14 | file://0001-When-building-introspection-files-add-CMAKE_C_FLAGS-.patch \ | ||
15 | file://0001-OptionsGTK.cmake-drop-the-hardcoded-introspection-gt.patch \ | ||
16 | file://0001-Fix-racy-parallel-build-of-WebKit2-4.0.gir.patch \ | ||
17 | file://0001-Tweak-gtkdoc-settings-so-that-gtkdoc-generation-work.patch \ | ||
18 | file://x32_support.patch \ | ||
19 | file://cross-compile.patch \ | ||
20 | file://detect-atomics-during-configure.patch \ | ||
21 | file://0001-WebKitMacros-Append-to-I-and-not-to-isystem.patch \ | ||
22 | file://0001-Fix-build-with-musl.patch \ | ||
23 | file://detect-gstreamer-gl.patch \ | ||
24 | file://0012-soup-Forward-declare-URL-class.patch \ | ||
25 | " | ||
26 | |||
27 | SRC_URI[md5sum] = "3fdda40dc10eb2a00d5fba4219b83967" | ||
28 | SRC_URI[sha256sum] = "dffe93a241f03f1c73b369f4e323e4d8f12e39d33d5515948cbf454ca4b526e2" | ||
29 | |||
30 | inherit cmake pkgconfig gobject-introspection perlnative distro_features_check upstream-version-is-even gtk-doc | ||
31 | |||
32 | # depends on libxt | ||
33 | REQUIRED_DISTRO_FEATURES = "x11" | ||
34 | |||
35 | DEPENDS = "zlib libsoup-2.4 curl libxml2 cairo libxslt libxt libidn libgcrypt \ | ||
36 | gtk+3 gstreamer1.0 gstreamer1.0-plugins-base flex-native gperf-native sqlite3 \ | ||
37 | pango icu bison-native gawk intltool-native libwebp \ | ||
38 | atk udev harfbuzz jpeg libpng pulseaudio librsvg libtheora libvorbis libxcomposite libxtst \ | ||
39 | ruby-native libnotify gstreamer1.0-plugins-bad \ | ||
40 | gettext-native glib-2.0 glib-2.0-native libtasn1 \ | ||
41 | " | ||
42 | |||
43 | PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', 'wayland' ,d)} \ | ||
44 | ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'webgl opengl', '' ,d)} \ | ||
45 | enchant \ | ||
46 | libsecret \ | ||
47 | " | ||
48 | |||
49 | PACKAGECONFIG[wayland] = "-DENABLE_WAYLAND_TARGET=ON,-DENABLE_WAYLAND_TARGET=OFF,wayland" | ||
50 | PACKAGECONFIG[x11] = "-DENABLE_X11_TARGET=ON,-DENABLE_X11_TARGET=OFF,virtual/libx11" | ||
51 | PACKAGECONFIG[geoclue] = "-DENABLE_GEOLOCATION=ON,-DENABLE_GEOLOCATION=OFF,geoclue" | ||
52 | PACKAGECONFIG[enchant] = "-DENABLE_SPELLCHECK=ON,-DENABLE_SPELLCHECK=OFF,enchant" | ||
53 | PACKAGECONFIG[gtk2] = "-DENABLE_PLUGIN_PROCESS_GTK2=ON,-DENABLE_PLUGIN_PROCESS_GTK2=OFF,gtk+" | ||
54 | PACKAGECONFIG[gles2] = "-DENABLE_GLES2=ON,-DENABLE_GLES2=OFF,virtual/libgles2" | ||
55 | PACKAGECONFIG[webgl] = "-DENABLE_WEBGL=ON,-DENABLE_WEBGL=OFF,virtual/libgl" | ||
56 | PACKAGECONFIG[opengl] = "-DENABLE_OPENGL=ON,-DENABLE_OPENGL=OFF,virtual/libgl" | ||
57 | PACKAGECONFIG[libsecret] = "-DUSE_LIBSECRET=ON,-DUSE_LIBSECRET=OFF,libsecret" | ||
58 | PACKAGECONFIG[libhyphen] = "-DUSE_LIBHYPHEN=ON,-DUSE_LIBHYPHEN=OFF,libhyphen" | ||
59 | # Source is at https://github.com/google/woff2 | ||
60 | PACKAGECONFIG[woff2] = "-DUSE_WOFF2=ON,-DUSE_WOFF2=OFF,woff2" | ||
61 | |||
62 | EXTRA_OECMAKE = " \ | ||
63 | -DPORT=GTK \ | ||
64 | -DCMAKE_BUILD_TYPE=Release \ | ||
65 | ${@bb.utils.contains('GI_DATA_ENABLED', 'True', '-DENABLE_INTROSPECTION=ON', '-DENABLE_INTROSPECTION=OFF', d)} \ | ||
66 | ${@bb.utils.contains('GTKDOC_ENABLED', 'True', '-DENABLE_GTKDOC=ON', '-DENABLE_GTKDOC=OFF', d)} \ | ||
67 | -DENABLE_MINIBROWSER=ON \ | ||
68 | -DPYTHON_EXECUTABLE=`which python` \ | ||
69 | " | ||
70 | |||
71 | # GL/GLES header clash: both define the same thing, differently, on 32 bit x86 | ||
72 | EXTRA_OECMAKE_append_x86 = " -DUSE_GSTREAMER_GL=OFF " | ||
73 | EXTRA_OECMAKE_append_x86-x32 = " -DUSE_GSTREAMER_GL=OFF " | ||
74 | |||
75 | # Javascript JIT is not supported on powerpc | ||
76 | EXTRA_OECMAKE_append_powerpc = " -DENABLE_JIT=OFF " | ||
77 | EXTRA_OECMAKE_append_powerpc64 = " -DENABLE_JIT=OFF " | ||
78 | |||
79 | # ARM JIT code does not build on ARMv4/5/6 anymore | ||
80 | EXTRA_OECMAKE_append_armv5 = " -DENABLE_JIT=OFF " | ||
81 | EXTRA_OECMAKE_append_armv6 = " -DENABLE_JIT=OFF " | ||
82 | EXTRA_OECMAKE_append_armv4 = " -DENABLE_JIT=OFF " | ||
83 | |||
84 | # binutils 2.25.1 has a bug on aarch64: | ||
85 | # https://sourceware.org/bugzilla/show_bug.cgi?id=18430 | ||
86 | EXTRA_OECMAKE_append_aarch64 = " -DUSE_LD_GOLD=OFF " | ||
87 | EXTRA_OECMAKE_append_mipsarch = " -DUSE_LD_GOLD=OFF " | ||
88 | EXTRA_OECMAKE_append_powerpc = " -DUSE_LD_GOLD=OFF " | ||
89 | |||
90 | EXTRA_OECMAKE_append_aarch64 = " -DWTF_CPU_ARM64_CORTEXA53=ON" | ||
91 | |||
92 | # JIT not supported on MIPS either | ||
93 | EXTRA_OECMAKE_append_mipsarch = " -DENABLE_JIT=OFF " | ||
94 | |||
95 | # JIT not supported on X32 | ||
96 | # An attempt was made to upstream JIT support for x32 in | ||
97 | # https://bugs.webkit.org/show_bug.cgi?id=100450, but this was closed as | ||
98 | # unresolved due to limited X32 adoption. | ||
99 | EXTRA_OECMAKE_append_x86-x32 = " -DENABLE_JIT=OFF " | ||
100 | |||
101 | SECURITY_CFLAGS_remove_aarch64 = "-fpie" | ||
102 | SECURITY_CFLAGS_append_aarch64 = " -fPIE" | ||
103 | |||
104 | FILES_${PN} += "${libdir}/webkit2gtk-4.0/injected-bundle/libwebkit2gtkinjectedbundle.so" | ||
105 | |||
106 | RRECOMMENDS_${PN} += "ca-certificates shared-mime-info" | ||
107 | |||
108 | # http://errors.yoctoproject.org/Errors/Details/20370/ | ||
109 | ARM_INSTRUCTION_SET_armv4 = "arm" | ||
110 | ARM_INSTRUCTION_SET_armv5 = "arm" | ||
111 | ARM_INSTRUCTION_SET_armv6 = "arm" | ||
112 | |||
113 | # https://bugzilla.yoctoproject.org/show_bug.cgi?id=9474 | ||
114 | # https://bugs.webkit.org/show_bug.cgi?id=159880 | ||
115 | # JSC JIT can build on ARMv7 with -marm, but doesn't work on runtime. | ||
116 | # Upstream only tests regularly the JSC JIT on ARMv7 with Thumb2 (-mthumb). | ||
117 | ARM_INSTRUCTION_SET_armv7a = "thumb" | ||
118 | ARM_INSTRUCTION_SET_armv7r = "thumb" | ||
119 | ARM_INSTRUCTION_SET_armv7ve = "thumb" | ||
120 | |||
121 | # qemu: uncaught target signal 11 (Segmentation fault) - core dumped | ||
122 | # Segmentation fault | ||
123 | GI_DATA_ENABLED_armv7a = "False" | ||
124 | GI_DATA_ENABLED_armv7ve = "False" | ||