Major layout change to the packages directory

Having one monolithic packages directory makes it hard to find things
and is generally overwhelming. This commit splits it into several
logical sections roughly based on function, recipes.txt gives more
information about the classifications used.

The opportunity is also used to switch from "packages" to "recipes"
as used in OpenEmbedded as the term "packages" can be confusing to
people and has many different meanings.

Not all recipes have been classified yet, this is just a first pass
at separating things out. Some packages are moved to meta-extras as
they're no longer actively used or maintained.

Signed-off-by: Richard Purdie <rpurdie@linux.intel.com>

5 files changed, 162 insertions, 0 deletions

diff --git a/meta/recipes-kernel/linux-libc-headers/linux-libc-headers-wrs_git.bb b/meta/recipes-kernel/linux-libc-headers/linux-libc-headers-wrs_git.bb
new file mode 100644
index 0000000000..ab25e500ba
--- /dev/null
+++ b/meta/recipes-kernel/linux-libc-headers/linux-libc-headers-wrs_git.bb
@@ -0,0 +1,51 @@
+require linux-libc-headers.inc
+
+INHIBIT_DEFAULT_DEPS = "1"
+DEPENDS += "unifdef-native"
+PROVIDES = "linux-libc-headers"
+PV = "2.6.34+git-${SRCPV}"
+PR = "r0"
+
+SRC_URI = "git://git.pokylinux.org/linux-2.6-windriver.git;fullclone=1"
+
+S = "${WORKDIR}/linux"
+
+set_arch() {
+        case ${TARGET_ARCH} in
+                arm*)     ARCH=arm ;;
+                i*86*)    ARCH=i386 ;;
+                ia64*)    ARCH=ia64 ;;
+                mips*)    ARCH=mips ;;
+                powerpc*) ARCH=powerpc ;;
+                x86_64*)  ARCH=x86_64 ;;
+        esac
+}
+
+do_configure() {
+        set_arch
+        oe_runmake allnoconfig ARCH=$ARCH
+}
+
+do_wrlinux_checkout() {
+        if [ -d ${WORKDIR}/.git/refs/remotes/origin ]; then
+                rm -rf ${S}
+                mkdir ${S}
+                mv ${WORKDIR}/.git ${S}
+                mv ${S}/.git/refs/remotes/origin/* ${S}/.git/refs/heads
+                rmdir ${S}/.git/refs/remotes/origin
+        fi
+        cd ${S}
+        git checkout -f standard
+}
+
+addtask wrlinux_checkout before do_patch after do_unpack
+
+do_compile () {
+}
+
+do_install() {
+        set_arch
+        oe_runmake headers_install_all INSTALL_HDR_PATH=${D}${exec_prefix} ARCH=$ARCH
+}
+
+BBCLASSEXTEND = "nativesdk"
diff --git a/meta/recipes-kernel/linux-libc-headers/linux-libc-headers.inc b/meta/recipes-kernel/linux-libc-headers/linux-libc-headers.inc
new file mode 100644
index 0000000000..e6cb1d8669
--- /dev/null
+++ b/meta/recipes-kernel/linux-libc-headers/linux-libc-headers.inc
@@ -0,0 +1,10 @@
+DESCRIPTION = "Sanitized set of 2.6 kernel headers for the C library's use."
+SECTION = "devel"
+LICENSE = "GPLv2"
+
+LIC_CHKSUM_FILES = "file://COPYING " 
+SRC_URI = "${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/linux-${PV}.tar.bz2"
+
+#DEPENDS = "cross-linkage"
+RDEPENDS_${PN}-dev = ""
+RRECOMMENDS_${PN}-dbg = "${PN}-dev (= ${EXTENDPV})"
diff --git a/meta/recipes-kernel/linux-libc-headers/linux-libc-headers/hayes-gone.patch b/meta/recipes-kernel/linux-libc-headers/linux-libc-headers/hayes-gone.patch
new file mode 100644
index 0000000000..719c320202
--- /dev/null
+++ b/meta/recipes-kernel/linux-libc-headers/linux-libc-headers/hayes-gone.patch
@@ -0,0 +1,28 @@
+# 2.6.33 deleted the Hayes esp driver, so the ioctls to get and set its
+# configuration are no longer needed, and they break setserial by making it
+# believe that it should compile in the code that supports this modem.
+
+2010/06/16
+Created-by: Jeff Dike <jdike@linux.intel.com>
+
+Index: linux-2.6.34/include/asm-generic/ioctls.h
+===================================================================
+--- linux-2.6.34.orig/include/asm-generic/ioctls.h
++++ linux-2.6.34/include/asm-generic/ioctls.h
+@@ -86,16 +86,6 @@
+ #define TIOCMIWAIT     0x545C  /* wait for a change on serial input line(s) */
+ #define TIOCGICOUNT    0x545D  /* read serial port inline interrupt counts */
+ 
+-/*
+- * some architectures define FIOQSIZE as 0x545E, which is used for
+- * TIOCGHAYESESP on others
+- */
+-#ifndef FIOQSIZE
+-# define TIOCGHAYESESP 0x545E  /* Get Hayes ESP configuration */
+-# define TIOCSHAYESESP 0x545F  /* Set Hayes ESP configuration */
+-# define FIOQSIZE      0x5460
+-#endif
+-
+ /* Used for packet mode */
+ #define TIOCPKT_DATA            0
+ #define TIOCPKT_FLUSHREAD       1
diff --git a/meta/recipes-kernel/linux-libc-headers/linux-libc-headers/ppc_glibc_build_fix.patch b/meta/recipes-kernel/linux-libc-headers/linux-libc-headers/ppc_glibc_build_fix.patch
new file mode 100644
index 0000000000..81fa5ce8c9
--- /dev/null
+++ b/meta/recipes-kernel/linux-libc-headers/linux-libc-headers/ppc_glibc_build_fix.patch
@@ -0,0 +1,25 @@
+stdint.h has C definitions which troubles assembler. and if asm/ptrace.h 
+is included in assembler context, then it should not include the 
+C-specific stdint.h file.
+  This was causing glibc building issue on ppc.
+Looks like this issue is introduced on the 2.6.34 kernel.
+
+2010-06-024
+Signed-Off-By:Nitin A Kamble <nitin.a.kamble@intel.com>
+Acked-By:Jeff Dike <jdike@linux.intel.com>
+
+Index: linux-2.6.34/arch/powerpc/include/asm/ptrace.h
+===================================================================
+--- linux-2.6.34.orig/arch/powerpc/include/asm/ptrace.h
++++ linux-2.6.34/arch/powerpc/include/asm/ptrace.h
+@@ -27,8 +27,10 @@
+ #ifdef __KERNEL__
+ #include <linux/types.h>
+ #else
++#ifndef __ASSEMBLY__
+ #include <stdint.h>
+ #endif
++#endif
+ 
+ #ifndef __ASSEMBLY__
+ 
diff --git a/meta/recipes-kernel/linux-libc-headers/linux-libc-headers_2.6.34.bb b/meta/recipes-kernel/linux-libc-headers/linux-libc-headers_2.6.34.bb
new file mode 100644
index 0000000000..31c305854f
--- /dev/null
+++ b/meta/recipes-kernel/linux-libc-headers/linux-libc-headers_2.6.34.bb
@@ -0,0 +1,48 @@
+require linux-libc-headers.inc
+
+INHIBIT_DEFAULT_DEPS = "1"
+DEPENDS += "unifdef-native"
+PR = "r0"
+
+SRC_URI += "file://hayes-gone.patch \
+           file://ppc_glibc_build_fix.patch"
+
+S = "${WORKDIR}/linux-${PV}"
+
+set_arch() {
+        case ${TARGET_ARCH} in
+                alpha*)   ARCH=alpha ;;
+                arm*)     ARCH=arm ;;
+                cris*)    ARCH=cris ;;
+                hppa*)    ARCH=parisc ;;
+                i*86*)    ARCH=i386 ;;
+                ia64*)    ARCH=ia64 ;;
+                mips*)    ARCH=mips ;;
+                m68k*)    ARCH=m68k ;;
+                powerpc*) ARCH=powerpc ;;
+                s390*)    ARCH=s390 ;;
+                sh*)      ARCH=sh ;;
+                sparc64*) ARCH=sparc64 ;;
+                sparc*)   ARCH=sparc ;;
+                x86_64*)  ARCH=x86_64 ;;
+                avr32*)   ARCH=avr32 ;;
+                bfin*)    ARCH=blackfin ;;
+        esac
+}
+
+do_configure() {
+        set_arch
+        oe_runmake allnoconfig ARCH=$ARCH
+}
+
+do_compile () {
+}
+
+do_install() {
+        set_arch
+        oe_runmake headers_install INSTALL_HDR_PATH=${D}${exec_prefix} ARCH=$ARCH
+        # Kernel should not be exporting this header
+        rm -f ${D}${exec_prefix}/include/scsi/scsi.h
+}
+
+BBCLASSEXTEND = "nativesdk"