linux-yocto: rename recipes to explicitly indicate version

The existing recipe names for the linux-yocto kernel builds
worked well when there was a single, or two versions of the
kernel available. But with the impending kernel updates and
retirement of older kernels, the re-use of the same recipes
for different kernel versions violates the principle of least
surprise.

To address this, the recipes are being renamed as follows:

    linux-yocto_git.bb -> linux-yocto_2.6.37.bb
    linux-yocto-stable_git.bb -> linux-yocto_2.6.34.bb

There continue to be versionless recipe names that feed into
versioned recipes at the appropriate points. They are:

     linux-yocto-dev.bb (tracking the latest yocto dev kernel)
     linux-yocto-korg_head.bb (tracking korg kernels)

There are no existing users of linux-yocto-stable in the master
branches to convert to the new naming, so these changes work
in isolation.

(From OE-Core rev: 576c87349a72a94357014ff29f55db692903ed80)

Signed-off-by: Bruce Ashfield <bruce.ashfield@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 49 insertions, 0 deletions

diff --git a/meta/recipes-kernel/linux/linux-yocto_2.6.34.bb b/meta/recipes-kernel/linux/linux-yocto_2.6.34.bb
new file mode 100644
index 0000000000..66991aeded
--- /dev/null
+++ b/meta/recipes-kernel/linux/linux-yocto_2.6.34.bb
@@ -0,0 +1,49 @@
+inherit kernel
+require linux-yocto.inc
+
+KMACHINE = "common_pc"
+KMACHINE_qemux86  = "common_pc"
+KMACHINE_qemux86-64  = "common_pc_64"
+KMACHINE_qemuppc  = "qemu_ppc32"
+KMACHINE_qemumips = "mti_malta32_be"
+KMACHINE_qemuarm  = "arm_versatile_926ejs"
+
+LINUX_VERSION ?= "2.6.34"
+LINUX_VERSION_EXTENSION ?= "-yocto-${LINUX_KERNEL_TYPE_EXTENSION}"
+
+KMETA = wrs_meta
+KBRANCH = ${KMACHINE}-${LINUX_KERNEL_TYPE_EXTENSION}
+
+SRCREV_machine_qemuarm = "a2fb081b44d6368eff8d28e2fdb991c61b1f428e"
+SRCREV_machine_qemumips = "c32d40f960e3c89d07f079bec4c96dcbfc749f0b"
+SRCREV_machine_qemuppc = "96d6bc31d3caaf62a966255479cc5cee0e76b1e9"
+SRCREV_machine_qemux86 = "72ca49ab08b8eb475cec82a10049503602325791"
+SRCREV_machine_qemux86-64 = "72ca49ab08b8eb475cec82a10049503602325791"
+SRCREV_machine = "72ca49ab08b8eb475cec82a10049503602325791"
+SRCREV_meta = "ec26387cb168e9e0976999b528b5a9dd62e3157a"
+
+PR = "r1"
+PV = "${LINUX_VERSION}+git${SRCPV}"
+SRCREV_FORMAT = "meta_machine"
+
+COMPATIBLE_MACHINE = "(qemuarm|qemux86|qemuppc|qemumips|qemux86-64)"
+
+# this performs a fixup on historical kernel types with embedded _'s
+python __anonymous () {
+    import bb, re, string
+
+    kerntype = string.replace(bb.data.expand("${LINUX_KERNEL_TYPE}", d), "_", "-")
+    bb.data.setVar("LINUX_KERNEL_TYPE_EXTENSION", kerntype, d)
+}
+
+SRC_URI = "git://git.yoctoproject.org/linux-yocto-2.6.34.git;protocol=git;nocheckout=1;branch=${KBRANCH},wrs_meta;name=machine,meta"
+
+# Functionality flags
+KERNEL_REVISION_CHECKING ?= "t"
+KERNEL_FEATURES=features/netfilter
+
+# extra tasks
+addtask kernel_link_vmlinux after do_compile before do_install
+addtask validate_branches before do_patch after do_kernel_checkout
+
+require linux-tools.inc