initial commit for Enea Linux 5.0 arm

Signed-off-by: Tudor Florea <tudor.florea@enea.com>

2 files changed, 42 insertions, 0 deletions

diff --git a/meta/recipes-extended/pigz/pigz.inc b/meta/recipes-extended/pigz/pigz.inc
new file mode 100644
index 0000000000..355fb2a4ec
--- /dev/null
+++ b/meta/recipes-extended/pigz/pigz.inc
@@ -0,0 +1,32 @@
+SUMMARY = "A parallel implementation of gzip"
+DESCRIPTION = "pigz, which stands for parallel implementation of gzip, is a \
+fully functional replacement for gzip that exploits multiple processors and \
+multiple cores to the hilt when compressing data. pigz was written by Mark \
+Adler, and uses the zlib and pthread libraries."
+HOMEPAGE = "http://zlib.net/pigz/"
+SECTION = "console/utils"
+LICENSE = "Zlib"
+
+SRC_URI = "http://zlib.net/pigz/pigz-${PV}.tar.gz"
+
+PROVIDES_class-native += "gzip-native"
+
+DEPENDS = "zlib"
+
+do_install () {
+        if [ "${CLASSOVERRIDE}" = "class-target" ] ; then
+                # Install files into /bin (FHS), which is typical place for gzip
+                install -d ${D}${base_bindir}           
+                install ${B}/pigz ${D}${base_bindir}/gzip
+                install ${B}/unpigz ${D}${base_bindir}/gunzip
+        else
+                install -d ${D}${bindir}
+                install ${B}/pigz ${D}${bindir}/gzip
+                install ${B}/unpigz ${D}${bindir}/gunzip
+        fi
+}
+
+ALTERNATIVE_${PN} = "gzip gunzip"
+ALTERNATIVE_LINK_NAME[gzip] = "${base_bindir}/gzip"
+ALTERNATIVE_LINK_NAME[gunzip] = "${base_bindir}/gunzip"
+ALTERNATIVE_PRIORITY = "80"
diff --git a/meta/recipes-extended/pigz/pigz_2.3.1.bb b/meta/recipes-extended/pigz/pigz_2.3.1.bb
new file mode 100644
index 0000000000..cd5508d63e
--- /dev/null
+++ b/meta/recipes-extended/pigz/pigz_2.3.1.bb
@@ -0,0 +1,10 @@
+require pigz.inc
+LIC_FILES_CHKSUM = "file://pigz.c;beginline=7;endline=21;md5=a21d4075cb00ab4ca17fce5e7534ca95"
+
+SRC_URI[md5sum] = "e803f8bc0770c7a5e96dccb1d2dd2aab"
+SRC_URI[sha256sum] = "629b0ce5422a3978f31742bf8275d0be2f84987140d18f390f1e3b4e46e0af54"
+
+NATIVE_PACKAGE_PATH_SUFFIX = "/${PN}"
+
+BBCLASSEXTEND = "native nativesdk"
+