Major layout change to the packages directory

Having one monolithic packages directory makes it hard to find things
and is generally overwhelming. This commit splits it into several
logical sections roughly based on function, recipes.txt gives more
information about the classifications used.

The opportunity is also used to switch from "packages" to "recipes"
as used in OpenEmbedded as the term "packages" can be confusing to
people and has many different meanings.

Not all recipes have been classified yet, this is just a first pass
at separating things out. Some packages are moved to meta-extras as
they're no longer actively used or maintained.

Signed-off-by: Richard Purdie <rpurdie@linux.intel.com>

1 files changed, 53 insertions, 0 deletions

diff --git a/meta/recipes-sato/puzzles/puzzles_r7593.bb b/meta/recipes-sato/puzzles/puzzles_r7593.bb
new file mode 100644
index 0000000000..eb1e009353
--- /dev/null
+++ b/meta/recipes-sato/puzzles/puzzles_r7593.bb
@@ -0,0 +1,53 @@
+
+DEPENDS = "gtk+ libxt"
+PR = "r8"
+MOD_PV = "${@bb.data.getVar('PV',d,1)[1:]}"
+
+#SRC_URI = "http://www.chiark.greenend.org.uk/~sgtatham/puzzles/puzzles-${PV}.tar.gz"
+SRC_URI = "svn://ixion.tartarus.org/main;module=puzzles;rev=${MOD_PV} \
+           file://makedist_hack.patch;patch=1"
+
+S = "${WORKDIR}/${PN}"
+
+do_configure () {
+        ./makedist.sh ${MOD_PV}
+}
+
+do_compile_prepend = " \
+        export XLDFLAGS='${LDFLAGS} `${STAGING_BINDIR_NATIVE}/pkg-config gtk+-2.0 --libs`'; \
+        export CFLAGS='${CFLAGS} -I./ `${STAGING_BINDIR_NATIVE}/pkg-config gtk+-2.0 --cflags`'; "
+
+FILES_${PN} = "${prefix}/games/* ${datadir}/applications/*"
+FILES_${PN}-dbg += "${prefix}/games/.debug"
+
+do_install () {
+    rm -rf ${D}/*
+    export prefix=${D}
+    export DESTDIR=${D}
+    install -d ${D}/${prefix}/
+    install -d ${D}/${prefix}/games/
+    oe_runmake install
+    
+    install -d ${D}/${datadir}/
+    install -d ${D}/${datadir}/applications/
+
+    cd ${D}/${prefix}/games 
+    for prog in *; do
+        if [ -x $prog ]; then
+            # Convert prog to Title Case
+            title=$(echo $prog | sed 's/\(^\| \)./\U&/g')
+            echo "making ${D}/${datadir}/applications/$prog.desktop"
+            cat <<STOP > ${D}/${datadir}/applications/$prog.desktop
+[Desktop Entry]
+Name=$title
+Exec=${prefix}/games/$prog
+Icon=applications-games
+Terminal=false
+Type=Application
+Categories=Game;
+StartupNotify=true
+X-MB-SingleInstance=true
+STOP
+        fi
+    done
+}