diff options
author | Maxin B. John <maxin.john@intel.com> | 2018-06-12 14:18:08 +0300 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2018-06-18 11:07:57 +0100 |
commit | 84cc64783223bef5fdc168429e9a2c451122da76 (patch) | |
tree | e62addf626060c6efef8bee69a4a8cdab8c7d7cc /meta/recipes-gnome/gtk+/gtk-icon-utils-native_3.22.30.bb | |
parent | bf5f7191e9d69b4ee276f6a435f539e04aa5e248 (diff) | |
download | poky-84cc64783223bef5fdc168429e9a2c451122da76.tar.gz |
gtk-icon-utils-native: upgrade to 3.22.30
3.22.29 -> 3.22.30
(From OE-Core rev: 08a67f0b4eb07a006c30c7ba9a52fc453739e63e)
Signed-off-by: Maxin B. John <maxin.john@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-gnome/gtk+/gtk-icon-utils-native_3.22.30.bb')
-rw-r--r-- | meta/recipes-gnome/gtk+/gtk-icon-utils-native_3.22.30.bb | 63 |
1 files changed, 63 insertions, 0 deletions
diff --git a/meta/recipes-gnome/gtk+/gtk-icon-utils-native_3.22.30.bb b/meta/recipes-gnome/gtk+/gtk-icon-utils-native_3.22.30.bb new file mode 100644 index 0000000000..28e7a312d2 --- /dev/null +++ b/meta/recipes-gnome/gtk+/gtk-icon-utils-native_3.22.30.bb | |||
@@ -0,0 +1,63 @@ | |||
1 | SUMMARY = "Native icon utils for GTK+" | ||
2 | DESCRIPTION = "gtk-update-icon-cache and gtk-encode-symbolic-svg built from GTK+ natively, for build time and on-host postinst script execution." | ||
3 | SECTION = "libs" | ||
4 | |||
5 | DEPENDS = "glib-2.0-native gdk-pixbuf-native librsvg-native" | ||
6 | |||
7 | LICENSE = "LGPLv2 & LGPLv2+ & LGPLv2.1+" | ||
8 | |||
9 | MAJ_VER = "${@oe.utils.trim_version("${PV}", 2)}" | ||
10 | |||
11 | SRC_URI = "http://ftp.gnome.org/pub/gnome/sources/gtk+/${MAJ_VER}/gtk+-${PV}.tar.xz \ | ||
12 | file://Remove-Gdk-dependency-from-gtk-encode-symbolic-svg.patch" | ||
13 | SRC_URI[md5sum] = "61e60dc073e0a6893c72043d20579dc0" | ||
14 | SRC_URI[sha256sum] = "a1a4a5c12703d4e1ccda28333b87ff462741dc365131fbc94c218ae81d9a6567" | ||
15 | |||
16 | LIC_FILES_CHKSUM = "file://COPYING;md5=5f30f0716dfdd0d91eb439ebec522ec2 \ | ||
17 | file://gtk/gtk.h;endline=25;md5=1d8dc0fccdbfa26287a271dce88af737 \ | ||
18 | file://gdk/gdk.h;endline=25;md5=c920ce39dc88c6f06d3e7c50e08086f2 \ | ||
19 | file://tests/testgtk.c;endline=25;md5=cb732daee1d82af7a2bf953cf3cf26f1" | ||
20 | |||
21 | S = "${WORKDIR}/gtk+-${PV}" | ||
22 | |||
23 | inherit pkgconfig native | ||
24 | |||
25 | # versions >= 3.90 are development versions, otherwise like upstream-version-is-even | ||
26 | UPSTREAM_CHECK_REGEX = "[^\d\.](?P<pver>3\.([1-8]?[02468])+(\.\d+)+)\.tar" | ||
27 | |||
28 | PKG_CONFIG_FOR_BUILD = "${STAGING_BINDIR_NATIVE}/pkg-config-native" | ||
29 | |||
30 | do_configure() { | ||
31 | # Quite ugly but defines enough to compile the tools. | ||
32 | if ! test -f gtk/config.h; then | ||
33 | echo "#define GETTEXT_PACKAGE \"gtk30\"" >> gtk/config.h | ||
34 | echo "#define HAVE_UNISTD_H 1" >> gtk/config.h | ||
35 | echo "#define HAVE_FTW_H 1" >> gtk/config.h | ||
36 | fi | ||
37 | if ! test -f gdk/config.h; then | ||
38 | touch gdk/config.h | ||
39 | fi | ||
40 | } | ||
41 | |||
42 | do_compile() { | ||
43 | ${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS} \ | ||
44 | ${S}/gtk/updateiconcache.c \ | ||
45 | $(${PKG_CONFIG_FOR_BUILD} --cflags --libs gdk-pixbuf-2.0) \ | ||
46 | -o gtk-update-icon-cache | ||
47 | |||
48 | ${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS} \ | ||
49 | ${S}/gtk/encodesymbolic.c \ | ||
50 | $(${PKG_CONFIG_FOR_BUILD} --cflags --libs gio-2.0 gdk-pixbuf-2.0) \ | ||
51 | -o gtk-encode-symbolic-svg | ||
52 | } | ||
53 | |||
54 | do_install() { | ||
55 | install -d ${D}${bindir} | ||
56 | install -m 0755 ${B}/gtk-update-icon-cache ${D}${bindir} | ||
57 | install -m 0755 ${B}/gtk-encode-symbolic-svg ${D}${bindir} | ||
58 | |||
59 | create_wrapper ${D}/${bindir}/gtk-update-icon-cache \ | ||
60 | GDK_PIXBUF_MODULE_FILE=${STAGING_LIBDIR_NATIVE}/gdk-pixbuf-2.0/2.10.0/loaders.cache | ||
61 | create_wrapper ${D}/${bindir}/gtk-encode-symbolic-svg \ | ||
62 | GDK_PIXBUF_MODULE_FILE=${STAGING_LIBDIR_NATIVE}/gdk-pixbuf-2.0/2.10.0/loaders.cache | ||
63 | } | ||