diff options
author | Cristian Iorga <cristian.iorga@intel.com> | 2013-08-07 17:53:47 +0300 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2013-08-12 13:09:51 +0100 |
commit | 3a8f3b88813c79e18a8b03c9fad959a406cbf19d (patch) | |
tree | b2afaee12b2dd7f5e96c1d072e68b5baca18f5aa /meta/recipes-extended/net-tools/net-tools_1.60-25.bb | |
parent | 60bc7c1917f8e8c741f919db5038843086800be7 (diff) | |
download | poky-3a8f3b88813c79e18a8b03c9fad959a406cbf19d.tar.gz |
net-tools: upgrade to v1.60-25
(From OE-Core rev: 2277b106b947248b06a257a90420d8d69fe522f9)
Signed-off-by: Cristian Iorga <cristian.iorga@intel.com>
Signed-off-by: Saul Wold <sgw@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-extended/net-tools/net-tools_1.60-25.bb')
-rw-r--r-- | meta/recipes-extended/net-tools/net-tools_1.60-25.bb | 86 |
1 files changed, 86 insertions, 0 deletions
diff --git a/meta/recipes-extended/net-tools/net-tools_1.60-25.bb b/meta/recipes-extended/net-tools/net-tools_1.60-25.bb new file mode 100644 index 0000000000..bd72acc9ef --- /dev/null +++ b/meta/recipes-extended/net-tools/net-tools_1.60-25.bb | |||
@@ -0,0 +1,86 @@ | |||
1 | SUMMARY="Basic networking tools" | ||
2 | DESCRIPTION="A collection of programs that form the base set of the NET-3 networking distribution for the Linux operating system" | ||
3 | HOMEPAGE = "http://net-tools.berlios.de/" | ||
4 | BUGTRACKER = "http://bugs.debian.org/net-tools" | ||
5 | LICENSE = "GPLv2+" | ||
6 | LIC_FILES_CHKSUM = "file://COPYING;md5=8ca43cbc842c2336e835926c2166c28b \ | ||
7 | file://ifconfig.c;beginline=11;endline=15;md5=d1ca372080ad5401e23ca0afc35cf9ba" | ||
8 | |||
9 | SRC_URI = "${DEBIAN_MIRROR}/main/n/net-tools/net-tools_1.60.orig.tar.gz;name=tarball \ | ||
10 | ${DEBIAN_MIRROR}/main/n/net-tools/${BPN}_${PV}.diff.gz;apply=no;name=patch \ | ||
11 | file://net-tools-config.h \ | ||
12 | file://net-tools-config.make" | ||
13 | |||
14 | S = "${WORKDIR}/net-tools-1.60" | ||
15 | |||
16 | SRC_URI[tarball.md5sum] = "ecaf37acb5b5daff4bdda77785fd916d" | ||
17 | SRC_URI[tarball.sha256sum] = "ec67967cf7b1a3a3828a84762fbc013ac50ee5dc9aa3095d5c591f302c2de0f5" | ||
18 | |||
19 | SRC_URI[patch.md5sum] = "5ab1e2184d0fa6518031291138f2fc51" | ||
20 | SRC_URI[patch.sha256sum] = "1bddcd96ac60e794978cb20fb7ea4c2e77258c56c042c9ac8b6ec2b2033bc56f" | ||
21 | |||
22 | inherit gettext | ||
23 | |||
24 | # The Makefile is lame, no parallel build | ||
25 | PARALLEL_MAKE = "" | ||
26 | |||
27 | # Unlike other Debian packages, net-tools *.diff.gz contains another series of | ||
28 | # patches maintained by quilt. So manually apply them before applying other local | ||
29 | # patches. Also remove all temp files before leaving, because do_patch() will pop | ||
30 | # up all previously applied patches in the start | ||
31 | nettools_do_patch() { | ||
32 | cd ${S} | ||
33 | quilt pop -a || true | ||
34 | if [ -d ${S}/.pc-nettools ]; then | ||
35 | mv ${S}/.pc-nettools ${S}/.pc | ||
36 | QUILT_PATCHES=${S}/debian/patches quilt pop -a | ||
37 | rm -rf ${S}/.pc ${S}/debian | ||
38 | fi | ||
39 | patch -p1 < ${WORKDIR}/${BPN}_${PV}.diff | ||
40 | QUILT_PATCHES=${S}/debian/patches quilt push -a | ||
41 | mv ${S}/.pc ${S}/.pc-nettools | ||
42 | } | ||
43 | |||
44 | do_unpack[cleandirs] += "${S}" | ||
45 | |||
46 | # We invoke base do_patch at end, to incorporate any local patch | ||
47 | python do_patch() { | ||
48 | bb.build.exec_func('nettools_do_patch', d) | ||
49 | bb.build.exec_func('patch_do_patch', d) | ||
50 | } | ||
51 | |||
52 | do_configure() { | ||
53 | # net-tools has its own config mechanism requiring "make config" | ||
54 | # we pre-generate desired options and copy to source directory instead | ||
55 | cp ${WORKDIR}/net-tools-config.h ${S}/config.h | ||
56 | cp ${WORKDIR}/net-tools-config.make ${S}/config.make | ||
57 | } | ||
58 | |||
59 | do_compile() { | ||
60 | # net-tools use COPTS/LOPTS to allow adding custom options | ||
61 | export COPTS="$CFLAGS" | ||
62 | export LOPTS="$LDFLAGS" | ||
63 | unset CFLAGS | ||
64 | unset LDFLAGS | ||
65 | |||
66 | oe_runmake | ||
67 | } | ||
68 | |||
69 | do_install() { | ||
70 | oe_runmake 'BASEDIR=${D}' install | ||
71 | } | ||
72 | |||
73 | inherit update-alternatives | ||
74 | |||
75 | base_sbindir_progs = "arp ifconfig ipmaddr iptunnel mii-tool nameif plipconfig rarp route slattach" | ||
76 | base_bindir_progs = "dnsdomainname domainname hostname netstat nisdomainname ypdomainname" | ||
77 | |||
78 | ALTERNATIVE_${PN} = "${base_sbindir_progs} ${base_bindir_progs}" | ||
79 | python __anonymous() { | ||
80 | for prog in d.getVar('base_sbindir_progs', True).split(): | ||
81 | d.setVarFlag('ALTERNATIVE_LINK_NAME', prog, '%s/%s' % (d.getVar('base_sbindir', True), prog)) | ||
82 | for prog in d.getVar('base_bindir_progs', True).split(): | ||
83 | d.setVarFlag('ALTERNATIVE_LINK_NAME', prog, '%s/%s' % (d.getVar('base_bindir', True), prog)) | ||
84 | } | ||
85 | ALTERNATIVE_PRIORITY = "100" | ||
86 | |||