diff options
author | Andreas Müller <schnitzeltony@gmail.com> | 2020-03-12 15:43:31 +0100 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2020-03-13 11:32:10 +0000 |
commit | d5ebb8e7ecdae4d11894fb7867156a8ad931b91d (patch) | |
tree | 040fc526c71957effccfe1338ab1add11826dc7b /meta/recipes-graphics/libsdl2/libsdl2_2.0.12.bb | |
parent | ce000c5270e6c2ca66595f4f924a8e79aa6490b5 (diff) | |
download | poky-d5ebb8e7ecdae4d11894fb7867156a8ad931b91d.tar.gz |
libsdl2: upgrade 2.0.10 -> 2.0.12
* checked all hunks: backported patches can go
* for machines with neon in TUNE_FEATURES enable new configure option
--enable-arm-neon. If enabled, license must be extended to MIT
* license checksum changed by copyright year
(From OE-Core rev: aaa1c3ee0fe782fb08a58f100bc04686824de815)
Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-graphics/libsdl2/libsdl2_2.0.12.bb')
-rw-r--r-- | meta/recipes-graphics/libsdl2/libsdl2_2.0.12.bb | 81 |
1 files changed, 81 insertions, 0 deletions
diff --git a/meta/recipes-graphics/libsdl2/libsdl2_2.0.12.bb b/meta/recipes-graphics/libsdl2/libsdl2_2.0.12.bb new file mode 100644 index 0000000000..c1c941e452 --- /dev/null +++ b/meta/recipes-graphics/libsdl2/libsdl2_2.0.12.bb | |||
@@ -0,0 +1,81 @@ | |||
1 | SUMMARY = "Simple DirectMedia Layer" | ||
2 | DESCRIPTION = "Simple DirectMedia Layer is a cross-platform multimedia \ | ||
3 | library designed to provide low level access to audio, keyboard, mouse, \ | ||
4 | joystick, 3D hardware via OpenGL, and 2D video framebuffer." | ||
5 | HOMEPAGE = "http://www.libsdl.org" | ||
6 | BUGTRACKER = "http://bugzilla.libsdl.org/" | ||
7 | |||
8 | SECTION = "libs" | ||
9 | |||
10 | LICENSE = "Zlib" | ||
11 | LIC_FILES_CHKSUM = "file://COPYING.txt;md5=2d4af6adb4d89aad0cdedbcc18c9a32f" | ||
12 | |||
13 | # arm-neon adds MIT license | ||
14 | LICENSE_append = " ${@bb.utils.contains('PACKAGECONFIG', 'arm-neon', '& MIT', '', d)}" | ||
15 | LIC_FILES_CHKSUM_append = " ${@bb.utils.contains('PACKAGECONFIG', 'arm-neon', 'file://src/video/arm/pixman-arm-neon-asm.h;md5=9a9cc1e51abbf1da58f4d9528ec9d49b;beginline=1;endline=24', '', d)}" | ||
16 | |||
17 | PROVIDES = "virtual/libsdl2" | ||
18 | |||
19 | SRC_URI = "http://www.libsdl.org/release/SDL2-${PV}.tar.gz \ | ||
20 | file://more-gen-depends.patch \ | ||
21 | " | ||
22 | |||
23 | S = "${WORKDIR}/SDL2-${PV}" | ||
24 | |||
25 | SRC_URI[md5sum] = "783b6f2df8ff02b19bb5ce492b99c8ff" | ||
26 | SRC_URI[sha256sum] = "349268f695c02efbc9b9148a70b85e58cefbbf704abd3e91be654db7f1e2c863" | ||
27 | |||
28 | inherit autotools lib_package binconfig-disabled pkgconfig | ||
29 | |||
30 | BINCONFIG = "${bindir}/sdl2-config" | ||
31 | |||
32 | CVE_PRODUCT = "simple_directmedia_layer sdl" | ||
33 | |||
34 | EXTRA_OECONF = "--disable-oss --disable-esd --disable-arts \ | ||
35 | --disable-diskaudio --disable-nas --disable-esd-shared --disable-esdtest \ | ||
36 | --disable-video-dummy \ | ||
37 | --enable-pthreads \ | ||
38 | --enable-sdl-dlopen \ | ||
39 | --disable-rpath \ | ||
40 | --disable-sndio \ | ||
41 | --disable-fcitx --disable-ibus \ | ||
42 | " | ||
43 | |||
44 | # opengl packageconfig factored out to make it easy for distros | ||
45 | # and BSP layers to pick either (desktop) opengl, gles2, or no GL | ||
46 | PACKAGECONFIG_GL ?= "${@bb.utils.filter('DISTRO_FEATURES', 'opengl', d)}" | ||
47 | |||
48 | PACKAGECONFIG_class-native = "x11" | ||
49 | PACKAGECONFIG_class-nativesdk = "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)}" | ||
50 | PACKAGECONFIG ??= " \ | ||
51 | ${PACKAGECONFIG_GL} \ | ||
52 | ${@bb.utils.filter('DISTRO_FEATURES', 'alsa directfb pulseaudio x11', d)} \ | ||
53 | ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland gles2', '', d)} \ | ||
54 | ${@bb.utils.contains("TUNE_FEATURES", "neon","arm-neon","",d)} \ | ||
55 | " | ||
56 | PACKAGECONFIG[alsa] = "--enable-alsa --disable-alsatest,--disable-alsa,alsa-lib," | ||
57 | PACKAGECONFIG[arm-neon] = "--enable-arm-neon,--disable-arm-neon" | ||
58 | PACKAGECONFIG[directfb] = "--enable-video-directfb,--disable-video-directfb,directfb" | ||
59 | PACKAGECONFIG[gles2] = "--enable-video-opengles,--disable-video-opengles,virtual/libgles2" | ||
60 | PACKAGECONFIG[jack] = "--enable-jack,--disable-jack,jack" | ||
61 | PACKAGECONFIG[kmsdrm] = "--enable-video-kmsdrm,--disable-video-kmsdrm,libdrm virtual/libgbm" | ||
62 | PACKAGECONFIG[opengl] = "--enable-video-opengl,--disable-video-opengl,virtual/libgl" | ||
63 | PACKAGECONFIG[pulseaudio] = "--enable-pulseaudio,--disable-pulseaudio,pulseaudio" | ||
64 | PACKAGECONFIG[tslib] = "--enable-input-tslib,--disable-input-tslib,tslib" | ||
65 | PACKAGECONFIG[wayland] = "--enable-video-wayland,--disable-video-wayland,wayland-native wayland wayland-protocols libxkbcommon" | ||
66 | PACKAGECONFIG[x11] = "--enable-video-x11,--disable-video-x11,virtual/libx11 libxext libxrandr libxrender" | ||
67 | |||
68 | EXTRA_AUTORECONF += "--include=acinclude --exclude=autoheader" | ||
69 | |||
70 | do_configure_prepend() { | ||
71 | # Remove old libtool macros. | ||
72 | MACROS="libtool.m4 lt~obsolete.m4 ltoptions.m4 ltsugar.m4 ltversion.m4" | ||
73 | for i in ${MACROS}; do | ||
74 | rm -f ${S}/acinclude/$i | ||
75 | done | ||
76 | export SYSROOT=$PKG_CONFIG_SYSROOT_DIR | ||
77 | } | ||
78 | |||
79 | FILES_${PN}-dev += "${libdir}/cmake" | ||
80 | |||
81 | BBCLASSEXTEND = "native nativesdk" | ||