powertop: upgrade 2.10 -> 2.12

(From OE-Core rev: f1cb1f5b29ac25b75c0872c91e36bb16b69afc76)

Signed-off-by: Alexander Kanavin <alex.kanavin@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 32 insertions, 0 deletions

diff --git a/meta/recipes-kernel/powertop/powertop_2.12.bb b/meta/recipes-kernel/powertop/powertop_2.12.bb
new file mode 100644
index 0000000000..f085d9b482
--- /dev/null
+++ b/meta/recipes-kernel/powertop/powertop_2.12.bb
@@ -0,0 +1,32 @@
+SUMMARY = "Power usage tool"
+DESCRIPTION = "Linux tool to diagnose issues with power consumption and power management."
+HOMEPAGE = "https://01.org/powertop/"
+BUGTRACKER = "https://app.devzing.com/powertopbugs/bugzilla"
+DEPENDS = "ncurses libnl pciutils autoconf-archive"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=12f884d2ae1ff87c09e5b7ccc2c4ca7e"
+
+SRC_URI = "git://github.com/fenrus75/powertop;protocol=https \
+    file://0001-wakeup_xxx.h-include-limits.h.patch \
+"
+SRCREV = "6988eaaa5bbcfff1dd86f757006c6c48cec965c5"
+
+S = "${WORKDIR}/git"
+
+inherit autotools gettext pkgconfig bash-completion
+
+# we do not want libncursesw if we can
+do_configure_prepend() {
+    # configure.ac checks for delwin() in "ncursesw ncurses" so let's drop first one
+    sed -i -e "s/ncursesw//g" ${S}/configure.ac
+    mkdir -p ${B}/src/tuning/
+    echo "${PV}" > ${S}/version-long
+    echo "${PV}" > ${S}/version-short
+    cp ${STAGING_DATADIR}/aclocal/ax_require_defined.m4 ${S}/m4/
+}
+
+inherit update-alternatives
+ALTERNATIVE_${PN} = "powertop"
+ALTERNATIVE_TARGET[powertop] = "${sbindir}/powertop"
+ALTERNATIVE_LINK_NAME[powertop] = "${sbindir}/powertop"
+ALTERNATIVE_PRIORITY = "100"