Major layout change to the packages directory

Having one monolithic packages directory makes it hard to find things
and is generally overwhelming. This commit splits it into several
logical sections roughly based on function, recipes.txt gives more
information about the classifications used.

The opportunity is also used to switch from "packages" to "recipes"
as used in OpenEmbedded as the term "packages" can be confusing to
people and has many different meanings.

Not all recipes have been classified yet, this is just a first pass
at separating things out. Some packages are moved to meta-extras as
they're no longer actively used or maintained.

Signed-off-by: Richard Purdie <rpurdie@linux.intel.com>

1 files changed, 40 insertions, 0 deletions

diff --git a/meta/recipes-extended/which/which_2.18.bb b/meta/recipes-extended/which/which_2.18.bb
new file mode 100644
index 0000000000..b177949788
--- /dev/null
+++ b/meta/recipes-extended/which/which_2.18.bb
@@ -0,0 +1,40 @@
+DESCRIPTION = "Which is a utility that prints out the full path of the \
+executables that bash(1) would execute when the passed \
+program names would have been entered on the shell prompt. \
+It does this by using the exact same algorithm as bash."
+HOMEPAGE = "http://www.xs4all.nl/~carlo17/which/"
+BUGTRACKER = "n/a"
+
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
+
+PR = "r0"
+
+SRC_URI = "http://www.xs4all.nl/~carlo17/which/which-${PV}.tar.gz \
+           file://fix_name_conflict_group_member.patch"
+
+DEPENDS = "cwautomacros-native"
+
+inherit autotools
+
+do_configure_prepend() {
+        OLD="@ACLOCAL_CWFLAGS@"
+        NEW="-I ${STAGING_DIR_NATIVE}/${datadir}/cwautomacros/m4"
+        sed -i "s#${OLD}#${NEW}#g" `grep -rl ${OLD} ${S}`
+}
+do_install_append() {
+        mv ${D}/${bindir}/which ${D}/${bindir}/which.${PN}
+}
+
+pkg_postinst_${PN}() {
+        if [ "${PN}" = "${BPN}" ] ; then
+                update-alternatives --install ${bindir}/which which which.${PN} 100
+        fi
+}
+
+pkg_prerm_${PN}() {
+        if [ "${PN}" = "${BPN}" ] ; then
+                update-alternatives --remove which which.${PN}
+        fi
+}
+