parted: upgrade to 3.2

Drop fix-git-version-gen.patch, fix-dvh-overflows.patch and
fix-deprecated-readline.patch, because the parted 3.2 have
merged them.

Add fix-compile-failure-while-dis.patch to fix compile failure

(From OE-Core rev: 5faae24198ded58c5328e9f3e5ab99c89047a57d)

Signed-off-by: Hongxu Jia <hongxu.jia@windriver.com>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 43 insertions, 0 deletions

diff --git a/meta/recipes-extended/parted/parted_3.2.bb b/meta/recipes-extended/parted/parted_3.2.bb
new file mode 100644
index 0000000000..655a825703
--- /dev/null
+++ b/meta/recipes-extended/parted/parted_3.2.bb
@@ -0,0 +1,43 @@
+SUMMARY = "Disk partition editing/resizing utility"
+HOMEPAGE = "http://www.gnu.org/software/parted/parted.html"
+LICENSE = "GPLv3+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=2f31b266d3440dd7ee50f92cf67d8e6c"
+SECTION = "console/tools"
+DEPENDS = "ncurses readline util-linux"
+PR = "r1"
+
+SRC_URI = "${GNU_MIRROR}/parted/parted-${PV}.tar.xz \
+           file://no_check.patch \
+           file://syscalls.patch \
+           file://fix-doc-mandir.patch \
+           file://fix-compile-failure-while-dis.patch \
+           file://run-ptest \
+           file://Makefile \
+"
+
+SRC_URI[md5sum] = "0247b6a7b314f8edeb618159fa95f9cb"
+SRC_URI[sha256sum] = "858b589c22297cacdf437f3baff6f04b333087521ab274f7ab677cb8c6bb78e4"
+
+EXTRA_OECONF = "--disable-device-mapper"
+
+inherit autotools pkgconfig gettext texinfo ptest
+
+BBCLASSEXTEND = "native"
+
+do_compile_ptest() {
+        oe_runmake -C tests print-align print-max dup-clobber duplicate fs-resize
+}
+
+do_install_ptest() {
+        t=${D}${PTEST_PATH}
+        mkdir $t/build-aux
+        cp ${S}/build-aux/test-driver $t/build-aux/
+        cp -r ${S}/tests $t
+        cp ${WORKDIR}/Makefile $t/tests/
+        for i in print-align print-max dup-clobber duplicate fs-resize; \
+          do cp ${B}/tests/.libs/$i $t/tests/; \
+        done
+        sed -e 's| ../parted||' -i $t/tests/*.sh
+}
+
+RDEPENDS_${PN}-ptest = "bash coreutils perl util-linux-losetup"