kexec-tools: 2.0.14 -> 2.0.15

1) Upgrade kexec-tools from 2.0.14 to 2.0.15.
2) Remove patches that are included in 2.0.15.
   kexec-tools/0001-arm64-Disable-PIC.patch
   kexec-tools/0001-kexec-exntend-the-semantics-of-kexec_iomem_for_each_.patch
   kexec-tools/0001-vmcore-dmesg-Define-_GNU_SOURCE.patch
   kexec-tools/0001-x86-x86_64-Fix-format-warning-with-die.patch
   kexec-tools/0002-kexec-generalize-and-rename-get_kernel_stext_sym.patch
   kexec-tools/0002-ppc-Fix-format-warning-with-die.patch
   kexec-tools/0003-arm64-identify-PHYS_OFFSET-correctly.patch
   kexec-tools/0004-arm64-kdump-identify-memory-regions.patch
   kexec-tools/0005-arm64-kdump-add-elf-core-header-segment.patch
   kexec-tools/0006-arm64-kdump-set-up-kernel-image-segment.patch
   kexec-tools/0007-arm64-kdump-set-up-other-segments.patch
   kexec-tools/0008-arm64-kdump-add-DT-properties-to-crash-dump-kernel-s.patch
   kexec-tools/0009-arm64-kdump-Add-support-for-binary-image-files.patch

(From OE-Core rev: d2f196351a8e30542d5fb1561cb7960b6673c5ab)

Signed-off-by: Zheng Ruoqin <zhengrq.fnst@cn.fujitsu.com>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/meta/recipes-kernel/kexec/kexec-tools_2.0.15.bb b/meta/recipes-kernel/kexec/kexec-tools_2.0.15.bb
new file mode 100644
index 0000000000..6bd9025e6f
--- /dev/null
+++ b/meta/recipes-kernel/kexec/kexec-tools_2.0.15.bb
@@ -0,0 +1,52 @@
+require kexec-tools.inc
+export LDFLAGS = "-L${STAGING_LIBDIR}"
+EXTRA_OECONF = " --with-zlib=yes"
+
+SRC_URI += "${KERNELORG_MIRROR}/linux/utils/kernel/kexec/kexec-tools-${PV}.tar.gz \
+            file://0002-powerpc-change-the-memory-size-limit.patch \
+            file://0001-purgatory-Pass-r-directly-to-linker.patch \
+            file://0010-kexec-ARM-Fix-add_buffer_phys_virt-align-issue.patch \
+            file://kexec-x32.patch \
+            file://0001-Disable-PIE-during-link.patch \
+         "
+
+SRC_URI[md5sum] = "78906fdc255656fa2b9996c8acb3ef62"
+SRC_URI[sha256sum] = "42dbd0dab9964cd1ed89fa4571c8d13191eb7132b361ade5ac44517c91ecb97e"
+
+SECURITY_PIE_CFLAGS_remove = "-fPIE -pie"
+
+PACKAGES =+ "kexec kdump vmcore-dmesg"
+
+ALLOW_EMPTY_${PN} = "1"
+RRECOMMENDS_${PN} = "kexec kdump vmcore-dmesg"
+
+FILES_kexec = "${sbindir}/kexec"
+FILES_kdump = "${sbindir}/kdump \
+               ${sysconfdir}/sysconfig/kdump.conf \
+               ${sysconfdir}/init.d/kdump \
+               ${libexecdir}/kdump-helper \
+               ${systemd_unitdir}/system/kdump.service \
+"
+
+FILES_vmcore-dmesg = "${sbindir}/vmcore-dmesg"
+
+inherit update-rc.d systemd
+
+INITSCRIPT_PACKAGES = "kdump"
+INITSCRIPT_NAME_kdump = "kdump"
+INITSCRIPT_PARAMS_kdump = "start 56 2 3 4 5 . stop 56 0 1 6 ."
+
+do_install_append () {
+        install -d ${D}${sysconfdir}/sysconfig
+        install -m 0644 ${WORKDIR}/kdump.conf ${D}${sysconfdir}/sysconfig
+
+        if ${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then
+                install -D -m 0755 ${WORKDIR}/kdump ${D}${sysconfdir}/init.d/kdump
+        fi
+
+        if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
+                install -D -m 0755 ${WORKDIR}/kdump ${D}${libexecdir}/kdump-helper
+                install -D -m 0644 ${WORKDIR}/kdump.service ${D}${systemd_unitdir}/system/kdump.service
+                sed -i -e 's,@LIBEXECDIR@,${libexecdir},g' ${D}${systemd_unitdir}/system/kdump.service
+        fi
+}