lighttpd: upgrade to 1.4.32

lighttpd_fix_for_automake-1.12.patch: removed
- included in the new version

(From OE-Core rev: 6b87ac303c1f7357c9630359614b373082a59506)

Signed-off-by: Constantin Musca <constantinx.musca@intel.com>
Signed-off-by: Saul Wold <sgw@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 63 insertions, 0 deletions

diff --git a/meta/recipes-extended/lighttpd/lighttpd_1.4.32.bb b/meta/recipes-extended/lighttpd/lighttpd_1.4.32.bb
new file mode 100644
index 0000000000..df6ce9723d
--- /dev/null
+++ b/meta/recipes-extended/lighttpd/lighttpd_1.4.32.bb
@@ -0,0 +1,63 @@
+DESCRIPTION = "Lightweight high-performance web server"
+HOMEPAGE = "http://www.lighttpd.net/"
+BUGTRACKER = "http://redmine.lighttpd.net/projects/lighttpd/issues"
+
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://COPYING;md5=e4dac5c6ab169aa212feb5028853a579"
+
+
+SECTION = "net"
+DEPENDS = "zlib libpcre"
+RDEPENDS_${PN} += " \
+               lighttpd-module-access \
+               lighttpd-module-accesslog \
+               lighttpd-module-indexfile \
+               lighttpd-module-dirlisting \
+               lighttpd-module-staticfile \
+"
+
+PR = "r0"
+
+SRC_URI = "http://download.lighttpd.net/lighttpd/releases-1.4.x/lighttpd-${PV}.tar.bz2 \
+        file://index.html.lighttpd \
+        file://lighttpd.conf \
+        file://lighttpd \
+        "
+
+SRC_URI[md5sum] = "8e2d4ae8e918d4de1aeb9842584d170b"
+SRC_URI[sha256sum] = "60691b2dcf3ad2472c06b23d75eb0c164bf48a08a630ed3f308f61319104701f"
+
+EXTRA_OECONF = " \
+             --without-bzip2 \
+             --without-ldap \
+             --without-lua \
+             --without-memcache \
+             --with-pcre \
+             --without-webdav-props \
+             --without-webdav-locks \
+             --without-openssl \
+             --disable-static \
+"
+
+inherit autotools pkgconfig update-rc.d gettext
+
+INITSCRIPT_NAME = "lighttpd"
+INITSCRIPT_PARAMS = "defaults 70"
+
+do_install_append() {
+    install -d ${D}${sysconfdir}/init.d ${D}/www/logs ${D}/www/pages/dav ${D}/www/var
+    install -m 0755 ${WORKDIR}/lighttpd ${D}${sysconfdir}/init.d
+    install -m 0755 ${WORKDIR}/lighttpd.conf ${D}${sysconfdir}
+    install -m 0644 ${WORKDIR}/index.html.lighttpd ${D}/www/pages/index.html
+}
+
+FILES_${PN} += "${sysconfdir} /www"
+
+CONFFILES_${PN} = "${sysconfdir}/lighttpd.conf"
+
+PACKAGES_DYNAMIC += "^lighttpd-module-.*"
+
+python populate_packages_prepend () {
+    lighttpd_libdir = d.expand('${libdir}')
+    do_split_packages(d, lighttpd_libdir, '^mod_(.*)\.so$', 'lighttpd-module-%s', 'Lighttpd module for %s', extra_depends='')
+}