diff options
author | Alexander Kanavin <alex.kanavin@gmail.com> | 2020-12-28 21:04:23 +0100 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2020-12-31 11:53:26 +0000 |
commit | b917439cb9df4e9f855fc8929e9f3d7dc2ffe6f1 (patch) | |
tree | edf570296d680c6f00e14ba2054308c2df8a0940 /meta/recipes-kernel/kexec/kexec-tools_2.0.21.bb | |
parent | cf8a40e6c48ce3c2888a713f0f13b73febb56091 (diff) | |
download | poky-b917439cb9df4e9f855fc8929e9f3d7dc2ffe6f1.tar.gz |
kexec-tools: update 2.0.20 -> 2.0.21
Drop patches that are either backports, or are obsolete
by upstream fixing the issues.
(From OE-Core rev: 9f4566b9dc37534fddbe65f4fd967454d3ad7690)
Signed-off-by: Alexander Kanavin <alex.kanavin@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-kernel/kexec/kexec-tools_2.0.21.bb')
-rw-r--r-- | meta/recipes-kernel/kexec/kexec-tools_2.0.21.bb | 88 |
1 files changed, 88 insertions, 0 deletions
diff --git a/meta/recipes-kernel/kexec/kexec-tools_2.0.21.bb b/meta/recipes-kernel/kexec/kexec-tools_2.0.21.bb new file mode 100644 index 0000000000..069e8f4d05 --- /dev/null +++ b/meta/recipes-kernel/kexec/kexec-tools_2.0.21.bb | |||
@@ -0,0 +1,88 @@ | |||
1 | |||
2 | SUMMARY = "Kexec fast reboot tools" | ||
3 | DESCRIPTION = "Kexec is a fast reboot feature that lets you reboot to a new Linux kernel" | ||
4 | AUTHOR = "Eric Biederman" | ||
5 | HOMEPAGE = "http://kernel.org/pub/linux/utils/kernel/kexec/" | ||
6 | SECTION = "kernel/userland" | ||
7 | LICENSE = "GPLv2" | ||
8 | LIC_FILES_CHKSUM = "file://COPYING;md5=ea5bed2f60d357618ca161ad539f7c0a \ | ||
9 | file://kexec/kexec.c;beginline=1;endline=20;md5=af10f6ae4a8715965e648aa687ad3e09" | ||
10 | DEPENDS = "zlib xz" | ||
11 | |||
12 | SRC_URI = "${KERNELORG_MIRROR}/linux/utils/kernel/kexec/kexec-tools-${PV}.tar.gz \ | ||
13 | file://kdump \ | ||
14 | file://kdump.conf \ | ||
15 | file://kdump.service \ | ||
16 | file://0001-powerpc-change-the-memory-size-limit.patch \ | ||
17 | file://0002-purgatory-Pass-r-directly-to-linker.patch \ | ||
18 | file://0003-kexec-ARM-Fix-add_buffer_phys_virt-align-issue.patch \ | ||
19 | file://0005-Disable-PIE-during-link.patch \ | ||
20 | file://0007-kexec-un-break-the-build-on-32-bit-x86.patch \ | ||
21 | file://0001-arm64-kexec-disabled-check-if-kaslr-seed-dtb-propert.patch \ | ||
22 | file://0001-kexec-arch-ppc-kexec-ppc.c-correct-double-definition.patch \ | ||
23 | " | ||
24 | |||
25 | SRC_URI[sha256sum] = "b3d4cfd2ba10d68ce341ea3b8ca414d00a0b6183b95686172154f94bce834f94" | ||
26 | |||
27 | inherit autotools update-rc.d systemd | ||
28 | |||
29 | export LDFLAGS = "-L${STAGING_LIBDIR}" | ||
30 | EXTRA_OECONF = " --with-zlib=yes" | ||
31 | |||
32 | do_compile_prepend() { | ||
33 | # Remove the prepackaged config.h from the source tree as it overrides | ||
34 | # the same file generated by configure and placed in the build tree | ||
35 | rm -f ${S}/include/config.h | ||
36 | |||
37 | # Remove the '*.d' file to make sure the recompile is OK | ||
38 | for dep in `find ${B} -type f -name '*.d'`; do | ||
39 | dep_no_d="`echo $dep | sed 's#.d$##'`" | ||
40 | # Remove file.d when there is a file.o | ||
41 | if [ -f "$dep_no_d.o" ]; then | ||
42 | rm -f $dep | ||
43 | fi | ||
44 | done | ||
45 | } | ||
46 | |||
47 | do_install_append () { | ||
48 | install -d ${D}${sysconfdir}/sysconfig | ||
49 | install -m 0644 ${WORKDIR}/kdump.conf ${D}${sysconfdir}/sysconfig | ||
50 | |||
51 | if ${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then | ||
52 | install -D -m 0755 ${WORKDIR}/kdump ${D}${sysconfdir}/init.d/kdump | ||
53 | fi | ||
54 | |||
55 | if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then | ||
56 | install -D -m 0755 ${WORKDIR}/kdump ${D}${libexecdir}/kdump-helper | ||
57 | install -D -m 0644 ${WORKDIR}/kdump.service ${D}${systemd_unitdir}/system/kdump.service | ||
58 | sed -i -e 's,@LIBEXECDIR@,${libexecdir},g' ${D}${systemd_unitdir}/system/kdump.service | ||
59 | fi | ||
60 | } | ||
61 | |||
62 | PACKAGES =+ "kexec kdump vmcore-dmesg" | ||
63 | |||
64 | ALLOW_EMPTY_${PN} = "1" | ||
65 | RRECOMMENDS_${PN} = "kexec kdump vmcore-dmesg" | ||
66 | |||
67 | FILES_kexec = "${sbindir}/kexec" | ||
68 | FILES_kdump = "${sbindir}/kdump \ | ||
69 | ${sysconfdir}/sysconfig/kdump.conf \ | ||
70 | ${sysconfdir}/init.d/kdump \ | ||
71 | ${libexecdir}/kdump-helper \ | ||
72 | ${systemd_unitdir}/system/kdump.service \ | ||
73 | " | ||
74 | |||
75 | FILES_vmcore-dmesg = "${sbindir}/vmcore-dmesg" | ||
76 | |||
77 | INITSCRIPT_PACKAGES = "kdump" | ||
78 | INITSCRIPT_NAME_kdump = "kdump" | ||
79 | INITSCRIPT_PARAMS_kdump = "start 56 2 3 4 5 . stop 56 0 1 6 ." | ||
80 | |||
81 | SYSTEMD_PACKAGES = "kdump" | ||
82 | SYSTEMD_SERVICE_kdump = "kdump.service" | ||
83 | |||
84 | SECURITY_PIE_CFLAGS_remove = "-fPIE -pie" | ||
85 | |||
86 | COMPATIBLE_HOST = '(x86_64.*|i.86.*|arm.*|aarch64.*|powerpc.*|mips.*)-(linux|freebsd.*)' | ||
87 | |||
88 | INSANE_SKIP_${PN} = "arch" | ||