rt-tests: Update recipes to use 1.8

John Kacur(the maintainer of rt-tests), recommends "that they use
unstable/devel/latest as the maintained stable branch". I received this
information on IRC, I couldn't find it documented anywhere else.

This means that both rt-tests and hwlatdetect can be updated to be 1.8,
the latest release on unstable/devel/latest.

0001-gzip-with-n-for-build-reproducibilty.patch was removed because
upstream now uses "gzip -n" by default.

(From OE-Core rev: 92b2386f0be0eac8ca761e2008288671c6f1dbb0)

Signed-off-by: Randy Witt <randy.e.witt@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 35 insertions, 0 deletions

diff --git a/meta/recipes-rt/rt-tests/rt-tests_1.8.bb b/meta/recipes-rt/rt-tests/rt-tests_1.8.bb
new file mode 100644
index 0000000000..2834cabcd4
--- /dev/null
+++ b/meta/recipes-rt/rt-tests/rt-tests_1.8.bb
@@ -0,0 +1,35 @@
+SUMMARY = "Real-Time preemption testcases"
+HOMEPAGE = "https://rt.wiki.kernel.org/index.php/Cyclictest"
+SECTION = "tests"
+DEPENDS = "linux-libc-headers virtual/libc numactl"
+LICENSE = "GPLv2 & GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
+
+require rt-tests.inc
+inherit ptest
+
+SRC_URI += " \
+            file://run-ptest \
+            file://rt_bmark.py \
+            file://0001-Makefile-Allow-for-CC-and-AR-to-be-overridden.patch \
+           "
+
+# rt-tests needs PI mutex support in libc
+COMPATIBLE_HOST_libc-musl = 'null'
+
+# Do not install hwlatdetect
+EXTRA_OEMAKE += "PYLIB=''"
+
+do_install() {
+        oe_runmake install DESTDIR=${D} SBINDIR=${sbindir} MANDIR=${mandir} \
+                           INCLUDEDIR=${includedir}
+}
+
+do_install_ptest() {
+        cp ${WORKDIR}/rt_bmark.py ${D}${PTEST_PATH}
+}
+
+RDEPENDS_${PN}-ptest += " stress-ng python3 python3-multiprocessing python3-datetime python3-misc"
+
+FILES_${PN} += "${prefix}/src/backfire"
+RDEPENDS_${PN} += "bash"