diff options
author | Tim Orling <TicoTimo@gmail.com> | 2014-05-22 09:02:20 -0700 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2014-05-27 16:11:54 +0100 |
commit | 0882d265d83bcf816c1513cf594cdd35a309af8c (patch) | |
tree | c6c57740a267d8e4e8808d0533c37912d2de9cb5 /meta/recipes-graphics/wayland/weston_1.5.0.bb | |
parent | 87e2ce604e6fbe2814a923e5077ad4d0a562e790 (diff) | |
download | poky-0882d265d83bcf816c1513cf594cdd35a309af8c.tar.gz |
weston: upgrade to 1.5.0
* replace 0001-remove-dependence-on-wayland-scanner-flags.patch with
disable-wayland-scanner-pkg-check.patch
* add make-lcms-configureable.patch (WIP... needs work)
= fix for JaMa test-dependencies
(From OE-Core rev: 7c40efb62f34f866c98a0b2df50d66c60d76143a)
Signed-off-by: Tim Orling <TicoTimo@gmail.com>
Signed-off-by: Saul Wold <sgw@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-graphics/wayland/weston_1.5.0.bb')
-rw-r--r-- | meta/recipes-graphics/wayland/weston_1.5.0.bb | 83 |
1 files changed, 83 insertions, 0 deletions
diff --git a/meta/recipes-graphics/wayland/weston_1.5.0.bb b/meta/recipes-graphics/wayland/weston_1.5.0.bb new file mode 100644 index 0000000000..f6ae8c4970 --- /dev/null +++ b/meta/recipes-graphics/wayland/weston_1.5.0.bb | |||
@@ -0,0 +1,83 @@ | |||
1 | SUMMARY = "Weston, a Wayland compositor" | ||
2 | DESCRIPTION = "Weston is the reference implementation of a Wayland compositor" | ||
3 | HOMEPAGE = "http://wayland.freedesktop.org" | ||
4 | LICENSE = "MIT" | ||
5 | LIC_FILES_CHKSUM = "file://COPYING;md5=275efac2559a224527bd4fd593d38466 \ | ||
6 | file://src/compositor.c;endline=23;md5=aa98a8db03480fe7d500d0b1f4b8850c" | ||
7 | |||
8 | SRC_URI = "http://wayland.freedesktop.org/releases/${BPN}-${PV}.tar.xz \ | ||
9 | file://weston.png \ | ||
10 | file://weston.desktop \ | ||
11 | file://disable-wayland-scanner-pkg-check.patch \ | ||
12 | file://make-lcms-configurable.patch" | ||
13 | SRC_URI[md5sum] = "8eb40d230efc2411f083c20656534780" | ||
14 | SRC_URI[sha256sum] = "06388ba04ac79aa72d685cc1a8e646ddb2b8cfe11fcc742294f9addac48b7684" | ||
15 | |||
16 | inherit autotools pkgconfig useradd | ||
17 | |||
18 | DEPENDS = "libxkbcommon gdk-pixbuf pixman cairo glib-2.0 jpeg" | ||
19 | DEPENDS += "wayland virtual/egl pango" | ||
20 | |||
21 | EXTRA_OECONF = "--enable-setuid-install \ | ||
22 | --disable-xwayland \ | ||
23 | --enable-simple-clients \ | ||
24 | --enable-clients \ | ||
25 | --enable-demo-clients-install \ | ||
26 | --disable-libunwind \ | ||
27 | --disable-rpi-compositor \ | ||
28 | --disable-rdp-compositor \ | ||
29 | --disable-lcms" | ||
30 | |||
31 | |||
32 | PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'kms fbdev wayland egl', '', d)} \ | ||
33 | ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', '', d)} \ | ||
34 | ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'launch', '', d)} \ | ||
35 | " | ||
36 | # | ||
37 | # Compositor choices | ||
38 | # | ||
39 | # Weston on KMS | ||
40 | PACKAGECONFIG[kms] = "--enable-drm-compositor,--disable-drm-compositor,drm udev virtual/mesa mtdev" | ||
41 | # Weston on Wayland (nested Weston) | ||
42 | PACKAGECONFIG[wayland] = "--enable-wayland-compositor,--disable-wayland-compositor,virtual/mesa" | ||
43 | # Weston on X11 | ||
44 | PACKAGECONFIG[x11] = "--enable-x11-compositor,--disable-x11-compositor,virtual/libx11 libxcb libxcb libxcursor cairo" | ||
45 | # Headless Weston | ||
46 | PACKAGECONFIG[headless] = "--enable-headless-compositor,--disable-headless-compositor" | ||
47 | # Weston on framebuffer | ||
48 | PACKAGECONFIG[fbdev] = "--enable-fbdev-compositor,--disable-fbdev-compositor,udev mtdev" | ||
49 | # weston-launch | ||
50 | PACKAGECONFIG[launch] = "--enable-weston-launch,--disable-weston-launch,libpam drm" | ||
51 | # VA-API desktop recorder | ||
52 | PACKAGECONFIG[vaapi] = "--enable-vaapi-recorder,--disable-vaapi-recorder,libva" | ||
53 | # Weston with EGL support | ||
54 | PACKAGECONFIG[egl] = "--enable-egl --enable-simple-egl-clients,--disable-egl --disable-simple-egl-clients,virtual/egl" | ||
55 | # Weston with cairo glesv2 support | ||
56 | PACKAGECONFIG[cairo-glesv2] = "--with-cairo-glesv2,--with-cairo=image,cairo" | ||
57 | # Weston with lcms support | ||
58 | PACKAGECONFIG[lcms] = "--enable-lcms,--disable-lcms,lcms" | ||
59 | |||
60 | do_install_append() { | ||
61 | # Weston doesn't need the .la files to load modules, so wipe them | ||
62 | rm -f ${D}/${libdir}/weston/*.la | ||
63 | |||
64 | # If X11, ship a desktop file to launch it | ||
65 | if [ "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', '', d)}" = "x11" ]; then | ||
66 | install -d ${D}${datadir}/applications | ||
67 | install ${WORKDIR}/weston.desktop ${D}${datadir}/applications | ||
68 | |||
69 | install -d ${D}${datadir}/icons/hicolor/48x48/apps | ||
70 | install ${WORKDIR}/weston.png ${D}${datadir}/icons/hicolor/48x48/apps | ||
71 | fi | ||
72 | } | ||
73 | |||
74 | PACKAGES += "${PN}-examples" | ||
75 | |||
76 | FILES_${PN} = "${bindir}/weston ${bindir}/weston-terminal ${bindir}/weston-info ${bindir}/weston-launch ${bindir}/wcap-decode ${libexecdir} ${datadir}" | ||
77 | FILES_${PN}-examples = "${bindir}/*" | ||
78 | |||
79 | RDEPENDS_${PN} += "xkeyboard-config" | ||
80 | RRECOMMENDS_${PN} = "liberation-fonts" | ||
81 | |||
82 | USERADD_PACKAGES = "${PN}" | ||
83 | GROUPADD_PARAM_${PN} = "--system weston-launch" | ||