diff options
author | Jussi Kukkonen <jussi.kukkonen@intel.com> | 2017-08-15 13:33:20 +0300 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2017-08-17 00:21:14 +0100 |
commit | 91572dc5870f0e216d10bf4e365b96baa80de77a (patch) | |
tree | ade17d402eae181a62ff5648945431b23470c237 /meta/recipes-gnome/gdk-pixbuf/gdk-pixbuf_2.36.8.bb | |
parent | 9b63e8247cf5608a1639b14ecbde125d43f5dd59 (diff) | |
download | poky-91572dc5870f0e216d10bf4e365b96baa80de77a.tar.gz |
gdk-pixbuf: Upgrade 2.36.6 -> 2.36.8
Smallish releases with bug fixes and minor improvements.
shared-mime-info is now always used for image type sniffing.
The dependency does not seem to currently be a build-time dependency
but configure.ac does check for it: I took the easy route and just
added shared-mime-info to DEPENDS as well.
(From OE-Core rev: ebba8c2999fc6cf94eca988f8d942acd9f0137ba)
Signed-off-by: Jussi Kukkonen <jussi.kukkonen@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-gnome/gdk-pixbuf/gdk-pixbuf_2.36.8.bb')
-rw-r--r-- | meta/recipes-gnome/gdk-pixbuf/gdk-pixbuf_2.36.8.bb | 102 |
1 files changed, 102 insertions, 0 deletions
diff --git a/meta/recipes-gnome/gdk-pixbuf/gdk-pixbuf_2.36.8.bb b/meta/recipes-gnome/gdk-pixbuf/gdk-pixbuf_2.36.8.bb new file mode 100644 index 0000000000..3d16ee0d8c --- /dev/null +++ b/meta/recipes-gnome/gdk-pixbuf/gdk-pixbuf_2.36.8.bb | |||
@@ -0,0 +1,102 @@ | |||
1 | SUMMARY = "Image loading library for GTK+" | ||
2 | HOMEPAGE = "http://www.gtk.org/" | ||
3 | BUGTRACKER = "https://bugzilla.gnome.org/" | ||
4 | |||
5 | LICENSE = "LGPLv2" | ||
6 | LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7 \ | ||
7 | file://gdk-pixbuf/gdk-pixbuf.h;endline=26;md5=72b39da7cbdde2e665329fef618e1d6b" | ||
8 | |||
9 | SECTION = "libs" | ||
10 | |||
11 | DEPENDS = "glib-2.0 gdk-pixbuf-native shared-mime-info" | ||
12 | |||
13 | MAJ_VER = "${@oe.utils.trim_version("${PV}", 2)}" | ||
14 | |||
15 | SRC_URI = "${GNOME_MIRROR}/${BPN}/${MAJ_VER}/${BPN}-${PV}.tar.xz \ | ||
16 | file://hardcoded_libtool.patch \ | ||
17 | file://extending-libinstall-dependencies.patch \ | ||
18 | file://run-ptest \ | ||
19 | file://fatal-loader.patch \ | ||
20 | file://0001-Work-around-thumbnailer-cross-compile-failure.patch \ | ||
21 | file://0001-queryloaders-Make-output-more-reproducible.patch \ | ||
22 | " | ||
23 | |||
24 | SRC_URI[md5sum] = "e0aaa0061eb12667b32b27472230b962" | ||
25 | SRC_URI[sha256sum] = "5d68e5283cdc0bf9bda99c3e6a1d52ad07a03364fa186b6c26cfc86fcd396a19" | ||
26 | |||
27 | inherit autotools pkgconfig gettext pixbufcache ptest-gnome upstream-version-is-even gobject-introspection gtk-doc lib_package | ||
28 | |||
29 | LIBV = "2.10.0" | ||
30 | |||
31 | GDK_PIXBUF_LOADERS ?= "png jpeg" | ||
32 | |||
33 | PACKAGECONFIG ??= "${GDK_PIXBUF_LOADERS}" | ||
34 | PACKAGECONFIG_linuxstdbase = "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)} ${GDK_PIXBUF_LOADERS}" | ||
35 | PACKAGECONFIG_class-native = "${GDK_PIXBUF_LOADERS}" | ||
36 | |||
37 | PACKAGECONFIG[png] = "--with-libpng,--without-libpng,libpng" | ||
38 | PACKAGECONFIG[jpeg] = "--with-libjpeg,--without-libjpeg,jpeg" | ||
39 | PACKAGECONFIG[tiff] = "--with-libtiff,--without-libtiff,tiff" | ||
40 | PACKAGECONFIG[jpeg2000] = "--with-libjasper,--without-libjasper,jasper" | ||
41 | |||
42 | PACKAGECONFIG[x11] = "--with-x11,--without-x11,virtual/libx11" | ||
43 | |||
44 | PACKAGES =+ "${PN}-xlib" | ||
45 | |||
46 | # For GIO image type sniffing | ||
47 | RDEPENDS_${PN} = "shared-mime-info" | ||
48 | |||
49 | FILES_${PN}-xlib = "${libdir}/*pixbuf_xlib*${SOLIBS}" | ||
50 | ALLOW_EMPTY_${PN}-xlib = "1" | ||
51 | |||
52 | FILES_${PN} += "${libdir}/gdk-pixbuf-2.0/gdk-pixbuf-query-loaders" | ||
53 | |||
54 | FILES_${PN}-bin += "${datadir}/thumbnailers/gdk-pixbuf-thumbnailer.thumbnailer" | ||
55 | |||
56 | FILES_${PN}-dev += " \ | ||
57 | ${bindir}/gdk-pixbuf-csource \ | ||
58 | ${bindir}/gdk-pixbuf-pixdata \ | ||
59 | ${bindir}/gdk-pixbuf-print-mime-types \ | ||
60 | ${includedir}/* \ | ||
61 | ${libdir}/gdk-pixbuf-2.0/${LIBV}/loaders/*.la \ | ||
62 | " | ||
63 | |||
64 | PACKAGES_DYNAMIC += "^gdk-pixbuf-loader-.*" | ||
65 | PACKAGES_DYNAMIC_class-native = "" | ||
66 | |||
67 | python populate_packages_prepend () { | ||
68 | postinst_pixbufloader = d.getVar("postinst_pixbufloader") | ||
69 | |||
70 | loaders_root = d.expand('${libdir}/gdk-pixbuf-2.0/${LIBV}/loaders') | ||
71 | |||
72 | packages = ' '.join(do_split_packages(d, loaders_root, '^libpixbufloader-(.*)\.so$', 'gdk-pixbuf-loader-%s', 'GDK pixbuf loader for %s')) | ||
73 | d.setVar('PIXBUF_PACKAGES', packages) | ||
74 | |||
75 | # The test suite exercises all the loaders, so ensure they are all | ||
76 | # dependencies of the ptest package. | ||
77 | d.appendVar("RDEPENDS_gdk-pixbuf-ptest", " " + packages) | ||
78 | } | ||
79 | |||
80 | do_install_append() { | ||
81 | # Move gdk-pixbuf-query-loaders into libdir so it is always available | ||
82 | # in multilib builds. | ||
83 | mv ${D}/${bindir}/gdk-pixbuf-query-loaders ${D}/${libdir}/gdk-pixbuf-2.0/ | ||
84 | } | ||
85 | |||
86 | do_install_append_class-native() { | ||
87 | find ${D}${libdir} -name "libpixbufloader-*.la" -exec rm \{\} \; | ||
88 | |||
89 | create_wrapper ${D}/${bindir}/gdk-pixbuf-csource \ | ||
90 | GDK_PIXBUF_MODULE_FILE=${STAGING_LIBDIR_NATIVE}/gdk-pixbuf-2.0/${LIBV}/loaders.cache | ||
91 | |||
92 | create_wrapper ${D}/${bindir}/gdk-pixbuf-pixdata \ | ||
93 | GDK_PIXBUF_MODULE_FILE=${STAGING_LIBDIR_NATIVE}/gdk-pixbuf-2.0/${LIBV}/loaders.cache | ||
94 | |||
95 | create_wrapper ${D}/${bindir}/gdk-pixbuf-print-mime-types \ | ||
96 | GDK_PIXBUF_MODULE_FILE=${STAGING_LIBDIR_NATIVE}/gdk-pixbuf-2.0/${LIBV}/loaders.cache | ||
97 | |||
98 | create_wrapper ${D}/${libdir}/gdk-pixbuf-2.0/gdk-pixbuf-query-loaders \ | ||
99 | GDK_PIXBUF_MODULE_FILE=${STAGING_LIBDIR_NATIVE}/gdk-pixbuf-2.0/${LIBV}/loaders.cache \ | ||
100 | GDK_PIXBUF_MODULEDIR=${STAGING_LIBDIR_NATIVE}/gdk-pixbuf-2.0/${LIBV}/loaders | ||
101 | } | ||
102 | BBCLASSEXTEND = "native" | ||