initial commit for Enea Linux 4.0

Migrated from the internal git server on the daisy-enea branch

Signed-off-by: Adrian Dudau <adrian.dudau@enea.com>

1 files changed, 58 insertions, 0 deletions

diff --git a/meta/recipes-graphics/freetype/freetype_2.5.2.bb b/meta/recipes-graphics/freetype/freetype_2.5.2.bb
new file mode 100644
index 0000000000..0c62a678cd
--- /dev/null
+++ b/meta/recipes-graphics/freetype/freetype_2.5.2.bb
@@ -0,0 +1,58 @@
+SUMMARY = "Freetype font rendering library"
+DESCRIPTION = "FreeType is a software font engine that is designed to be small, efficient, \
+highly customizable, and portable while capable of producing high-quality output (glyph \
+images). It can be used in graphics libraries, display servers, font conversion tools, text \
+image generation tools, and many other products as well."
+HOMEPAGE = "http://www.freetype.org/"
+BUGTRACKER = "https://savannah.nongnu.org/bugs/?group=freetype"
+
+LICENSE = "FreeType | GPLv2+"
+LIC_FILES_CHKSUM = "file://docs/LICENSE.TXT;md5=c017ff17fc6f0794adf93db5559ccd56 \
+                    file://docs/FTL.TXT;md5=d479e83797f699fe873b38dadd0fcd4c \
+                    file://docs/GPLv2.TXT;md5=8ef380476f642c20ebf40fecb0add2ec"
+
+SECTION = "libs"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/freetype/freetype-${PV}.tar.bz2 \
+"
+
+SRC_URI[md5sum] = "10e8f4d6a019b124088d18bc26123a25"
+SRC_URI[sha256sum] = "4ff4bd393aa01071ec7b849d035508a505a78f88b2bcf25ff11e58e43c0b9def"
+
+S = "${WORKDIR}/freetype-${PV}"
+
+inherit autotools-brokensep pkgconfig binconfig multilib_header
+
+LIBTOOL = "${S}/builds/unix/${HOST_SYS}-libtool"
+EXTRA_OEMAKE = "'LIBTOOL=${LIBTOOL}'"
+EXTRA_OEMAKE_class-native = ""
+EXTRA_OECONF = "--without-zlib --without-bzip2 CC_BUILD='${BUILD_CC}'"
+
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[pixmap] = "--with-png,--without-png,libpng"
+
+do_configure() {
+        cd builds/unix
+        libtoolize --force --copy
+        aclocal -I .
+        gnu-configize --force
+        autoconf
+        cd ${S}
+        oe_runconf
+}
+
+do_configure_class-native() {
+        (cd builds/unix && gnu-configize) || die "failure running gnu-configize"
+        oe_runconf
+}
+
+do_compile_prepend() {
+        ${BUILD_CC} -o objs/apinames src/tools/apinames.c
+}
+
+do_install_append() {
+        oe_multilib_header freetype2/config/ftconfig.h
+}
+
+BBCLASSEXTEND = "native"
+