gconf: add upstream GNOME gconf 3.2.3 and drop gconf-dbus

The D-Bus backend has been integrated into upstream GConf so we can
switch to upstream and drop gconf-dbus.

I've gone for a release in the 3.2 series as we disable Gtk+, and
therefore are not impacted by the gtk+3 changes, and the D-Bus backend
was unstable before this release.

(From OE-Core rev: f952b1bc8a4f307e2e2f3941f50becd72d88421d)

Signed-off-by: Joshua Lock <josh@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 43 insertions, 0 deletions

diff --git a/meta/recipes-gnome/gnome/gconf_3.2.3.bb b/meta/recipes-gnome/gnome/gconf_3.2.3.bb
new file mode 100644
index 0000000000..0e06cb5e87
--- /dev/null
+++ b/meta/recipes-gnome/gnome/gconf_3.2.3.bb
@@ -0,0 +1,43 @@
+DESCRIPTION = "GNOME configuration system"
+SECTION = "x11/gnome"
+LICENSE = "LGPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=55ca817ccb7d5b5b66355690e9abc605"
+
+DEPENDS = "glib-2.0 dbus dbus-glib libxml2 intltool-native polkit"
+
+inherit gnomebase
+
+SRC_URI = "${GNOME_MIRROR}/GConf/${@gnome_verdir("${PV}")}/GConf-${PV}.tar.bz2;name=archive \
+           file://nointro.patch"
+
+SRC_URI[archive.md5sum] = "f80329173cd9d134ad07e36002dd2a15"
+SRC_URI[archive.sha256sum] = "52008a82a847527877d9e1e549a351c86cc53cada4733b8a70a1123925d6aff4"
+
+S = "${WORKDIR}/GConf-${PV}"
+
+EXTRA_OECONF = "--disable-gtk-doc --disable-gtk --enable-shared --disable-static --enable-debug=yes --disable-introspection --disable-orbit --with-openldap=no"
+
+do_configure_prepend () {
+        touch gtk-doc.make
+}
+
+do_install_append() {
+        # this directory need to be created to avoid an Error 256 at gdm launch
+        install -d ${D}${sysconfdir}/gconf/gconf.xml.system
+
+        # this stuff is unusable
+        rm ${D}${libdir}/GConf/*/*.*a
+        rm ${D}${libdir}/gio/*/*.*a
+}
+
+RDEPENDS_${PN} += "dbus-x11"
+FILES_${PN} += "${libdir}/GConf/* \
+                ${libdir}/gio/*/*.so \
+                ${datadir}/polkit* \
+                ${datadir}/dbus-1/services/*.service \
+                ${datadir}/dbus-1/system-services/*.service \
+                "
+FILES_${PN}-dbg += "${libdir}/*/*/.debug"
+FILES_${PN}-dev += "${datadir}/sgml/gconf/gconf-1.0.dtd"
+
+BBCLASSEXTEND = "native"