lttng2-ust: rename to lttng-ust

recipes-kernel/lttng/lttng-ust was removed by a previous patch, which
also removed the naming conflict that caused the lttng-2.0 version of
lttng-ust to be named lttng2-ust.  lttng2-ust was the only lttng-2.0
recipe to be named in this way and since that was entirely due to the
conflict, we can go back to the consistent naming for it.

(From OE-Core rev: 3c927c39502061bdf3ef9fba1f0f6e7080f6c3cd)

Signed-off-by: Tom Zanussi <tom.zanussi@intel.com>
Signed-off-by: Saul Wold <sgw@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 35 insertions, 0 deletions

diff --git a/meta/recipes-kernel/lttng-2.0/lttng-ust_2.1.0.bb b/meta/recipes-kernel/lttng-2.0/lttng-ust_2.1.0.bb
new file mode 100644
index 0000000000..1076bde574
--- /dev/null
+++ b/meta/recipes-kernel/lttng-2.0/lttng-ust_2.1.0.bb
@@ -0,0 +1,35 @@
+SUMMARY = "Linux Trace Toolkit Userspace Tracer 2.0"
+DESCRIPTION = "The LTTng UST 2.0 package contains the userspace tracer library to trace userspace codes."
+HOMEPAGE = "http://lttng.org/lttng2.0"
+BUGTRACKER = "n/a"
+
+LICENSE = "LGPLv2.1+ & BSD & GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=c963eb366b781252b0bf0fdf1624d9e9 \
+                    file://snprintf/snprintf.c;endline=32;md5=d3d544959d8a3782b2e07451be0a903c \
+                    file://snprintf/various.h;endline=31;md5=89f2509b6b4682c4fc95255eec4abe44"
+
+inherit autotools
+
+DEPENDS = "liburcu util-linux"
+
+# For backwards compatibility after rename
+RPROVIDES_${PN} = "lttng2-ust"
+RREPLACES_${PN} = "lttng2-ust"
+RCONFLICTS_${PN} = "lttng2-ust"
+
+SRCREV = "0c9ad44b7604040dfcd1e67b18afc3dc5d025b19"
+PV = "2.1.0"
+PR = "r0"
+
+SRC_URI = "git://git.lttng.org/lttng-ust.git;protocol=git"
+
+S = "${WORKDIR}/git"
+
+do_configure_prepend () {
+        ${S}/bootstrap
+}
+
+# Due to liburcu not building for MIPS currently this recipe needs to
+# be limited also.
+# So here let us first suppport x86/arm/powerpc platforms now.
+COMPATIBLE_HOST = '(x86_64.*|i.86.*|arm.*|powerpc.*)-linux.*'