alsa-lib: 1.1.9 -> 1.2.1.2

Changelogs:
https://alsa-project.org/wiki/Changes_v1.1.9_v1.2.1
https://alsa-project.org/wiki/Changes_v1.2.1_v1.2.1.1
https://alsa-project.org/wiki/Changes_v1.2.1.1_v1.2.1.2

This upgrade brings support for the new "UCM2" configuration format.
Another big change is that the UCM and topology configuration files were
moved to separate repositories, so those are removed from alsa-lib and
will need to be packaged separately.

The topology API was moved from libasound to a separate libatopology
library. This seems like a recipe for regressions for applications that
used to use libasound for the topology stuff, but I don't think there
are many applications in existence that use the topology API. I hope the
upstream knows what they are doing.

Patches added:

0001-configure.ac-remove-an-unnecessary-libtool-fix.patch
This fixes a failure during configure.

0001-ucm-Use-strncmp-to-avoid-access-out-of-boundary.patch
0002-ucm-return-always-at-least-NULL-if-no-list-is-availa.patch
Backports. I don't know if these are regression fixes, but since the UCM
code was heavily worked on in this upgrade, it seems likely that these
patches fix regressions.

0003-namehint-correct-the-args-check.patch
0004-namehint-improve-the-previous-patch-check-the-return.patch
Backports. A change in alsa-plugins caused a regression in the pulse
plugin, but that was actually due to a bug in alsa-lib, which is fixed
by these patches.

0005-ucm-Do-not-fail-to-parse-configs-on-cards-with-an-em.patch
Backport. Fixes a regression with some Intel hardware.

0001-Fix-alsa-sound-.h-for-external-programs.patch
0001-uapi-Move-typedefs-from-uapi-to-sound.patch
Backports. These fix build failures in alsa-tools.

I removed alsa-doc from PACKAGES, because no files were assigned to it.

(From OE-Core rev: 966890009b4dd81abb72534192c688dbd1195d00)

Signed-off-by: Tanu Kaskinen <tanuk@iki.fi>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 51 insertions, 0 deletions

diff --git a/meta/recipes-multimedia/alsa/alsa-lib_1.2.1.2.bb b/meta/recipes-multimedia/alsa/alsa-lib_1.2.1.2.bb
new file mode 100644
index 0000000000..9565ad1b20
--- /dev/null
+++ b/meta/recipes-multimedia/alsa/alsa-lib_1.2.1.2.bb
@@ -0,0 +1,51 @@
+SUMMARY = "ALSA sound library"
+HOMEPAGE = "http://www.alsa-project.org"
+BUGTRACKER = "http://alsa-project.org/main/index.php/Bug_Tracking"
+SECTION = "libs/multimedia"
+LICENSE = "LGPLv2.1 & GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=a916467b91076e631dd8edb7424769c7 \
+                    file://src/socket.c;md5=285675b45e83f571c6a957fe4ab79c93;beginline=9;endline=24 \
+                    "
+
+SRC_URI = "https://www.alsa-project.org/files/pub/lib/${BP}.tar.bz2 \
+           file://0001-configure.ac-remove-an-unnecessary-libtool-fix.patch \
+           file://0001-ucm-Use-strncmp-to-avoid-access-out-of-boundary.patch \
+           file://0002-ucm-return-always-at-least-NULL-if-no-list-is-availa.patch \
+           file://0003-namehint-correct-the-args-check.patch \
+           file://0004-namehint-improve-the-previous-patch-check-the-return.patch \
+           file://0005-ucm-Do-not-fail-to-parse-configs-on-cards-with-an-em.patch \
+           file://0001-Fix-alsa-sound-.h-for-external-programs.patch \
+           file://0001-uapi-Move-typedefs-from-uapi-to-sound.patch \
+           "
+SRC_URI[md5sum] = "82ddd3698469beec147e4f4a67134ea0"
+SRC_URI[sha256sum] = "958e260e3673f1f6ff6b2d2c0df3fc2e469bea5b2957163ce96ce17f23e87943"
+
+inherit autotools pkgconfig
+
+EXTRA_OECONF += " \
+    ${@bb.utils.contains('TARGET_FPU', 'soft', '--with-softfloat', '', d)} \
+    --disable-python \
+"
+
+PACKAGES =+ "alsa-server alsa-conf libatopology"
+
+FILES_alsa-server = "${bindir}/*"
+FILES_alsa-conf = "${datadir}/alsa/"
+FILES_libatopology = "${libdir}/libatopology.so.*"
+
+RDEPENDS_${PN}_class-target = "alsa-conf"
+
+# upgrade path
+RPROVIDES_${PN} = "libasound"
+RREPLACES_${PN} = "libasound"
+RCONFLICTS_${PN} = "libasound"
+
+RPROVIDES_${PN}-dev = "alsa-dev"
+RREPLACES_${PN}-dev = "alsa-dev"
+RCONFLICTS_${PN}-dev = "alsa-dev"
+
+RPROVIDES_alsa-conf = "alsa-conf-base"
+RREPLACES_alsa-conf = "alsa-conf-base"
+RCONFLICTS_alsa-conf = "alsa-conf-base"
+
+BBCLASSEXTEND = "native nativesdk"