diff options
author | Armin Kuster <akuster808@gmail.com> | 2018-05-18 19:13:48 -0700 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2018-05-29 21:07:14 +0100 |
commit | 6dbac6e225bb8579c6098981ed57de6001cd4d14 (patch) | |
tree | a9389bbf391ddc61689f8bcbdfcad71aea20a464 /meta/recipes-kernel/kexec/kexec-tools_2.0.17.bb | |
parent | 1f9bb6c96a24062be7e9d01abbd391f68a3cc39e (diff) | |
download | poky-6dbac6e225bb8579c6098981ed57de6001cd4d14.tar.gz |
kexec-tools: upgrade 2.0.16 -> 2.0.17
(From OE-Core rev: 8da23d49367f48a195b952b5c2e2f7ce2221a572)
Signed-off-by: Armin Kuster <akuster808@gmail.com>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-kernel/kexec/kexec-tools_2.0.17.bb')
-rw-r--r-- | meta/recipes-kernel/kexec/kexec-tools_2.0.17.bb | 84 |
1 files changed, 84 insertions, 0 deletions
diff --git a/meta/recipes-kernel/kexec/kexec-tools_2.0.17.bb b/meta/recipes-kernel/kexec/kexec-tools_2.0.17.bb new file mode 100644 index 0000000000..f4ec5865e3 --- /dev/null +++ b/meta/recipes-kernel/kexec/kexec-tools_2.0.17.bb | |||
@@ -0,0 +1,84 @@ | |||
1 | |||
2 | SUMMARY = "Kexec fast reboot tools" | ||
3 | DESCRIPTION = "Kexec is a fast reboot feature that lets you reboot to a new Linux kernel" | ||
4 | AUTHOR = "Eric Biederman" | ||
5 | HOMEPAGE = "http://kernel.org/pub/linux/utils/kernel/kexec/" | ||
6 | SECTION = "kernel/userland" | ||
7 | LICENSE = "GPLv2" | ||
8 | LIC_FILES_CHKSUM = "file://COPYING;md5=ea5bed2f60d357618ca161ad539f7c0a \ | ||
9 | file://kexec/kexec.c;beginline=1;endline=20;md5=af10f6ae4a8715965e648aa687ad3e09" | ||
10 | DEPENDS = "zlib xz" | ||
11 | |||
12 | SRC_URI = "${KERNELORG_MIRROR}/linux/utils/kernel/kexec/kexec-tools-${PV}.tar.gz \ | ||
13 | file://kdump \ | ||
14 | file://kdump.conf \ | ||
15 | file://kdump.service \ | ||
16 | file://0002-powerpc-change-the-memory-size-limit.patch \ | ||
17 | file://0001-purgatory-Pass-r-directly-to-linker.patch \ | ||
18 | file://0010-kexec-ARM-Fix-add_buffer_phys_virt-align-issue.patch \ | ||
19 | file://kexec-x32.patch \ | ||
20 | file://0001-Disable-PIE-during-link.patch \ | ||
21 | " | ||
22 | |||
23 | SRC_URI[md5sum] = "8e071ca473694a71e4ae60ed7ef6f377" | ||
24 | SRC_URI[sha256sum] = "450c87ba048641eb05f9717f5567aca57f063c266149ae663b58a34e5852deaf" | ||
25 | |||
26 | inherit autotools update-rc.d systemd | ||
27 | |||
28 | export LDFLAGS = "-L${STAGING_LIBDIR}" | ||
29 | EXTRA_OECONF = " --with-zlib=yes" | ||
30 | |||
31 | do_compile_prepend() { | ||
32 | # Remove the prepackaged config.h from the source tree as it overrides | ||
33 | # the same file generated by configure and placed in the build tree | ||
34 | rm -f ${S}/include/config.h | ||
35 | |||
36 | # Remove the '*.d' file to make sure the recompile is OK | ||
37 | for dep in `find ${B} -type f -name '*.d'`; do | ||
38 | dep_no_d="`echo $dep | sed 's#.d$##'`" | ||
39 | # Remove file.d when there is a file.o | ||
40 | if [ -f "$dep_no_d.o" ]; then | ||
41 | rm -f $dep | ||
42 | fi | ||
43 | done | ||
44 | } | ||
45 | |||
46 | do_install_append () { | ||
47 | install -d ${D}${sysconfdir}/sysconfig | ||
48 | install -m 0644 ${WORKDIR}/kdump.conf ${D}${sysconfdir}/sysconfig | ||
49 | |||
50 | if ${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then | ||
51 | install -D -m 0755 ${WORKDIR}/kdump ${D}${sysconfdir}/init.d/kdump | ||
52 | fi | ||
53 | |||
54 | if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then | ||
55 | install -D -m 0755 ${WORKDIR}/kdump ${D}${libexecdir}/kdump-helper | ||
56 | install -D -m 0644 ${WORKDIR}/kdump.service ${D}${systemd_unitdir}/system/kdump.service | ||
57 | sed -i -e 's,@LIBEXECDIR@,${libexecdir},g' ${D}${systemd_unitdir}/system/kdump.service | ||
58 | fi | ||
59 | } | ||
60 | |||
61 | PACKAGES =+ "kexec kdump vmcore-dmesg" | ||
62 | |||
63 | ALLOW_EMPTY_${PN} = "1" | ||
64 | RRECOMMENDS_${PN} = "kexec kdump vmcore-dmesg" | ||
65 | |||
66 | FILES_kexec = "${sbindir}/kexec" | ||
67 | FILES_kdump = "${sbindir}/kdump \ | ||
68 | ${sysconfdir}/sysconfig/kdump.conf \ | ||
69 | ${sysconfdir}/init.d/kdump \ | ||
70 | ${libexecdir}/kdump-helper \ | ||
71 | ${systemd_unitdir}/system/kdump.service \ | ||
72 | " | ||
73 | |||
74 | FILES_vmcore-dmesg = "${sbindir}/vmcore-dmesg" | ||
75 | |||
76 | INITSCRIPT_PACKAGES = "kdump" | ||
77 | INITSCRIPT_NAME_kdump = "kdump" | ||
78 | INITSCRIPT_PARAMS_kdump = "start 56 2 3 4 5 . stop 56 0 1 6 ." | ||
79 | |||
80 | SECURITY_PIE_CFLAGS_remove = "-fPIE -pie" | ||
81 | |||
82 | COMPATIBLE_HOST = '(x86_64.*|i.86.*|arm.*|aarch64.*|powerpc.*|mips.*)-(linux|freebsd.*)' | ||
83 | |||
84 | INSANE_SKIP_${PN} = "arch" | ||