diff options
author | Anders Wallin <wallinux@gmail.com> | 2020-03-13 13:14:58 +0100 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2020-03-13 23:00:26 +0000 |
commit | 6a999ec1b589ab1d3619e0f08976fbdb860c3540 (patch) | |
tree | 2a2e30fb7dc4ab089cce564fae4aea5ac458bd53 /meta/recipes-kernel/lttng/babeltrace2_2.0.2.bb | |
parent | 1e647ab5a9b9d7318786d585d6fd1ec8c7628a69 (diff) | |
download | poky-6a999ec1b589ab1d3619e0f08976fbdb860c3540.tar.gz |
babeltrace2: updated to 2.0.2
(From OE-Core rev: b1ae2178fa188b2864280f2c3a9ba443e042cae0)
Signed-off-by: Anders Wallin <wallinux@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-kernel/lttng/babeltrace2_2.0.2.bb')
-rw-r--r-- | meta/recipes-kernel/lttng/babeltrace2_2.0.2.bb | 94 |
1 files changed, 94 insertions, 0 deletions
diff --git a/meta/recipes-kernel/lttng/babeltrace2_2.0.2.bb b/meta/recipes-kernel/lttng/babeltrace2_2.0.2.bb new file mode 100644 index 0000000000..0791c654f9 --- /dev/null +++ b/meta/recipes-kernel/lttng/babeltrace2_2.0.2.bb | |||
@@ -0,0 +1,94 @@ | |||
1 | SUMMARY = "Babeltrace2 - Trace Format Babel Tower" | ||
2 | DESCRIPTION = "Babeltrace provides trace read and write libraries in host side, as well as a trace converter, which used to convert LTTng 2.0 traces into human-readable log." | ||
3 | HOMEPAGE = "http://babeltrace.org/" | ||
4 | BUGTRACKER = "https://bugs.lttng.org/projects/babeltrace" | ||
5 | LICENSE = "MIT & GPLv2 & LGPLv2.1 & BSD-2-Clause" | ||
6 | LIC_FILES_CHKSUM = "file://LICENSE;md5=a6a458c13f18385b7bc5069a6d7b176e" | ||
7 | |||
8 | DEPENDS = "glib-2.0 util-linux popt bison-native flex-native" | ||
9 | |||
10 | SRC_URI = "git://git.linuxfoundation.org/diamon/babeltrace.git;branch=stable-2.0 \ | ||
11 | file://run-ptest \ | ||
12 | file://0001-tests-do-not-run-test-applications-from-.libs.patch \ | ||
13 | file://0001-Make-manpages-multilib-identical.patch \ | ||
14 | file://0001-fs.c-initialize-other_entry.patch \ | ||
15 | " | ||
16 | SRCREV = "33003c352ed56aa49e0b3df272bbab6fac36cae8" | ||
17 | UPSTREAM_CHECK_GITTAGREGEX = "v(?P<pver>2(\.\d+)+)$" | ||
18 | |||
19 | S = "${WORKDIR}/git" | ||
20 | |||
21 | inherit autotools pkgconfig ptest | ||
22 | |||
23 | EXTRA_OECONF = "--disable-debug-info" | ||
24 | |||
25 | PACKAGECONFIG ??= "manpages" | ||
26 | PACKAGECONFIG[manpages] = ", --disable-man-pages, asciidoc-native xmlto-native" | ||
27 | |||
28 | FILES_${PN}-staticdev += "${libdir}/babeltrace2/plugins/*.a" | ||
29 | FILES_${PN} += "${libdir}/babeltrace2/plugins/*.so" | ||
30 | |||
31 | ASNEEDED = "" | ||
32 | |||
33 | RDEPENDS_${PN}-ptest += "bash gawk python3" | ||
34 | |||
35 | do_compile_ptest () { | ||
36 | make -C tests all | ||
37 | } | ||
38 | |||
39 | do_install_ptest () { | ||
40 | install -d "${D}${PTEST_PATH}/tests" | ||
41 | |||
42 | # Copy required files from source directory | ||
43 | for d in $(find "${S}/tests" -type d -printf '%P ') ; do | ||
44 | install -d "${D}${PTEST_PATH}/tests/$d" | ||
45 | find "${S}/tests/$d" -maxdepth 1 -executable -type f \ | ||
46 | -exec install -t "${D}${PTEST_PATH}/tests/$d" {} + | ||
47 | find "${S}/tests/$d" -maxdepth 1 -name *.sh \ | ||
48 | -exec install -t "${D}${PTEST_PATH}/tests/$d" {} \; | ||
49 | find "${S}/tests/$d" -maxdepth 1 -name *.py \ | ||
50 | -exec install -t "${D}${PTEST_PATH}/tests/$d" {} \; | ||
51 | find "${S}/tests/$d" -maxdepth 1 -name *.expect \ | ||
52 | -exec install -t "${D}${PTEST_PATH}/tests/$d" {} \; | ||
53 | done | ||
54 | install -d "${D}${PTEST_PATH}/tests/data/ctf-traces/" | ||
55 | cp -a ${S}/tests/data/ctf-traces/* ${D}${PTEST_PATH}/tests/data/ctf-traces/ | ||
56 | |||
57 | # Copy the tests directory tree and the executables and | ||
58 | # Makefiles found within. | ||
59 | install -D "${B}/tests/Makefile" "${D}${PTEST_PATH}/tests/" | ||
60 | for d in $(find "${B}/tests" -type d -not -name .libs -printf '%P ') ; do | ||
61 | install -d "${D}${PTEST_PATH}/tests/$d" | ||
62 | find "${B}/tests/$d" -maxdepth 1 -executable -type f \ | ||
63 | -exec install -t "${D}${PTEST_PATH}/tests/$d" {} + | ||
64 | test -r "${B}/tests/$d/Makefile" && \ | ||
65 | install -t "${D}${PTEST_PATH}/tests/$d" "${B}/tests/$d/Makefile" | ||
66 | find "${B}/tests/$d" -maxdepth 1 -name *.sh \ | ||
67 | -exec install -t "${D}${PTEST_PATH}/tests/$d" {} \; | ||
68 | done | ||
69 | |||
70 | for d in $(find "${B}/tests" -type d -name .libs -printf '%P ') ; do | ||
71 | for f in $(find "${B}/tests/$d" -maxdepth 1 -executable -type f -printf '%P ') ; do | ||
72 | cp ${B}/tests/$d/$f ${D}${PTEST_PATH}/tests/`dirname $d`/$f | ||
73 | done | ||
74 | done | ||
75 | |||
76 | # Prevent attempts to update Makefiles during test runs, and | ||
77 | # silence "Making check in $SUBDIR" messages. | ||
78 | find "${D}${PTEST_PATH}" -name Makefile -type f -exec \ | ||
79 | sed -i \ | ||
80 | -e '/Makefile:/,/^$/d' \ | ||
81 | -e '/%: %.in/,/^$/d' \ | ||
82 | -e '/echo "Making $$target in $$subdir"; \\/d' \ | ||
83 | -e 's/^srcdir = \(.*\)/srcdir = ./' \ | ||
84 | -e 's/^builddir = \(.*\)/builddir = ./' \ | ||
85 | -e 's/^all-am:.*/all-am:/' \ | ||
86 | {} + | ||
87 | |||
88 | # Substitute links to installed binaries. | ||
89 | install -d "${D}${PTEST_PATH}/src/cli/" | ||
90 | ln -s "${bindir}/babeltrace2" ${D}${PTEST_PATH}/src/cli/ | ||
91 | |||
92 | # Remove architechture specific testfiles | ||
93 | rm -rf ${D}${PTEST_PATH}/tests/data/plugins/flt.lttng-utils.debug-info/* | ||
94 | } | ||