Major layout change to the packages directory

Having one monolithic packages directory makes it hard to find things
and is generally overwhelming. This commit splits it into several
logical sections roughly based on function, recipes.txt gives more
information about the classifications used.

The opportunity is also used to switch from "packages" to "recipes"
as used in OpenEmbedded as the term "packages" can be confusing to
people and has many different meanings.

Not all recipes have been classified yet, this is just a first pass
at separating things out. Some packages are moved to meta-extras as
they're no longer actively used or maintained.

Signed-off-by: Richard Purdie <rpurdie@linux.intel.com>

1 files changed, 38 insertions, 0 deletions

diff --git a/meta/recipes-kernel/linux/linux-mx31.inc b/meta/recipes-kernel/linux/linux-mx31.inc
new file mode 100644
index 0000000000..520229cf7f
--- /dev/null
+++ b/meta/recipes-kernel/linux/linux-mx31.inc
@@ -0,0 +1,38 @@
+SECTION = "kernel"
+DESCRIPTION = "Linux kernel for imx31 devices"
+LICENSE = "GPL"
+
+KERNEL_OUTPUT = "arch/${ARCH}/boot/${KERNEL_IMAGETYPE}"
+
+inherit kernel deploy
+
+COMPATIBLE_MACHINE = "mx31litekit|mx31ads|mx31phy"
+
+do_configure_prepend() {
+
+        rm -f ${S}/.config || true
+
+        if [ "${TARGET_OS}" = "linux-gnueabi" -o  "${TARGET_OS}" = "linux-uclibcgnueabi" ]; then
+                echo "CONFIG_AEABI=y"                   >> ${S}/.config
+                echo "CONFIG_OABI_COMPAT=y"             >> ${S}/.config
+        else
+                echo "# CONFIG_AEABI is not set"        >> ${S}/.config
+                echo "# CONFIG_OABI_COMPAT is not set"  >> ${S}/.config
+        fi
+
+        sed     -e '/CONFIG_AEABI/d' \
+                -e '/CONFIG_OABI_COMPAT=/d' \
+                '${WORKDIR}/defconfig-${MACHINE}' >>'${S}/.config'
+
+        yes '' | oe_runmake oldconfig
+
+}
+
+do_deploy() {
+        install -m 0644 arch/${ARCH}/boot/${KERNEL_IMAGETYPE} ${DEPLOYDIR}/${KERNEL_IMAGETYPE}-${PV}-${MACHINE}-${DATETIME}.bin
+        cd ${DEPLOYDIR}
+        ln -sf ${KERNEL_IMAGETYPE}-${PV}-${MACHINE}-${DATETIME}.bin ${KERNEL_IMAGETYPE}-${MACHINE}.bin
+        tar -cvzf ${DEPLOYDIR}/modules-${KERNEL_RELEASE}-${MACHINE}.tgz -C ${D} lib
+}
+
+addtask deploy before do_populate_sysroot after do_install