libpng12: rename libpng_1.2.50 to libpng12

As Mark's suggestion, rename libpng_1.2.50 to libpng12 that
multi-versions libpng could coexist.

We want to make sure we have both the old and new versions to meet LSB
compliance (for people who have that enabled) as well as the new version
for newer applications.

And drop link files that conflict with higher version.

[YOCTO #4221]

(From OE-Core rev: fc626e6861e491b0144b813a5b48b0f5f57664e6)

Signed-off-by: Kang Kai <kai.kang@windriver.com>
CC: Mark Hatle <mark.hatle@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 35 insertions, 0 deletions

diff --git a/meta/recipes-lsb4/libpng/libpng12_1.2.50.bb b/meta/recipes-lsb4/libpng/libpng12_1.2.50.bb
new file mode 100644
index 0000000000..cfefd41beb
--- /dev/null
+++ b/meta/recipes-lsb4/libpng/libpng12_1.2.50.bb
@@ -0,0 +1,35 @@
+SUMMARY = "PNG Library"
+DESCRIPTION = "PNG Library"
+HOMEPAGE = "http://www.libpng.org/"
+SECTION = "libs"
+LICENSE = "Libpng"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=c3d807a85c09ebdff087f18b4969ff96 \
+                    file://png.h;beginline=310;endline=424;md5=b87b5e9252a3e14808a27b92912d268d"
+DEPENDS = "zlib"
+PR = "r0"
+
+PN = "libpng12"
+S = "${WORKDIR}/libpng-${PV}"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/project/libpng/libpng12/${PV}/libpng-${PV}.tar.xz"
+
+SRC_URI[md5sum] = "a3e00fccbfe356174ab515b5c00641c7"
+SRC_URI[sha256sum] = "4724f81f8c92ac7f360ad1fbf173396ea7c535923424db9fbaff07bfd9d8e8e7"
+
+BINCONFIG_GLOB = "${PN}-config"
+
+inherit autotools binconfig pkgconfig
+
+do_install_append() {
+        # The follow link files link to corresponding png12*.h and libpng12* files
+        # They conflict with higher verison, so drop them
+        unlink ${D}/${includedir}/png.h
+        unlink ${D}/${includedir}/pngconf.h
+
+        unlink ${D}/${libdir}/libpng.la
+        unlink ${D}/${libdir}/libpng.so
+        unlink ${D}/${libdir}/libpng.a
+        unlink ${D}/${libdir}/pkgconfig/libpng.pc
+
+        unlink ${D}/${bindir}/libpng-config
+}