rt-tests: bump to v0.94

All of the rt-tests patches that OE has been carrying have been
upstreamed or superceded by changes in the v0.94 release.

Adjust SRC_URI to point to canonical upstream git repo, instead of a
development tree.

There was a notable change upstream that required slight reworking of
the recipe.  rt-tests now joins other kbuild-inspired projects by making
use of a CROSS_COMPILE flag to indicate the compiler prefix.

Previously TOOLCHAIN_OPTIONS were conveyed via $CC directly, however,
this does not work with CROSS_COMPILE.  Workaround this by both
specifying CROSS_COMPILE, and feeding the rt-tests build system the
proper $(HOST_CC_ARCH)$(TOOLCHAIN_OPTIONS) via $CFLAGS.

(From OE-Core rev: 37bd229626a259d2509a9cdd2d6a2d934121e9ca)

Signed-off-by: Josh Cartwright <joshc@ni.com>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 32 insertions, 0 deletions

diff --git a/meta/recipes-rt/rt-tests/rt-tests_0.94.bb b/meta/recipes-rt/rt-tests/rt-tests_0.94.bb
new file mode 100644
index 0000000000..7d703925a8
--- /dev/null
+++ b/meta/recipes-rt/rt-tests/rt-tests_0.94.bb
@@ -0,0 +1,32 @@
+SUMMARY = "Real-Time preemption testcases"
+HOMEPAGE = "https://rt.wiki.kernel.org/index.php/Cyclictest"
+SECTION = "tests"
+DEPENDS = "linux-libc-headers virtual/libc"
+LICENSE = "GPLv2 & GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe \
+                    file://src/cyclictest/cyclictest.c;beginline=7;endline=9;md5=e768b8da44555fe63f65e5c497844cb5 \
+                    file://src/pi_tests/pi_stress.c;beginline=6;endline=19;md5=bd426a634a43ec612e9fbf125dfcc949"
+
+require rt-tests.inc
+inherit ptest
+
+SRC_URI += "file://run-ptest \
+            file://rt_bmark.py \
+           "
+# Do not install hwlatdetect
+EXTRA_OEMAKE += "PYLIB='' CROSS_COMPILE=${TARGET_PREFIX}"
+
+CFLAGS_prepend = "${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
+
+do_install() {
+        oe_runmake install DESTDIR=${D} SBINDIR=${sbindir} MANDIR=${mandir} \
+                           INCLUDEDIR=${includedir}
+}
+
+do_install_ptest() {
+        cp ${WORKDIR}/rt_bmark.py ${D}${PTEST_PATH}
+}
+
+RDEPENDS_${PN}-ptest += " stress python python-subprocess python-multiprocessing python-datetime python-re python-lang"
+
+FILES_${PN} += "${prefix}/src/backfire"